I_TAXPAYABLEDOCUMENT

CDS View

Tax Payable Document

I_TAXPAYABLEDOCUMENT is a CDS View in S/4HANA. Tax Payable Document. It contains 13 fields. 4 CDS views read from this table.

Used by 4 CDS view(s) 13 fields

CDS Views using this table (4)

ViewTypeJoinVDMDescription
C_TaxPayableDocument view_entity from CONSUMPTION Tax Payable Document
I_TaxItemProcessFlow view_entity inner COMPOSITE Tax Item Process Flow
P_TaxPayablePaymentDocument view_entity from COMPOSITE Tax Payable Payment Document
P_TaxPayablePaymentDocument view_entity union COMPOSITE Tax Payable Payment Document

Fields (13)

KeyField CDS FieldsUsed in Views
KEY TaxPayableDocument TaxPayableDocument 1
KEY TaxPayableDocumentYear TaxPayableDocumentYear 1
AccountingDocument AccountingDocument 1
CompanyCode CompanyCode 1
CreatedByUser CreatedByUser 1
CreationDateTime CreationDateTime 1
FiscalYear FiscalYear 1
IntercompanyTransaction IntercompanyTransaction 2
LastChangeDateTime LastChangeDateTime 1
TaxCountry TaxCountry 1
TaxPayableDocumentStatus TaxPayableDocumentStatus 1
TaxPaymentDueDate TaxPaymentDueDate 1
TxPyblBizPurposeIsCompleted TxPyblBizPurposeIsCompleted 1 
@ObjectModel.usageType: {
                         sizeCategory: #L,
                         serviceQuality: #A,
                         dataClass: #TRANSACTIONAL
                         }

@AccessControl: {
                authorizationCheck: #MANDATORY ,
                personalData.blocking: #REQUIRED
                }
@VDM: {
        viewType: #BASIC,
        lifecycle.contract.type: #SAP_INTERNAL_API
        }
@EndUserText.label: 'Tax Payable Document'
define view entity I_TaxPayableDocument
  as select from tax_reg_pybl_hdr as PayableDocument
  association [1..*] to I_TaxPayableItem as _PayableDocumentItem on  $projection.TaxPayableDocument     = _PayableDocumentItem.TaxPayableDocument
                                                                 and $projection.TaxPayableDocumentYear = _PayableDocumentItem.TaxPayableDocumentYear
  association [1..1] to I_CompanyCode    as _CompanyCode         on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_TaxationType   as _TaxationType        on  $projection.TaxationType = _TaxationType.TaxationType
  association [0..1] to I_Country        as _TaxCountry          on  $projection.TaxCountry = _TaxCountry.Country
  association [1..1] to I_Currency       as _ReportingCurrency   on  $projection.ReportingCurrency = _ReportingCurrency.Currency
{

  key tax_pybl_doc_nmbr                                                      as TaxPayableDocument,
  key tax_pybl_doc_year                                                      as TaxPayableDocumentYear,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      pybl_company_code                                                      as CompanyCode,
      @ObjectModel.foreignKey.association: '_TaxationType'
      taxation_type                                                          as TaxationType,
      @ObjectModel.foreignKey.association: '_TaxCountry'
      cast( tax_country  as txrg_tax_ctry preserving type )                  as TaxCountry,
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      reported_amount                                                        as ReportedTaxAmountInRptgCrcy,
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      rounded_amount                                                         as RptdRoundedTaxAmountInRptgCrcy,
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      payable_amount                                                         as TaxPayableAmountInRptgCrcy,
      @ObjectModel.foreignKey.association: '_ReportingCurrency'
      reporting_currency                                                     as ReportingCurrency,
      tax_authority                                                          as TaxAuthorityBusinessPartner,
      tax_paymt_due_date                                                     as TaxPaymentDueDate,
      document_status                                                        as TaxPayableDocumentStatus,
      cast( belnr as txrg_txpybl_journal_entry preserving type )             as AccountingDocument,
      cast( gjahr as txrg_txpybl_jrnl_entr_fy preserving type )              as FiscalYear,
      cast( cross_company_key as txrg_txpybl_intco_transac preserving type ) as IntercompanyTransaction,
      document_origin                                                        as TaxPayableDocumentOrigin,
      external_reference                                                     as TaxPayableExternalReference,
      @Semantics.systemDateTime.createdAt: true
      created_at                                                             as CreationDateTime,
      @Semantics.user.createdBy: true
      created_by                                                             as CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      lastchangedat                                                          as LastChangeDateTime,
      @Semantics.user.lastChangedBy: true
      lastchangedby                                                          as LastChangedByUser,
      xblocked                                                               as TxPyblBizPurposeIsCompleted,
      _PayableDocumentItem,
      _CompanyCode,
      _TaxationType,
      _TaxCountry,
      _ReportingCurrency
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"TAX_REG_PYBL_HDR"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_COUNTRY",
"I_CURRENCY",
"I_TAXATIONTYPE",
"I_TAXPAYABLEITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More