C_WrkPmtSftyCertValueHelp

@AbapCatalog.sqlViewName: 'CPMTSFTYCERTVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #S, dataClass: #META}
@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.representativeKey: 'SafetyCertificate'
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Safety Certificate in Work Permit'
define view C_WrkPmtSftyCertValueHelp
  as select from I_SafetyCertificate
  association [0..1] to I_Equipment                 as _Equipment                 on  $projection.Equipment = _Equipment.Equipment
  association [0..*] to I_EquipmentText             as _EquipmentText             on  $projection.Equipment = _EquipmentText.Equipment
  association [0..1] to I_FunctionalLocation        as _FunctionalLocation        on  $projection.FunctionalLocation = _FunctionalLocation.FunctionalLocation
  association [0..*] to I_FunctionalLocationText    as _FunctionalLocationText    on  $projection.FunctionalLocation = _FunctionalLocationText.FunctionalLocation
  association [0..1] to I_FunctionalLocationLabel   as _FunctionalLocationLabel   on  $projection.FunctionalLocation = _FunctionalLocationLabel.FunctionalLocation
  association [1..1] to I_SafetyCertificateTypeText as _SafetyCertificateTypeText on  $projection.SafetyCertificateType    = _SafetyCertificateTypeText.SafetyCertificateType
                                                                                  and $projection.MaintenancePlanningPlant = _SafetyCertificateTypeText.MaintenancePlanningPlant
                                                                                  and _SafetyCertificateTypeText.Language  = $session.system_language
  association [1..1] to I_Plant                     as _Plant                     on  $projection.MaintenancePlanningPlant = _Plant.Plant
{
       @EndUserText: { label: 'Safety Certificate', quickInfo: 'Safety Certificate' }
       @ObjectModel.text.element: ['SftyCertDesc']
       @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
       @UI: {
       selectionField: [{ position: 30 }],
       lineItem:[ {position:30, importance: #HIGH} ],
       textArrangement: #TEXT_FIRST
       }
  key  SafetyCertificate,
       SafetyCertificateInternalID,
       @EndUserText: { label: 'Description', quickInfo: 'Safety Certificate Description' }
       @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7 }
       SftyCertDesc,
       @EndUserText: { label: 'Safety Certificate Type', quickInfo: 'Safety Certificate Type' }
       @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7 }
       SafetyCertificateType,
       @EndUserText: { label: 'Safety Certificate Type Description', quickInfo: 'Safety Certificate Type Description' }
       @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7 }
       _SafetyCertificateTypeText.SftyCertificateTypeDescription,
       @EndUserText: { label: 'Maintenance Planning Plant', quickInfo: 'Maintenance Planning Plant' }
       @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7 }
       @ObjectModel.text.element: ['PlantName']
       MaintenancePlanningPlant,
       @EndUserText: { label: 'Plant Name', quickInfo: 'Plant Name' }
       @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7 }
       _Plant.PlantName,
       @EndUserText: { label: 'Technical Object', quickInfo: 'Technical Object' }
       @Consumption.filter.hidden: true
       cast( case when _Equipment.Equipment <> '' then ltrim( _Equipment.Equipment,'0')
                 else case when _FunctionalLocation.FunctionalLocation <> ''
                           then _FunctionalLocationLabel.FunctionalLocationLabelName
                           else ''  end end as eams_tec_obj preserving type ) as TechnicalObjectLabel,
       @Semantics.text: true
       cast( case when _Equipment.Equipment <> ''
              then _EquipmentText[1:Language = $session.system_language].EquipmentName
              else case when _FunctionalLocation.FunctionalLocation <> ''
                        then _FunctionalLocationText[1:Language = $session.system_language].FunctionalLocationName
                        else '' end end as eams_tec_obj_des preserving type ) as TechnicalObjectDescription,
       @UI.hidden: true
       Equipment,
       @UI.hidden: true
       FunctionalLocation,
       @UI.hidden: true
       ValidFromDateTime,
       @UI.hidden: true
       ValidToDateTime,
       @EndUserText: { label: 'Safety Certificate Processing Status', quickInfo: 'Safety Certificate Processing Status' }
       @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7 }
       SftyCertProcessingStatus,
       @EndUserText: { label: 'Processing Status', quickInfo: 'Processing Status' }
       @Search.defaultSearchElement: true
       @Search.ranking:#MEDIUM
       SftyCertProcessingStatusText,
       WorkCenter,
       WorkCenterText,
       MaintenancePlannerGroup,
       TechObjAuthorizationGroup,
       _Equipment,
       _EquipmentText,
       _FunctionalLocation,
       _FunctionalLocationText,
       _FunctionalLocationLabel,
       _SafetyCertificateTypeText,
       _Plant
}
where
  (
      SftyCertProcessingStatus     < 'PS80'
  )
  and SftyCertificateSubobjectType = 'S'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EQUIPMENT",
"I_EQUIPMENTTEXT",
"I_FUNCTIONALLOCATION",
"I_FUNCTIONALLOCATIONLABEL",
"I_FUNCTIONALLOCATIONTEXT",
"I_PLANT",
"I_SAFETYCERTIFICATE",
"I_SAFETYCERTIFICATETYPETEXT"
],
"ASSOCIATED":
[
"I_EQUIPMENT",
"I_EQUIPMENTTEXT",
"I_FUNCTIONALLOCATION",
"I_FUNCTIONALLOCATIONLABEL",
"I_FUNCTIONALLOCATIONTEXT",
"I_PLANT",
"I_SAFETYCERTIFICATETYPETEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/