I_BPAdditionalOwnerOverviewTP

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'BP Additional Owners Overview - TP'
@ObjectModel: {
  usageType: {
    serviceQuality: #B,
    sizeCategory: #XXL,
    dataClass: #TRANSACTIONAL
  }
}
@VDM.viewType: #TRANSACTIONAL
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK", "CALCULATED_FIELD_CHECK" ]  } */
define root view entity I_BPAdditionalOwnerOverviewTP
  as select from I_BusinessPartnerProcess as BusinessPartner
    inner join   I_MDChgProcessStep       as _Step on  BusinessPartner.MasterDataChangeProcess = _Step.MasterDataChangeProcess
                                                   and BusinessPartner.MDChgProcessStep        = _Step.MDChgProcessStep
  composition [*] of I_BPAddlOwnerSentRecordTP       as _AdditionalOwnersRecords
  association [*]    to I_MDFederationAddlOwnr          as _AdditionalOwners             on  $projection.MasterDataChangeProcess              = _AdditionalOwners.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep                     = _AdditionalOwners.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem               = _AdditionalOwners.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject               = _AdditionalOwners.MDChgProcessSrceObject
                                                                                         and _AdditionalOwners.MDChgProcessSrceObjectTypeCode = '147'
  association [*]    to I_MDFederationAddlOwnr          as _AdditionalOwnersReportedBack on  $projection.MasterDataChangeProcess                          = _AdditionalOwnersReportedBack.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep                                 = _AdditionalOwnersReportedBack.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem                           = _AdditionalOwnersReportedBack.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject                           = _AdditionalOwnersReportedBack.MDChgProcessSrceObject
                                                                                         and _AdditionalOwnersReportedBack.MDChgProcessSrceObjectTypeCode = '147'
                                                                                         and _AdditionalOwnersReportedBack.MDAddlOwnerHasReportedBack     = 'X'
  association [0..1] to I_MDChgProcKPIFltrFederation as _FederationStatusText            on  $projection.MDChgProcessFederationStatus = _FederationStatusText.MDChangeProcKPIValueKey

{
  key BusinessPartner.MasterDataChangeProcess,
  key BusinessPartner.MDChgProcessStep,
  key BusinessPartner.MDChgProcessSrceSystem,
  key BusinessPartner.MDChgProcessSrceObject,
      cast(
        case
          when count( distinct _AdditionalOwners.MasterDataChangeProcess ) = 0 then 'N'
          when count( distinct _AdditionalOwnersReportedBack.MDChgProcessAddlOwnerSystem ) = count( distinct _AdditionalOwners.MDChgProcessAddlOwnerSystem ) then 'F'
          else 'P'
      end as mdc_fed_addowner_status preserving type) as MDChgProcessFederationStatus,
      cast(
        case
          when count( distinct _AdditionalOwners.MasterDataChangeProcess ) = 0 then 0
          when count( distinct _AdditionalOwnersReportedBack.MDChgProcessAddlOwnerSystem ) = count( distinct _AdditionalOwners.MDChgProcessAddlOwnerSystem ) then 3
          else 2
      end as int1 preserving type)                    as MDChgProcFederationStsCritlty,
      BusinessPartner.AuthorizationGroup,
      BusinessPartner.IsBusinessPurposeCompleted,

      BusinessPartner.DataControllerSet,
      BusinessPartner.DataController1,
      BusinessPartner.DataController2,
      BusinessPartner.DataController3,
      BusinessPartner.DataController4,
      BusinessPartner.DataController5,
      BusinessPartner.DataController6,
      BusinessPartner.DataController7,
      BusinessPartner.DataController8,
      BusinessPartner.DataController9,
      BusinessPartner.DataController10,

      _AdditionalOwnersRecords,
      _FederationStatusText
}
where
  _Step.MDChgProcessStepType = 'FED'
group by
  BusinessPartner.MasterDataChangeProcess,
  BusinessPartner.MDChgProcessStep,
  BusinessPartner.MDChgProcessSrceSystem,
  BusinessPartner.MDChgProcessSrceObject,
  BusinessPartner.AuthorizationGroup,
  BusinessPartner.IsBusinessPurposeCompleted,
  BusinessPartner.DataControllerSet,
  BusinessPartner.DataController1,
  BusinessPartner.DataController2,
  BusinessPartner.DataController3,
  BusinessPartner.DataController4,
  BusinessPartner.DataController5,
  BusinessPartner.DataController6,
  BusinessPartner.DataController7,
  BusinessPartner.DataController8,
  BusinessPartner.DataController9,
  BusinessPartner.DataController10
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNERPROCESS",
"I_MDCHGPROCESSSTEP",
"I_MDFEDERATIONADDLOWNR"
],
"ASSOCIATED":
[
"I_BPADDLOWNERSENTRECORDTP",
"I_MDCHGPROCKPIFLTRFEDERATION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/