I_AssetSimulatedDueDeprValues

@AbapCatalog: {sqlViewName: 'IFASSETSIMDUEVAL', compiler.compareFilter: true, preserveKey: true}
@EndUserText.label: 'Simulated due depreciation of balance carry forward'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel: { usageType.serviceQuality: #C,
                usageType.sizeCategory: #XXL,
                usageType.dataClass: #MIXED }
@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_AssetSimulatedDueDeprValues
  as select from faat_plan_values as values
  association [1]    to I_LedgerCompanyCodeCrcyRoles as _LedgerCompanyCodeCrcyRoles on  $projection.Ledger      = _LedgerCompanyCodeCrcyRoles.Ledger
                                                                                    and $projection.CompanyCode = _LedgerCompanyCodeCrcyRoles.CompanyCode

  association [1]    to I_CompanyCode                as _CompanyCode                on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1]    to I_MasterFixedAsset           as _MasterFixedAsset           on  $projection.CompanyCode      = _MasterFixedAsset.CompanyCode
                                                                                    and $projection.MasterFixedAsset = _MasterFixedAsset.MasterFixedAsset
  association [1]    to I_FixedAsset                 as _FixedAsset                 on  $projection.CompanyCode      = _FixedAsset.CompanyCode
                                                                                    and $projection.FixedAsset       = _FixedAsset.FixedAsset
                                                                                    and $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset
  association [1]    to I_DepreciationAreaForLedger  as _AssetDepreciationArea      on  $projection.CompanyCode           = _AssetDepreciationArea.CompanyCode
                                                                                    and $projection.Ledger                = _AssetDepreciationArea.Ledger
                                                                                    and $projection.AssetDepreciationArea = _AssetDepreciationArea.AssetDepreciationArea
  association [1]    to I_SubLedgerAccLineItemType   as _SubLedgerAccLineItemType   on  $projection.SubLedgerAcctLineItemType = _SubLedgerAccLineItemType.SubLedgerAcctLineItemType
  association [1]    to I_FiscalYearForCompanyCode   as _FiscalYear                 on  $projection.FiscalYear  = _FiscalYear.FiscalYear
                                                                                    and $projection.CompanyCode = _FiscalYear.CompanyCode
  association [1]    to I_AssetTransactionType       as _AssetTransactionType       on  $projection.AssetTransactionType = _AssetTransactionType.AssetTransactionType
  association [1]    to I_MovementCategory           as _AssetAcctTransClassfctn    on  $projection.AssetAcctTransClassfctn = _AssetAcctTransClassfctn.AssetAcctTransClassfctn
  association [1]    to I_Ledger                     as _Ledger                     on  $projection.Ledger = _Ledger.Ledger
  association [0..1] to I_LedgerGroup                as _LedgerGroup                on  $projection.LedgerGroup = _LedgerGroup.LedgerGroup
  association [1]    to I_AccountingPrinciple        as _AccountingPrinciple        on  $projection.accountingprinciple = _AccountingPrinciple.AccountingPrinciple
  association [0..1] to I_Currency                   as _CompanyCodeCurrency        on  $projection.CompanyCodeCurrency = _CompanyCodeCurrency.Currency
  association [0..1] to I_Currency                   as _GlobalCurrency             on  $projection.GlobalCurrency = _GlobalCurrency.Currency
  association [0..1] to I_Currency                   as _FreeDefinedCurrency1       on  $projection.FreeDefinedCurrency1 = _FreeDefinedCurrency1.Currency
  association [0..1] to I_Currency                   as _FreeDefinedCurrency2       on  $projection.FreeDefinedCurrency2 = _FreeDefinedCurrency2.Currency
  association [0..1] to I_Currency                   as _FreeDefinedCurrency3       on  $projection.FreeDefinedCurrency3 = _FreeDefinedCurrency3.Currency
  association [0..1] to I_Currency                   as _FreeDefinedCurrency4       on  $projection.FreeDefinedCurrency4 = _FreeDefinedCurrency4.Currency
  association [0..1] to I_Currency                   as _FreeDefinedCurrency5       on  $projection.FreeDefinedCurrency5 = _FreeDefinedCurrency5.Currency
  association [0..1] to I_Currency                   as _FreeDefinedCurrency6       on  $projection.FreeDefinedCurrency6 = _FreeDefinedCurrency6.Currency
  association [0..1] to I_Currency                   as _FreeDefinedCurrency7       on  $projection.FreeDefinedCurrency7 = _FreeDefinedCurrency7.Currency
  association [0..1] to I_Currency                   as _FreeDefinedCurrency8       on  $projection.FreeDefinedCurrency8 = _FreeDefinedCurrency8.Currency
{
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key values.bukrs                    as CompanyCode,
      @ObjectModel.foreignKey.association: '_MasterFixedAsset'
  key values.anln1                    as MasterFixedAsset,
      @ObjectModel.foreignKey.association: '_FixedAsset'
  key values.anln2                    as FixedAsset,
      @ObjectModel.foreignKey.association: '_AssetDepreciationArea'
  key values.afabe                    as AssetDepreciationArea,
      @ObjectModel.foreignKey.association: '_SubledgerAccLineItemType'
  key values.slalittype               as SubLedgerAcctLineItemType,
      @ObjectModel.foreignKey.association: '_FiscalYear'
  key values.gjahr                    as FiscalYear,
  key values.poper                    as FiscalPeriod,

      @Semantics.fiscal.year: true
      cast(values.gjahr as gjahr_pos) as LedgerFiscalYear,
      @ObjectModel.foreignKey.association: '_AssetTransactionType'
      cast('999' as anbwa)            as AssetTransactionType,
      @ObjectModel.foreignKey.association: '_AssetAcctTransClassfctn'
      cast('00' as faa_movcat)        as AssetAcctTransClassfctn,
      @ObjectModel.foreignKey.association: '_Ledger'
      values.rldnr                    as Ledger,
      @ObjectModel.foreignKey.association: '_LedgerGroup'
      values.ldgrp                    as LedgerGroup,
      @ObjectModel.foreignKey.association: '_AccountingPrinciple'
      _LedgerCompanyCodeCrcyRoles.AccountingPrinciple,

      values.anlgr                    as GroupMasterFixedAsset,
      values.anlgr2                   as GroupFixedAsset,

      @Semantics.currencyCode:true
      @ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
      values.rhcur                    as CompanyCodeCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      values.hsl                      as AmountInCompanyCodeCurrency,

      @Semantics.currencyCode:true
      @ObjectModel.foreignKey.association: '_GlobalCurrency'
      values.rkcur                    as GlobalCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      values.ksl                      as AmountInGlobalCurrency,

      @Semantics.currencyCode:true
      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency1'
      values.rocur                    as FreeDefinedCurrency1,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
      values.osl                      as AmountInFreeDefinedCurrency1,

      @Semantics.currencyCode:true
      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency2'
      values.rvcur                    as FreeDefinedCurrency2,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
      values.vsl                      as AmountInFreeDefinedCurrency2,

      @Semantics.currencyCode:true
      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency3'
      values.rbcur                    as FreeDefinedCurrency3,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
      values.bsl                      as AmountInFreeDefinedCurrency3,

      @Semantics.currencyCode:true
      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency4'
      values.rccur                    as FreeDefinedCurrency4,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
      values.csl                      as AmountInFreeDefinedCurrency4,

      @Semantics.currencyCode:true
      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency5'
      values.rdcur                    as FreeDefinedCurrency5,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
      values.dsl                      as AmountInFreeDefinedCurrency5,

      @Semantics.currencyCode:true
      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency6'
      values.recur                    as FreeDefinedCurrency6,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
      values.esl                      as AmountInFreeDefinedCurrency6,

      @Semantics.currencyCode:true
      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency7'
      values.rfcur                    as FreeDefinedCurrency7,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
      values.fsl                      as AmountInFreeDefinedCurrency7,

      @Semantics.currencyCode:true
      @ObjectModel.foreignKey.association: '_FreeDefinedCurrency8'
      values.rgcur                    as FreeDefinedCurrency8,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
      values.gsl                      as AmountInFreeDefinedCurrency8,

      _CompanyCode,
      _MasterFixedAsset,
      _FixedAsset,
      _AssetDepreciationArea,
      _SubLedgerAccLineItemType,
      _FiscalYear,
      _AssetTransactionType,
      _AssetAcctTransClassfctn,
      _Ledger,
      _LedgerGroup,
      _AccountingPrinciple,
      _CompanyCodeCurrency,
      _GlobalCurrency,
      _FreeDefinedCurrency1,
      _FreeDefinedCurrency2,
      _FreeDefinedCurrency3,
      _FreeDefinedCurrency4,
      _FreeDefinedCurrency5,
      _FreeDefinedCurrency6,
      _FreeDefinedCurrency7,
      _FreeDefinedCurrency8
}
where
  values.movcat = '00'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LEDGERCOMPANYCODECRCYROLES",
"FAAT_PLAN_VALUES"
],
"ASSOCIATED":
[
"I_ACCOUNTINGPRINCIPLE",
"I_ASSETTRANSACTIONTYPE",
"I_COMPANYCODE",
"I_CURRENCY",
"I_DEPRECIATIONAREAFORLEDGER",
"I_FISCALYEARFORCOMPANYCODE",
"I_FIXEDASSET",
"I_LEDGER",
"I_LEDGERCOMPANYCODECRCYROLES",
"I_LEDGERGROUP",
"I_MASTERFIXEDASSET",
"I_MOVEMENTCATEGORY",
"I_SUBLEDGERACCLINEITEMTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/