FMUSFGA_FROM_ACDOCA_CCFWD

@AbapCatalog.sqlViewName: 'FMUSFGA_ACDOCCV'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: false
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Ledger 95 data from ACDOCA for correction/close postings'
@AbapCatalog.viewEnhancementCategory: [#UNION, #PROJECTION_LIST]
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.personalData.blocking
@ClientHandling.algorithm: #SESSION_VARIABLE

define view FMUSFGA_FROM_ACDOCA_CCFWD
  as select from FMUSFGA_COMPAT
{
  rclnt,
  gl_sirid,
  rldnr,
  rrcty,
  rvers,
  ryear,
  rtcur,
  drcrk,
  poper,
  docct,
  docnr,
  docln,
  rbukrs,
  racct,
  rbusa,
  rprctr,
  rcntr,
  rprojk,
  rfarea,
  rfund
}

union all select from acdoca
  inner join          fmfg_uj_activ as activation on acdoca.rclnt = activation.client
association        to finsc_ledger                    on  finsc_ledger.rldnr    = acdoca.rldnr
                                                      and finsc_ledger.xleading = 'X' // Leading ledger only

association [0..1] to prps                            on  acdoca.ps_pspid = prps.posid // To get correct format to replace FMUSFGA.PROJK

association [0..1] to finsc_period                    on  finsc_period.fiscal_year_variant = acdoca.periv
                                                      and finsc_period.fiscal_year         = acdoca.ryear
                                                      and finsc_period.fiscal_period       = acdoca.poper
association [0..1] to finsc_period as _finsc_period_0 on  _finsc_period_0.fiscal_year_variant = acdoca.periv
                                                      and _finsc_period_0.fiscal_year         = acdoca.ryear
                                                      and _finsc_period_0.fiscal_period       = '001'
{
  rclnt,
  cast('000000000000000000' as abap.char( 18 ))                                                as gl_sirid,
  cast('95' as abap.char(2))                                                                   as rldnr,
  rrcty,
  cast('001' as abap.char(3))                                                                  as rvers,
  ryear,
  rtcur,
  drcrk,
  poper,
  'S'                                                                                          as docct,
  acdoca.belnr                                                                                 as docnr,
  docln,
  rbukrs,
  racct,
  rbusa,
  acdoca.prctr                                                                                 as rprctr,
  rcntr,
  prps.pspnr                                                                                   as rprojk,
  rfarea,
  rfund
}
where
      activation.uj_activation_timestamp <= acdoca.timestamp // Entered on or after UL activation

  and bstat                              =  'C' // Correction and c/fwd type items only

  and acdoca.rldnr = finsc_ledger.rldnr
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FMUSFGA_COMPAT",
"ACDOCA",
"FINSC_LEDGER",
"FMFG_UJ_ACTIV",
"PRPS"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/