I_AllocationTableDeliveryPhase

@AbapCatalog.sqlViewName: 'IALLOCTBLDELIVPH'
@EndUserText.label: 'Allocation Table Delivery Phase'

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #BASIC
@ObjectModel: {
    representativeKey: 'AllocationTableDeliveryPhase',
    usageType.serviceQuality: #A,
    usageType.sizeCategory: #L,
    usageType.dataClass: #TRANSACTIONAL
}

define view I_AllocationTableDeliveryPhase
  as select from aulw
  association [1..1] to I_AllocationTable              as _AllocationTable              on  $projection.AllocationTable = _AllocationTable.AllocationTable
  association [1..1] to I_AllocationTableItem          as _AllocationTableItem          on  $projection.AllocationTable     = _AllocationTableItem.AllocationTable
                                                                                        and $projection.AllocationTableItem = _AllocationTableItem.AllocationTableItem
  association [1..1] to I_AllocationTableItemRcpntGrp  as _AllocationTableItemRcpntGrp  on  $projection.AllocationTable             = _AllocationTableItemRcpntGrp.AllocationTable
                                                                                        and $projection.AllocationTableItem         = _AllocationTableItemRcpntGrp.AllocationTableItem
                                                                                        and $projection.AllocationTableItemRcpntGrp = _AllocationTableItemRcpntGrp.AllocationTableItemRcpntGrp
  association [1..1] to I_AllocationTableItemRecipient as _AllocationTableItemRecipient on  $projection.AllocationTable              = _AllocationTableItemRecipient.AllocationTable
                                                                                        and $projection.AllocationTableItem          = _AllocationTableItemRecipient.AllocationTableItem
                                                                                        and $projection.AllocationTableItemRcpntGrp  = _AllocationTableItemRecipient.AllocationTableItemRcpntGrp
                                                                                        and $projection.AllocationTableItemRecipient = _AllocationTableItemRecipient.AllocationTableItemRecipient
  association [0..1] to I_OutboundDelivery             as _OutboundDelivery             on  $projection.OutboundDelivery = _OutboundDelivery.OutboundDelivery
  association [0..1] to I_OutboundDeliveryItem         as _OutboundDeliveryItem         on  $projection.OutboundDelivery     = _OutboundDeliveryItem.OutboundDelivery
                                                                                        and $projection.OutboundDeliveryItem = _OutboundDeliveryItem.OutboundDeliveryItem
  association [0..1] to I_PurchaseOrder                as _PurchaseOrder                on  $projection.PurchaseOrder = _PurchaseOrder.PurchaseOrder
  association [0..1] to I_PurchaseOrderItem            as _PurchaseOrderItem            on  $projection.PurchaseOrder     = _PurchaseOrderItem.PurchaseOrder
                                                                                        and $projection.PurchaseOrderItem = _PurchaseOrderItem.PurchaseOrderItem
  association [0..1] to I_StockTransportOrder          as _StockTransportOrder          on  $projection.StockTransportOrder = _StockTransportOrder.PurchaseOrder
  association [0..1] to I_StockTransportOrderItem      as _StockTransportOrderItem      on  $projection.StockTransportOrder     = _StockTransportOrderItem.PurchaseOrder
                                                                                        and $projection.StockTransportOrderItem = _StockTransportOrderItem.PurchaseOrderItem
  association [0..1] to I_SalesOrder                   as _SalesOrder                   on  $projection.SalesOrder = _SalesOrder.SalesOrder
  association [0..1] to I_SalesOrderItem               as _SalesOrderItem               on  $projection.SalesOrder     = _SalesOrderItem.SalesOrder
                                                                                        and $projection.SalesOrderItem = _SalesOrderItem.SalesOrderItem
{
      @ObjectModel.foreignKey.association: '_AllocationTable'
  key abeln                                                       as AllocationTable,
      @ObjectModel.foreignKey.association: '_AllocationTableItem'
  key abelp                                                       as AllocationTableItem,
      @ObjectModel.foreignKey.association: '_AllocationTableItemRcpntGrp'
  key abelg                                                       as AllocationTableItemRcpntGrp,
      @ObjectModel.foreignKey.association: '_AllocationTableItemRecipient'
  key abelf                                                       as AllocationTableItemRecipient,
  key lwnum                                                       as AllocationTableDeliveryPhase,

      cast(wedat as deliverydate preserving type)                 as DeliveryDate,

      @ObjectModel.foreignKey.association: '_OutboundDelivery'
      cast(vblnu as outbound_delivery preserving type)            as OutboundDelivery,
      @ObjectModel.foreignKey.association: '_OutboundDeliveryItem'
      cast(vblpu as outbound_delivery_item preserving type)       as OutboundDeliveryItem,

      @ObjectModel.foreignKey.association: '_PurchaseOrder'
      cast(eblnu as vdm_purchaseorder preserving type)            as PurchaseOrder,
      @ObjectModel.foreignKey.association: '_PurchaseOrderItem'
      cast(eblpu as vdm_purchaseorderitem preserving type )       as PurchaseOrderItem,

      @ObjectModel.foreignKey.association: '_StockTransportOrder'
      cast(ubstn as vdm_stocktransportorder preserving type )     as StockTransportOrder,
      @ObjectModel.foreignKey.association: '_StockTransportOrderItem'
      cast(ubstp as vdm_stocktransportorderitem preserving type ) as StockTransportOrderItem,

      @ObjectModel.foreignKey.association: '_SalesOrder'
      vbeln_gka                                                   as SalesOrder,
      @ObjectModel.foreignKey.association: '_SalesOrderItem'
      vbelp_gka                                                   as SalesOrderItem,

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _AllocationTable,
      _AllocationTableItem,
      _AllocationTableItemRcpntGrp,
      _AllocationTableItemRecipient,
      _OutboundDelivery,
      _OutboundDeliveryItem,
      _PurchaseOrder,
      _PurchaseOrderItem,
      _StockTransportOrder,
      _StockTransportOrderItem,
      _SalesOrder,
      _SalesOrderItem
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"AULW"
],
"ASSOCIATED":
[
"I_ALLOCATIONTABLE",
"I_ALLOCATIONTABLEITEM",
"I_ALLOCATIONTABLEITEMRCPNTGRP",
"I_ALLOCATIONTABLEITEMRECIPIENT",
"I_OUTBOUNDDELIVERY",
"I_OUTBOUNDDELIVERYITEM",
"I_PURCHASEORDER",
"I_PURCHASEORDERITEM",
"I_SALESORDER",
"I_SALESORDERITEM",
"I_STOCKTRANSPORTORDER",
"I_STOCKTRANSPORTORDERITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/