I_AllocationTableItemRecipient

@AbapCatalog.sqlViewName: 'IALLOCTBLITRCPNT'
@EndUserText.label: 'Allocation Table Item Recipient' // Recipient are Stores and DCs but also external Customers


@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl: {
    authorizationCheck: #CHECK,
    personalData.blocking: #REQUIRED
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #BASIC
@ObjectModel: {
    representativeKey: 'AllocationTableItemRecipient',
    usageType: {
        serviceQuality: #A,
        sizeCategory: #L,
        dataClass: #TRANSACTIONAL
    }
}

define view I_AllocationTableItemRecipient
  as select from aufi
  association [1..1] to I_AllocationTable              as _AllocationTable              on  $projection.AllocationTable = _AllocationTable.AllocationTable
  association [1..1] to I_AllocationTableItem          as _AllocationTableItem          on  $projection.AllocationTable     = _AllocationTableItem.AllocationTable
                                                                                        and $projection.AllocationTableItem = _AllocationTableItem.AllocationTableItem
  association [1..1] to I_AllocationTableItemRcpntGrp  as _AllocationTableItemRcpntGrp  on  $projection.AllocationTable             = _AllocationTableItemRcpntGrp.AllocationTable
                                                                                        and $projection.AllocationTableItem         = _AllocationTableItemRcpntGrp.AllocationTableItem
                                                                                        and $projection.AllocationTableItemRcpntGrp = _AllocationTableItemRcpntGrp.AllocationTableItemRcpntGrp
  association [0..1] to I_AllocationTableItemRcpntSts  as _AllocationTableItemRcpntSts  on  $projection.AllocationTable              = _AllocationTableItemRcpntSts.AllocationTable
                                                                                        and $projection.AllocationTableItem          = _AllocationTableItemRcpntSts.AllocationTableItem
                                                                                        and $projection.AllocationTableItemRcpntGrp  = _AllocationTableItemRcpntSts.AllocationTableItemRcpntGrp
                                                                                        and $projection.AllocationTableItemRecipient = _AllocationTableItemRcpntSts.AllocationTableItemRecipient
  association [0..*] to I_AllocationTableDeliveryPhase as _AllocationTableDeliveryPhase on  $projection.AllocationTable              = _AllocationTableDeliveryPhase.AllocationTable
                                                                                        and $projection.AllocationTableItem          = _AllocationTableDeliveryPhase.AllocationTableItem
                                                                                        and $projection.AllocationTableItemRcpntGrp  = _AllocationTableDeliveryPhase.AllocationTableItemRcpntGrp
                                                                                        and $projection.AllocationTableItemRecipient = _AllocationTableDeliveryPhase.AllocationTableItemRecipient

  association [0..1] to I_Site                         as _Site                         on  $projection.Site = _Site.Site
  association [0..1] to I_Customer                     as _Customer                     on  $projection.Customer = _Customer.Customer
  association [0..1] to I_Site                         as _DistributionCenter           on  $projection.DistributionCenter = _DistributionCenter.Site
  association [0..1] to I_Supplier                     as _Supplier                     on  $projection.Supplier = _Supplier.Supplier
  association [0..1] to I_OutboundDelivery             as _OutboundDelivery             on  $projection.OutboundDelivery = _OutboundDelivery.OutboundDelivery
  association [0..1] to I_OutboundDeliveryItem         as _OutboundDeliveryItem         on  $projection.OutboundDelivery     = _OutboundDeliveryItem.OutboundDelivery
                                                                                        and $projection.OutboundDeliveryItem = _OutboundDeliveryItem.OutboundDeliveryItem
  association [0..1] to I_PurchaseOrder                as _PurchaseOrder                on  $projection.PurchaseOrder = _PurchaseOrder.PurchaseOrder
  association [0..1] to I_PurchaseOrderItem            as _PurchaseOrderItem            on  $projection.PurchaseOrder     = _PurchaseOrderItem.PurchaseOrder
                                                                                        and $projection.PurchaseOrderItem = _PurchaseOrderItem.PurchaseOrderItem
  association [0..1] to I_StockTransportOrder          as _StockTransportOrder          on  $projection.StockTransportOrder = _StockTransportOrder.PurchaseOrder
  association [0..1] to I_StockTransportOrderItem      as _StockTransportOrderItem      on  $projection.StockTransportOrder     = _StockTransportOrderItem.PurchaseOrder
                                                                                        and $projection.StockTransportOrderItem = _StockTransportOrderItem.PurchaseOrderItem
  association [0..1] to I_UnitOfMeasure                as _QuantityUnit                 on  $projection.QuantityUnit = _QuantityUnit.UnitOfMeasure

{
      @ObjectModel.foreignKey.association: '_AllocationTable'
  key abeln                                                        as AllocationTable,
      @ObjectModel.foreignKey.association: '_AllocationTableItem'
  key abelp                                                        as AllocationTableItem,
      @ObjectModel.foreignKey.association: '_AllocationTableItemRcpntGrp'
  key abelg                                                        as AllocationTableItemRcpntGrp,
  key abelf                                                        as AllocationTableItemRecipient,

      @ObjectModel.foreignKey.association: '_Site'
      fiwrk                                                        as Site,
      @ObjectModel.foreignKey.association: '_Customer'
      filnr                                                        as Customer,
      @ObjectModel.foreignKey.association: '_DistributionCenter'
      vzwrk                                                        as DistributionCenter, 

      @ObjectModel.foreignKey.association: '_Supplier'
      cast(lfnru as md_supplier preserving type)                   as Supplier,

      @ObjectModel.foreignKey.association: '_OutboundDelivery'
      cast(vblnu as outbound_delivery preserving type)             as OutboundDelivery,
      @ObjectModel.foreignKey.association: '_OutboundDeliveryItem'
      cast(vblpu as outbound_delivery_item preserving type)        as OutboundDeliveryItem,

      @ObjectModel.foreignKey.association: '_PurchaseOrder'
      cast(eblnu as vdm_purchaseorder preserving type)             as PurchaseOrder,
      @ObjectModel.foreignKey.association: '_PurchaseOrderItem'
      cast(eblpu as vdm_purchaseorderitem preserving type )        as PurchaseOrderItem,

      @ObjectModel.foreignKey.association: '_StockTransportOrder'
      cast(ubstn as vdm_stocktransportorder preserving type )      as StockTransportOrder,
      @ObjectModel.foreignKey.association: '_StockTransportOrderItem'
      cast(ubstp as vdm_stocktransportorderitem preserving type )  as StockTransportOrderItem,

      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      pmngu                                                        as PlannedQuantity,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      imngu                                                        as ConfirmedQuantity,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_QuantityUnit'
      aufme                                                        as QuantityUnit,

      _Site,
      _Customer,
      _DistributionCenter,
      _Supplier,
      _OutboundDelivery,
      _OutboundDeliveryItem,
      _PurchaseOrder,
      _PurchaseOrderItem,
      _StockTransportOrder,
      _StockTransportOrderItem,
      _QuantityUnit,

      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
      _AllocationTable,
      _AllocationTableItem,
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]
      _AllocationTableItemRcpntGrp,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _AllocationTableDeliveryPhase,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _AllocationTableItemRcpntSts

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"AUFI"
],
"ASSOCIATED":
[
"I_ALLOCATIONTABLE",
"I_ALLOCATIONTABLEDELIVERYPHASE",
"I_ALLOCATIONTABLEITEM",
"I_ALLOCATIONTABLEITEMRCPNTGRP",
"I_ALLOCATIONTABLEITEMRCPNTSTS",
"I_CUSTOMER",
"I_OUTBOUNDDELIVERY",
"I_OUTBOUNDDELIVERYITEM",
"I_PURCHASEORDER",
"I_PURCHASEORDERITEM",
"I_SITE",
"I_STOCKTRANSPORTORDER",
"I_STOCKTRANSPORTORDERITEM",
"I_SUPPLIER",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/