I_BOOSequenceChangeState

@AbapCatalog.sqlViewName: 'IPPBOOSEQUENCECS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true 
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@Analytics: {dataCategory: #DIMENSION}
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions: true
@ObjectModel.representativeKey: 'BOOSqncInternalVersionCounter'
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@EndUserText.label: 'Bill of Operations Sequence Change State'

define view I_BOOSequenceChangeState
  as select from    plfl as plfl

  association [1..1] to I_BillOfOperationsType        as _BillOfOperationsType         on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType

  association [1..1] to I_BillOfOperationsGroup       as _BillOfOperationsGroup        on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                                       and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup

  association [1..1] to I_BillOfOperations            as _BillOfOperations             on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                                       and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                                       and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
  association [1..1] to I_BillOfOperationsSequence    as _BillOfOperationsSequence     on  $projection.BillOfOperationsType     = _BillOfOperationsSequence.BillOfOperationsType
                                                                                       and $projection.BillOfOperationsGroup    = _BillOfOperationsSequence.BillOfOperationsGroup
                                                                                       and $projection.BillOfOperationsVariant  = _BillOfOperationsSequence.BillOfOperationsVariant
                                                                                       and $projection.BillOfOperationsSequence = _BillOfOperationsSequence.BillOfOperationsSequence

  association [1..1] to I_BillOfOperationsSequenceCat as _BillOfOperationsSequenceCat  on  $projection.BillOfOperationsSequenceCat = _BillOfOperationsSequenceCat.BillOfOperationsSequenceCat

  association [0..1] to I_SequenceSchedulingAlignment as _SequenceSchedulingAlignment  on  $projection.SequenceSchedulingAlignment = _SequenceSchedulingAlignment.SequenceSchedulingAlignment

  association [1..1] to I_BillOfOperationsSequence    as _BillOfOperationsRefSequence  on  $projection.BillOfOperationsType        = _BillOfOperationsRefSequence.BillOfOperationsType
                                                                                       and $projection.BillOfOperationsGroup       = _BillOfOperationsRefSequence.BillOfOperationsGroup
                                                                                       and $projection.BillOfOperationsVariant     = _BillOfOperationsRefSequence.BillOfOperationsVariant
                                                                                       and $projection.BillOfOperationsRefSequence = _BillOfOperationsRefSequence.BillOfOperationsSequence

  association [0..1] to I_BillOfOperationsOperation   as _BOOOperationsBranchOperation on  $projection.BillOfOperationsType        = _BOOOperationsBranchOperation.BillOfOperationsType
                                                                                       and $projection.BillOfOperationsGroup       = _BOOOperationsBranchOperation.BillOfOperationsGroup
                                                                                       and $projection.BillOfOperationsVariant     = _BOOOperationsBranchOperation.BillOfOperationsVariant
                                                                                       and $projection.BillOfOperationsRefSequence = _BOOOperationsBranchOperation.BillOfOperationsSequence
                                                                                       and $projection.BOOSqncBranchOpInternalID   = _BOOOperationsBranchOperation.BOOOperationInternalID

  association [0..1] to I_BillOfOperationsOperation   as _BOOOperationsReturnOperation on  $projection.BillOfOperationsType        = _BOOOperationsReturnOperation.BillOfOperationsType
                                                                                       and $projection.BillOfOperationsGroup       = _BOOOperationsReturnOperation.BillOfOperationsGroup
                                                                                       and $projection.BillOfOperationsVariant     = _BOOOperationsReturnOperation.BillOfOperationsVariant
                                                                                       and $projection.BillOfOperationsRefSequence = _BOOOperationsReturnOperation.BillOfOperationsSequence
                                                                                       and $projection.BOOSqncReturnOpInternalID   = _BOOOperationsReturnOperation.BOOOperationInternalID

  association [0..1] to I_ChangeMaster                as _ChangeMaster                 on  $projection.ChangeNumber = _ChangeMaster.ChangeNumber

{
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plfl.plnty                                                     as   BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key plfl.plnnr                                                     as   BillOfOperationsGroup,
      @ObjectModel.foreignKey.association: '_BillOfOperations'
  key plfl.plnal                                                     as   BillOfOperationsVariant,
      @ObjectModel.foreignKey.association: '_BillOfOperationsSequence'
  key plfl.plnfl                                                     as   BillOfOperationsSequence,
      @ObjectModel.text.element: 'SequenceText'
  key plfl.zaehl                                                     as   BOOSqncInternalVersionCounter,

      // NOT a key field in THIS view !

      plfl.versn                                                     as   BillOfOperationsVersion,

      // ***************** Technical fields not on the CEWB-UI *****************


      plfl.loekz                                                     as   IsDeleted,
      plfl.loekz_inherited                                           as   IsImplicitlyDeleted,

      // *************************** Sequence Detail ***************************


      -- Sequence
      @ObjectModel.foreignKey.association: '_BillOfOperationsSequenceCat'
      plfl.flgat                                                     as   BillOfOperationsSequenceCat,

      @Semantics.text: true
      plfl.ltxa1                                                     as   SequenceText,

      @ObjectModel.foreignKey.association: '_SequenceSchedulingAlignment'
      plfl.auschl                                                    as   SequenceSchedulingAlignment,

      -- Reference
      @ObjectModel.foreignKey.association: '_BillOfOperationsRefSequence'
      plfl.bezfl                                                     as   BillOfOperationsRefSequence,

      @ObjectModel.foreignKey.association: '_BOOOperationsBranchOperation'
      plfl.bknt1                                                     as   BOOSqncBranchOpInternalID,
      @ObjectModel.foreignKey.association: '_BOOOperationsReturnOperation'
      plfl.bknt2                                                     as   BOOSqncReturnOpInternalID,

      -- Alternative Sequence
      //as of now the correct UoM cannot be determined in CDS views. Field needs to be kept for compatibility reasons.

      @Consumption.hidden: true
      cast(' ' as plnme)                                             as   BillOfOperationsUnit,  
      @DefaultAggregation: #MIN
      plfl.losvn                                                     as   MinimumLotSizeQuantity,
      @DefaultAggregation: #MAX
      plfl.losbs                                                     as   MaximumLotSizeQuantity,

      -- Administrative Data
      @ObjectModel.foreignKey.association: '_ChangeMaster'
      plfl.aennr                                                     as   ChangeNumber,

      @Semantics.businessDate.from: true
      cast(plfl.datuv  as pph_begda preserving type)                 as   ValidityStartDate,
      @Semantics.businessDate.to: true
      cast(plfl.valid_to as pph_endda preserving type)               as   ValidityEndDate,

      @Semantics.systemDate.createdAt: true
      plfl.andat                                                     as   CreationDate,
      cast(plfl.annam as vdm_createdbyuserid preserving type)        as   CreatedByUser,
      
      @Semantics.systemDate.lastChangedAt: true
      plfl.aedat                                                     as   LastChangeDate,
      cast(plfl.aenam as vdm_lastchangedbyuserid preserving type)    as   LastChangedByUser,

      // **************************** Associations *****************************


      _BOOOperationsBranchOperation,
      _BOOOperationsReturnOperation,
      _BillOfOperations,
      _BillOfOperationsGroup,
      _BillOfOperationsRefSequence,
      _BillOfOperationsSequence,
      _BillOfOperationsSequenceCat,
      _BillOfOperationsType,
      _ChangeMaster,
      _SequenceSchedulingAlignment
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"PLFL"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSOPERATION",
"I_BILLOFOPERATIONSSEQUENCE",
"I_BILLOFOPERATIONSSEQUENCECAT",
"I_BILLOFOPERATIONSTYPE",
"I_CHANGEMASTER",
"I_SEQUENCESCHEDULINGALIGNMENT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/