FAC_CDS_FH_COMPANYCODE
Company Code in Flexible Hierarchy
FAC_CDS_FH_COMPANYCODE is a CDS View that provides data about "Company Code in Flexible Hierarchy" in SAP S/4HANA. It reads from 1 data source (t001) and exposes 48 fields with key field CompanyCode. It has 9 associations to related views.
Data Sources (1)
| Source | Alias | Join Type |
|---|---|---|
| t001 | t001 | from |
Associations (9)
| Cardinality | Target | Alias | Condition |
|---|---|---|---|
| [0..1] | I_Currency | _Currency | $projection.Currency = _Currency.Currency |
| [0..1] | I_Country | _Country | $projection.Country = _Country.Country |
| [0..1] | I_Language | _Language | $projection.Language = _Language.Language |
| [0..1] | I_ChartOfAccounts | _ChartOfAccounts | $projection.ChartOfAccounts = _ChartOfAccounts.ChartOfAccounts |
| [0..1] | I_FiscalYearVariant | _FiscalYearVariant | $projection.FiscalYearVariant = _FiscalYearVariant.FiscalYearVariant |
| [0..1] | I_ChartOfAccounts | _CountryChartOfAccounts | $projection.CountryChartOfAccounts = _CountryChartOfAccounts.ChartOfAccounts |
| [0..1] | I_CreditControlArea | _CreditControlArea | $projection.CreditControlArea = _CreditControlArea.CreditControlArea |
| [0..1] | I_FieldStatusVariant | _FieldStatusVariant | $projection.FieldStatusVariant = _FieldStatusVariant.FieldStatusVariant |
| [0..1] | I_Globalcompany | _GlobalCompany | $projection.Company = _GlobalCompany.Company |
Annotations (6)
| Name | Value | Level | Field |
|---|---|---|---|
| AbapCatalog.sqlViewName | FACV_FH_COCD | view | |
| AccessControl.authorizationCheck | #NOT_REQUIRED | view | |
| EndUserText.label | Company Code in Flexible Hierarchy | view | |
| ObjectModel.usageType.dataClass | #MASTER | view | |
| ObjectModel.usageType.serviceQuality | #D | view | |
| ObjectModel.usageType.sizeCategory | #L | view |
Fields (48)
| Key | Field | Source Table | Source Field | Description |
|---|---|---|---|---|
| KEY | CompanyCode | t001 | bukrs | |
| Country | t001 | land1 | Country/Region Key | |
| CityName | t001 | ort01 | ||
| Currency | t001 | waers | ||
| Language | t001 | spras | ||
| ChartOfAccounts | t001 | ktopl | ||
| CountryChartOfAccounts | t001 | ktop2 | ||
| Company | t001 | rcomp | ||
| FinancialManagementArea | t001 | fikrs | ||
| CreditControlArea | t001 | kkber | ||
| FiscalYearVariant | t001 | periv | ||
| IsProductive | t001 | xprod | ||
| ScreenVariant | t001 | buvar | ||
| FieldStatusVariant | t001 | fstva | ||
| PostingPeriodVariant | t001 | opvar | ||
| WorkflowVariant | t001 | wfvar | ||
| CostOfSalesAccountingStatus | t001 | xcos | ||
| AddressID | t001 | adrnr | ||
| CompanyCode_T | t001 | butxt | ||
| Currency_T | ||||
| Language_T | ||||
| Country_T | ||||
| ChartOfAccounts_T | ||||
| FiscalYearVariant_T | ||||
| CountryChartOfAccounts_T | ||||
| CreditControlArea_T | ||||
| FieldStatusVariant_T | ||||
| Company_T | _GlobalCompany | CompanyName | ||
| CompanyCode_L_T | ||||
| Currency_L_T | ||||
| Language_L_T | ||||
| Country_L_T | ||||
| ChartOfAccounts_L_T | ||||
| FiscalYearVariant_L_T | ||||
| CountryChartOfAccounts_L_T | ||||
| CreditControlArea_L_T | ||||
| FieldStatusVariant_L_T | ||||
| Company_L_T | ||||
| NodeTextUpper | ||||
| _Currency | _Currency | |||
| _Country | _Country | |||
| _Language | _Language | |||
| _ChartOfAccounts | _ChartOfAccounts | |||
| _CountryChartOfAccounts | _CountryChartOfAccounts | |||
| _FiscalYearVariant | _FiscalYearVariant | |||
| _CreditControlArea | _CreditControlArea | |||
| _FieldStatusVariant | _FieldStatusVariant | |||
| _GlobalCompany | _GlobalCompany |
@AbapCatalog.sqlViewName: 'FACV_FH_COCD'
//@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Company Code in Flexible Hierarchy'
@ObjectModel.usageType: {
dataClass: #MASTER,
serviceQuality: #D,
sizeCategory: #L
}
//@VDM.viewType: #CONSUMPTION
define view FAC_CDS_FH_COMPANYCODE
as select from t001
association [0..1] to I_Currency as _Currency on $projection.Currency = _Currency.Currency
association [0..1] to I_Country as _Country on $projection.Country = _Country.Country
association [0..1] to I_Language as _Language on $projection.Language = _Language.Language
association [0..1] to I_ChartOfAccounts as _ChartOfAccounts on $projection.ChartOfAccounts = _ChartOfAccounts.ChartOfAccounts
association [0..1] to I_FiscalYearVariant as _FiscalYearVariant on $projection.FiscalYearVariant = _FiscalYearVariant.FiscalYearVariant
association [0..1] to I_ChartOfAccounts as _CountryChartOfAccounts on $projection.CountryChartOfAccounts = _CountryChartOfAccounts.ChartOfAccounts
//association [0..1] to I_ControllingArea as _ControllingArea on $projection.ControllingArea = _ControllingArea.ControllingArea
association [0..1] to I_CreditControlArea as _CreditControlArea on $projection.CreditControlArea = _CreditControlArea.CreditControlArea
association [0..1] to I_FieldStatusVariant as _FieldStatusVariant on $projection.FieldStatusVariant = _FieldStatusVariant.FieldStatusVariant
association [0..1] to I_Globalcompany as _GlobalCompany on $projection.Company = _GlobalCompany.Company
{
key t001.bukrs as CompanyCode,
// t001.butxt as CompanyCodeName,
@EndUserText.label: 'Country/Region Key'
t001.land1 as Country,
t001.ort01 as CityName,
t001.waers as Currency,
t001.spras as Language,
t001.ktopl as ChartOfAccounts,
t001.ktop2 as CountryChartOfAccounts,
t001.rcomp as Company,
t001.fikrs as FinancialManagementArea,
t001.kkber as CreditControlArea,
t001.periv as FiscalYearVariant,
// t001.bukrs_glob as GlobalCompanyCode,
t001.xprod as IsProductive,
t001.buvar as ScreenVariant,
t001.fstva as FieldStatusVariant,
t001.opvar as PostingPeriodVariant,
t001.wfvar as WorkflowVariant,
t001.xcos as CostOfSalesAccountingStatus,
t001.adrnr as AddressID,
//add text field for flexible hierarchy
t001.butxt as CompanyCode_T,
_Currency._Text[1:Language = $session.system_language].CurrencyName as Currency_T,
_Language._Text[1:Language = $session.system_language].LanguageName as Language_T,
_Country._Text[1:Language = $session.system_language].CountryName as Country_T,
_ChartOfAccounts._Text[1:Language = $session.system_language].ChartOfAccountsName as ChartOfAccounts_T,
_FiscalYearVariant._Text[1:Language = $session.system_language].FiscalYearVariantDescription as FiscalYearVariant_T,
_CountryChartOfAccounts._Text[1:Language = $session.system_language].ChartOfAccountsName as CountryChartOfAccounts_T,
_CreditControlArea._Text[1:Language = $session.system_language].CreditControlAreaName as CreditControlArea_T,
_FieldStatusVariant._Text[1:Language = $session.system_language].FieldStatusVariantName as FieldStatusVariant_T,
_GlobalCompany.CompanyName as Company_T,
cast(concat(bukrs, concat(concat (' (', t001.butxt ), ')') ) as fac_fh_char60) as CompanyCode_L_T,
cast(concat(waers, concat(concat (' (', _Currency._Text[1:Language = $session.system_language].CurrencyName ), ')')) as fac_fh_char60) as Currency_L_T,
cast(concat(spras, concat(concat (' (', _Language._Text[1:Language = $session.system_language].LanguageName ), ')')) as fac_fh_char60) as Language_L_T,
cast(concat(land1, concat(concat (' (', _Country._Text[1:Language = $session.system_language].CountryName ), ')')) as fac_fh_char60) as Country_L_T,
cast(concat(ktopl, concat(concat (' (', _ChartOfAccounts._Text[1:Language = $session.system_language].ChartOfAccountsName ), ')')) as fac_fh_char60) as ChartOfAccounts_L_T,
cast(concat(periv, concat(concat (' (', _FiscalYearVariant._Text[1:Language = $session.system_language].FiscalYearVariantDescription ), ')')) as fac_fh_char60) as FiscalYearVariant_L_T,
cast(concat(ktop2, concat(concat (' (', _CountryChartOfAccounts._Text[1:Language = $session.system_language].ChartOfAccountsName ), ')')) as fac_fh_char60) as CountryChartOfAccounts_L_T,
cast(concat(kkber, concat(concat (' (', _CreditControlArea._Text[1:Language = $session.system_language].CreditControlAreaName ), ')')) as fac_fh_char60) as CreditControlArea_L_T,
cast(concat(fstva, concat(concat (' (', _FieldStatusVariant._Text[1:Language = $session.system_language].FieldStatusVariantName ), ')')) as fac_fh_char60) as FieldStatusVariant_L_T,
cast(concat(rcomp, concat(concat (' (', _GlobalCompany.CompanyName ), ')') ) as fac_fh_char60) as Company_L_T,
cast(upper(t001.butxt) as butxt ) as NodeTextUpper,
_Currency,
_Country,
_Language,
_ChartOfAccounts,
_CountryChartOfAccounts,
_FiscalYearVariant,
// _ControllingArea,
_CreditControlArea,
_FieldStatusVariant,
_GlobalCompany
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHARTOFACCOUNTS",
"I_CHARTOFACCOUNTSTEXT",
"I_COUNTRY",
"I_COUNTRYTEXT",
"I_CREDITCONTROLAREA",
"I_CREDITCONTROLAREATEXT",
"I_CURRENCY",
"I_CURRENCYTEXT",
"I_FIELDSTATUSVARIANT",
"I_FIELDSTATUSVARIANTTEXT",
"I_FISCALYEARVARIANT",
"I_FISCALYEARVARIANTTEXT",
"I_GLOBALCOMPANY",
"I_LANGUAGE",
"I_LANGUAGETEXT",
"T001"
],
"ASSOCIATED":
[
"I_CHARTOFACCOUNTS",
"I_COUNTRY",
"I_CREDITCONTROLAREA",
"I_CURRENCY",
"I_FIELDSTATUSVARIANT",
"I_FISCALYEARVARIANT",
"I_GLOBALCOMPANY",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/Learn More
- What Is a CDS View in SAP S/4HANA?
- Types of CDS Views: Basic, Composite, Consumption, and Transactional
- SAP Tables vs CDS Views — Key Differences
- Understanding Data Lineage in SAP S/4HANA
- VDM (Virtual Data Model) in SAP S/4HANA Explained
- CDS View Annotations — A Complete Guide
- CDS View Field Mapping and Associations
- Understanding the SAP S/4HANA Data Model
- CDS View Extensions and Custom Fields in SAP S/4HANA
- Released APIs and Stability Contracts in SAP S/4HANA