DDCDS_BOE_OBJINFO_PROCESSING_2

@AbapCatalog.sqlViewName: 'DDCDSBOEOBJINFO2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Compilation of all object info'
define view DDCDS_BOE_OBJINFO_PROCESSING_2
  as select from    DDCDS_BOE_OBJINFO_PROCESSING_1
    left outer join dd02bnd  as dep_info  on dep_info.strucobjn = dep_name
    left outer join dd02bnd  as baseobj_info on baseobj_info.strucobjn = baseobj_name
    left outer join ddddlsrc as dep_act   on dep_act.ddlname = DDCDS_BOE_OBJINFO_PROCESSING_1.dep_ddl
    left outer join ddddlsrc as baseobj_act  on baseobj_act.ddlname = DDCDS_BOE_OBJINFO_PROCESSING_1.baseobj_ddl
  association [*] to DDCDS_BOE_OBJINFO_PROCESSING_2 as _Parent on $projection.dep_name = _Parent.baseobj_name
{


  key dep_name,
  key baseobj_name,
  key case dep_objtype
    when 'H' then 'Hierarchy'
    when 'P' then 'Projection'
    when 'E' then 'Extend'
    when 'V' then 'View (V1)'
    when 'W' then 'View (V2)'
    when 'View' then 'SQL View'
    when 'Synonym' then 'Synonym'
    when 'A' then 'Abstract Entity'
    when 'F' then 'Table Function'
    when 'TABLE' then 'Table'
    when 'Q' then 'Custom Query'
    end                             as dep_objtype,
  key case baseobj_objtype
     when 'H' then 'Hierarchy'
     when 'P' then 'Projection'
     when 'E' then 'Extend'
     when 'V' then 'View (V1)'
     when 'W' then 'View (V2)'
     when 'View' then 'SQL View'
     when 'Synonym' then 'Synonym'
     when 'A' then 'Abstract Entity'
     when 'F' then 'Table Function'
     when 'TABLE' then 'Table'
     when 'Q' then 'Custom Query'
     end                            as baseobj_objtype,
      case
        when dep_is_valid = 'TRUE' then 'Valid'
        when dep_is_valid = 'FALSE' then 'Invalid'
        when dep_is_valid is null and dep_objtype <> 'TABLE' and dep_objtype <> 'A' then 'Does not exist'
        end                         as dep_is_valid,
      dep_info.used_session_vars  as dep_session_vars,
      case
        when syn_is_valid is not null and syn_is_valid = 'TRUE' then 'Valid'
        when syn_is_valid is not null and syn_is_valid = 'FALSE' then 'Invalid'
        when syn_is_valid is null and baseobj_is_valid = 'TRUE' then 'Valid'
        when syn_is_valid is null and baseobj_is_valid = 'FALSE' then 'Invalid'
        when baseobj_is_valid is null and baseobj_objtype <> 'TABLE' and baseobj_objtype <> 'A' then 'Does not exist'
        end                         as baseobj_is_valid,
      baseobj_info.used_session_vars as baseobj_session_vars,
      baseobj_info.hdb_only_entity_included as baseobj_hdb_only_entity_incl,
      baseobj_ddl,
      synonym_name,
      syn_is_valid,
      object_name,
      case
      when obj_is_valid = 'TRUE' then 'Valid'
      when obj_is_valid = 'FALSE' then 'Invalid'
      when obj_is_valid is null and object_name is not null then 'Does not exist'
      end                           as obj_is_valid,
      //dep_act

      dep_act.as4local            as dep_act_state,
      dep_act.as4user             as dep_user,
      dep_act.as4date             as dep_date,
      dep_act.as4time             as dep_time,
      //baseobj_act

      baseobj_act.as4local           as baseobj_act_state,
      baseobj_act.as4user            as baseobj_user,
      baseobj_act.as4date            as baseobj_date,
      baseobj_act.as4time            as baseobj_time,
      _Parent

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DDCDS_BOE_OBJINFO_PROCESSING_1",
"DD02BND",
"DDDDLSRC"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/