FMUSFGA_COMPAT

@AbapCatalog.sqlViewName: 'FMUSFGA_COMPAT_V'
@ClientHandling.algorithm: #AUTOMATED  // SESSION_VARIABLE causes short dump with CLIENT-SPECIFIED

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.viewEnhancementCategory: [#UNION, #PROJECTION_LIST]
@AbapCatalog.preserveKey:false
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Compatibility view for FMUSFGA replace with ACDOCA'

define view FMUSFGA_COMPAT
  as select from fmusfga
{
  rclnt,
  gl_sirid,
  rldnr,
  rrcty,
  rvers,
  ryear,
  rtcur,
  drcrk,
  poper,
  docct,
  docnr,
  docln,
  rbukrs,
  racct,
  rbusa,
  rprctr,
  rcntr,
  rprojk,
  rfarea,
  rfund
}

union all

select from  acdoca
  inner join fmfg_uj_activ as activation on acdoca.rclnt = activation.client
association [1..1] to finsc_ledger on  acdoca.rldnr          = finsc_ledger.rldnr
                                   and finsc_ledger.xleading = 'X' // Leading ledger only

association [1..1] to bkpf         on  acdoca.rbukrs = bkpf.bukrs // TO GET HEADER FIELDS NOT DUPLICATED IN ACDOCA

                                   and acdoca.gjahr  = bkpf.gjahr
                                   and acdoca.belnr  = bkpf.belnr
association [0..1] to prps         on  acdoca.ps_posid = prps.posid // TO GET CORRECT FORMAT TO REPLACE FMUSFGA.PROJK


{
  rclnt,
  cast('000000000000000000' as abap.char( 18 ))                                           as gl_sirid,
  cast('95' as abap.char(2))                                                              as rldnr,
  rrcty,
  cast('001' as abap.char(3))                                                             as rvers,
  ryear,
  rtcur,
  drcrk,
  poper,
  'S'                                                                                     as docct,
  acdoca.belnr                                                                            as docnr,
  docln,
  rbukrs,
  racct,
  rbusa,
  acdoca.prctr                                                                            as rprctr,
  rcntr,
  prps.pspnr                                                                              as rprojk,
  rfarea,
  rfund
}
where
       activation.uj_activation_timestamp <= acdoca.timestamp // Entered on or after UL activation

  and  acdoca.rldnr = finsc_ledger.rldnr
  and(
       bstat = ' '
   or  bstat = 'L'
   or  bstat = 'U'
   or  bstat = 'J'
   or  bstat = 'T'
   or (bstat = 'C' and poper = '000')  
  ) // Normal/clearing/reset clearing/noted items only

  // Updated with new bstat values based on feedback from FI (Ruediger)

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"ACDOCA",
"FINSC_LEDGER",
"FMFG_UJ_ACTIV",
"FMUSFGA",
"PRPS"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/