C_TaxPayableDocument

@VDM : {
    viewType: #CONSUMPTION ,
    lifecycle.contract.type: #NONE
}

@AccessControl: {
    authorizationCheck: #MANDATORY,
    personalData.blocking: #REQUIRED,
    privilegedAssociations: ['_CreatedByUserContactCard', '_LastChangedByUserContactCard']
}

@ObjectModel:{
    usageType: { sizeCategory: #L,
                 serviceQuality: #A,
                 dataClass: #TRANSACTIONAL  },
    text.control: #ASSOCIATED_TEXT_UI_HIDDEN,
    updateEnabled: #( EXTERNAL_CALCULATION )
}

@Search.searchable: true
@Consumption.ranked: true
@Metadata.allowExtensions: true
@EndUserText.label: 'Tax Payable Document'
define view entity C_TaxPayableDocument
  as select from I_TaxPayableDocument as TaxPayableDocument

  association [1..*] to C_TaxPayableItem               as _TaxPayableDocumentItem       on  $projection.TaxPayableDocument     = _TaxPayableDocumentItem.TaxPayableDocument
                                                                                        and $projection.TaxPayableDocumentYear = _TaxPayableDocumentItem.TaxPayableDocumentYear
  // Not Used

  //association [1..*] to C_TaxPayableTaxItem            as _TaxPayableTaxItems           on  $projection.TaxPayableDocument     = _TaxPayableTaxItems.TaxPayableDocument

  //                                                                                        and $projection.TaxPayableDocumentYear = _TaxPayableTaxItems.TaxPayableDocumentYear

  association [1..*] to C_TransactionalTaxItem         as _TransactionalTaxItem         on  $projection.TaxPayableDocument     = _TransactionalTaxItem.TaxPayableDocument
                                                                                        and $projection.TaxPayableDocumentYear = _TransactionalTaxItem.TaxPayableDocumentYear
  association [0..1] to C_TaxPayableReportDetail       as _PayableReportDetail          on  $projection.TaxPayableDocument     = _PayableReportDetail.TaxPayableDocument
                                                                                        and $projection.TaxPayableDocumentYear = _PayableReportDetail.TaxPayableDocumentYear
  association [1..1] to I_UserContactCard              as _CreatedByUserContactCard     on  $projection.CreatedByUser = _CreatedByUserContactCard.ContactCardID
  association [0..1] to I_UserContactCard              as _LastChangedByUserContactCard on  $projection.LastChangedByUser = _LastChangedByUserContactCard.ContactCardID
  association [0..*] to I_TaxationTypeText             as _TaxationTypeTxt              on  $projection.TaxationType = _TaxationTypeTxt.TaxationType
  association [0..*] to I_CountryText                  as _TaxCountryText               on  $projection.TaxCountry = _TaxCountryText.Country
  association [0..*] to I_TaxPayableDocumentOriginText as _TaxPayableDocumentOriginText on  $projection.TaxPayableDocumentOrigin = _TaxPayableDocumentOriginText.TaxPayableDocumentOrigin
  association [0..*] to I_TaxPayableDocumentStatusText as _TaxPayableStatusText         on  $projection.TaxPayableDocumentStatus = _TaxPayableStatusText.TaxPayableDocumentStatus
  association [0..*] to C_TaxPayableNote               as _TaxPayableNote               on  $projection.TaxPayableDocument     = _TaxPayableNote.TaxPayableDocument
                                                                                        and $projection.TaxPayableDocumentYear = _TaxPayableNote.TaxPayableDocumentYear
  association [1..*] to C_TxPyblCompAmountChangeLog    as _TxPyblCompAmountChangeLog    on  $projection.TaxPayableDocument     = _TxPyblCompAmountChangeLog.TaxPayableDocument
                                                                                        and $projection.TaxPayableDocumentYear = _TxPyblCompAmountChangeLog.TaxPayableDocumentYear
{
       @Semantics.fiscal.year: true
       @EndUserText.label: 'Document Year'
  key  TaxPayableDocumentYear,

       @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.9 }
       @EndUserText.label: 'Document Number'
  key  TaxPayableDocument,

       @ObjectModel:{
          text.association: '_CompanyCode',
          readOnly: true
       }
       @Consumption.valueHelpDefinition: [{ entity: { name: 'I_CompanyCodeVH', element: 'CompanyCode' }}]
       @Search: { defaultSearchElement: true }
       CompanyCode,

       @Consumption.valueHelpDefinition: [{ entity: { name: 'I_TaxPayableDocumentStatus', element: 'TaxPayableDocumentStatus' }}]
       @Consumption.filter.defaultValue: 'PE'
       @ObjectModel.text.association: '_TaxPayableStatusText'
       TaxPayableDocumentStatus,

       @Consumption:{ filter : { selectionType: #SINGLE, mandatory: true },
                      valueHelpDefinition: [{ entity: { name: 'I_TaxCountryValueHelp', element: 'TaxCountry' }}]}
       @ObjectModel:{
          text.association: '_TaxCountryText',
          readOnly: true
       }
       TaxCountry,

       @Consumption:{ filter : { selectionType: #SINGLE, mandatory: true },
                      valueHelpDefinition: [{ entity: { name: 'I_TaxationTypeValueHelp', element: 'TaxationType'},
                                              additionalBinding: [{ localElement: 'TaxCountry', element: 'TaxCountry'}] }]}
       @ObjectModel: {
          text.association: '_TaxationTypeTxt',
          readOnly: true
        }
       TaxationType,

       @Semantics.amount.currencyCode: 'ReportingCurrency'
       @Consumption.filter.hidden: true
       @ObjectModel.readOnly: true
       ReportedTaxAmountInRptgCrcy,

       @Semantics.amount.currencyCode: 'ReportingCurrency'
       @Consumption.filter.hidden: true
       @ObjectModel.readOnly: true
       RptdRoundedTaxAmountInRptgCrcy,

       @Semantics.amount.currencyCode: 'ReportingCurrency'
       @Consumption.filter.hidden: true
       @ObjectModel.readOnly: true
       TaxPayableAmountInRptgCrcy,

       @Consumption.filter.hidden: true
       @ObjectModel.readOnly: true
       ReportingCurrency,

       @Consumption.valueHelpDefinition: [{ entity: { name: 'I_TaxAuthorityValueHelp', element: 'BusinessPartner'},
                                            additionalBinding: [{ localElement: 'CompanyCode', element: 'CompanyCode'}]}]
       TaxAuthorityBusinessPartner,

       @ObjectModel.text.association: '_TaxPayableDocumentOriginText'
       @Consumption.valueHelpDefinition: [{ entity: { name: 'I_TaxPayableDocumentOrigin', element: 'TaxPayableDocumentOrigin' } }]
       TaxPayableDocumentOrigin,

       @Search: { defaultSearchElement: true,  ranking: #MEDIUM, fuzzinessThreshold: 0.7 }
       TaxPayableExternalReference,

       TaxPaymentDueDate,

       @Search: { defaultSearchElement: true,  ranking: #MEDIUM, fuzzinessThreshold: 0.7 }
       AccountingDocument,
       @Semantics.fiscal.year: true
       FiscalYear,
       IntercompanyTransaction,

       @Consumption.filter : { selectionType: #INTERVAL }
       @ObjectModel.readOnly: true
       CreationDateTime,

       @ObjectModel:{
          foreignKey.association: '_CreatedByUserContactCard',
          readOnly: true
        }
       CreatedByUser,

       @Consumption.filter : { selectionType: #INTERVAL }
       @ObjectModel.readOnly: true
       LastChangeDateTime,

       @ObjectModel: {
          foreignKey.association: '_LastChangedByUserContactCard',
          readOnly: true
        }
       LastChangedByUser,


       cast( case
                    when TaxPayableDocumentStatus = 'CN'
                     then 1
                    when TaxPayableDocumentStatus = 'PE'
                     then 2
                     else 3
                    end  as eve_tv_criticality    ) as Criticality,

       @Consumption.hidden: true
       TxPyblBizPurposeIsCompleted,
       _TaxationType,
       _ReportingCurrency,
       @Consumption.filter.hidden: true
       _CreatedByUserContactCard,
       @Consumption.filter.hidden: true
       _LastChangedByUserContactCard,
       _TaxPayableDocumentItem,
       _CompanyCode,
       //       _StRpCategoryPhaseText,

       _TaxationTypeTxt,
       _TaxPayableStatusText,
       _TaxCountryText,
       _TaxPayableDocumentOriginText,
       _TaxPayableNote,
       //_TaxPayableTaxItems,

       _TransactionalTaxItem,
       _TxPyblCompAmountChangeLog,
       _PayableReportDetail

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_TAXPAYABLEDOCUMENT"
],
"ASSOCIATED":
[
"C_TAXPAYABLEITEM",
"C_TAXPAYABLENOTE",
"C_TAXPAYABLEREPORTDETAIL",
"C_TRANSACTIONALTAXITEM",
"C_TXPYBLCOMPAMOUNTCHANGELOG",
"I_COMPANYCODE",
"I_COUNTRYTEXT",
"I_CURRENCY",
"I_TAXATIONTYPE",
"I_TAXATIONTYPETEXT",
"I_TAXPAYABLEDOCUMENTORIGINTEXT",
"I_TAXPAYABLEDOCUMENTSTATUSTEXT",
"I_USERCONTACTCARD"
],
"BASE":
[
"I_TAXPAYABLEDOCUMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/