C_ShopFloorOrderOperation

@AbapCatalog.sqlViewName: 'CMPESFOOPER'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}
@VDM.viewType: #CONSUMPTION
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@UI.headerInfo.typeName: 'Shop Floor Order Operation'
@UI.headerInfo.typeNamePlural: 'Shop Floor Order Operations'
@UI.headerInfo.title.label: 'Shop Floor Order Operation'
@UI.presentationVariant.sortOrder: {by: 'ManufacturingOrderOperation', direction: #ASC}
@UI.textArrangement: #TEXT_LAST
@EndUserText.label: 'Shop Floor Order Operation'

define view C_ShopFloorOrderOperation
  as select from I_MfgOrderOperation as MfgOrderOperation

  association [0..1] to I_WorkCenter                   as _WorkCenter                   on  $projection.WorkCenterTypeCode   = _WorkCenter.WorkCenterTypeCode
                                                                                        and $projection.WorkCenterInternalID = _WorkCenter.WorkCenterInternalID
  association [1..1] to I_WorkCenterType               as _WorkCenterType               on  $projection.WorkCenterTypeCode = _WorkCenterType.WorkCenterTypeCode
  association [0..*] to I_MfgOrderOpDocInfoRecdObjLink as _MfgOrderOpDocInfoRecdObjLink on  $projection.ManufacturingOrder       = _MfgOrderOpDocInfoRecdObjLink.ManufacturingOrder
                                                                                        and $projection.OrderOperationInternalID = _MfgOrderOpDocInfoRecdObjLink.OrderOperationInternalID
{

      @UI.hidden: true
      @ObjectModel.foreignKey.association: '_OrdInternalBillOfOperations'
  key MfgOrderOperation.OrderInternalBillOfOperations                                                                    as OrderInternalID,

      @UI.hidden: true
  key MfgOrderOperation.OrderIntBillOfOperationsItem                                                                     as OrderOperationInternalID,

      -- Order
      @UI.identification.position: 20
      @UI.statusInfo.position: 20
      @UI.lineItem.position: 20
      @UI.selectionField.position: 20
      @UI.fieldGroup.position: 20
      @ObjectModel.foreignKey.association: '_MfgOrder'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderStdVH', element: 'ManufacturingOrder' } } ]
      cast(MfgOrderOperation.ManufacturingOrder as aufnr preserving type)                                                as ManufacturingOrder,

      -- Operation
      @UI.identification.position: 30
      @UI.statusInfo.position: 30
      @UI.selectionField.position: 30
      @UI.fieldGroup.position: 30
      @UI.lineItem.position: 30
      cast(MfgOrderOperation.ManufacturingOrderOperation as mpe_vornr_char preserving type)                              as ManufacturingOrderOperation,

      @UI.identification.position: 40
      @UI.statusInfo.position: 40
      @UI.selectionField.position: 40
      @UI.fieldGroup.position: 40
      @UI.lineItem.position: 40
      MfgOrderOperation.MfgOrderOperationText,

      -- Material
      @ObjectModel.foreignKey.association: '_Material'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      @ObjectModel.text.element: 'MaterialName'
      @UI.dataPoint:{ title: 'Material'}
      MfgOrderOperation._MfgOrder.Material,

      @UI.hidden: true
      MfgOrderOperation._MfgOrder._Material._Text[1: Language=$session.system_language].MaterialName,

      @ObjectModel.text.element: 'OperationControlProfileName'
      @ObjectModel.foreignKey.association: '_OperationControlProfile'
      MfgOrderOperation.OperationControlProfile,

      @UI.hidden: true
      MfgOrderOperation._OperationControlProfile._Text[1: Language=$session.system_language].OperationControlProfileName as OperationControlProfileName,

      @ObjectModel.text.element: 'WorkCenter'
      @ObjectModel.foreignKey.association: '_WorkCenter'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_WorkCenterStdVH', element: 'WorkCenterInternalID' } } ]
      @UI.hidden: true
      MfgOrderOperation.WorkCenterInternalID,

      @ObjectModel.foreignKey.association: '_WorkCenterType'
      @UI.hidden: true
      cast(MfgOrderOperation.WorkCenterTypeCode as pph_objty)                                                            as WorkCenterTypeCode,

      @UI.hidden: true
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_WorkCenterStdVH', element: 'WorkCenterInternalID' } } ]
      MfgOrderOperation._WorkCenter.WorkCenter,

      @UI.hidden: true
      MfgOrderOperation.ProduceOpActyNtwkInstance                                                                        as OpActyNtwkInstance,

      @UI.hidden: true
      MfgOrderOperation.ProductionPlant,

      MfgOrderOperation._OperationControlProfile,
      MfgOrderOperation._OrdInternalBillOfOperations,
      MfgOrderOperation._MfgOrder,
      MfgOrderOperation._MfgOrder._Material,
      MfgOrderOperation._ProductionPlant,
      _WorkCenter,
      _WorkCenterType,
      @Consumption.filter.hidden: true
      _MfgOrderOpDocInfoRecdObjLink
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIAL",
"I_MATERIALTEXT",
"I_MFGORDER",
"I_MFGORDEROPERATION",
"I_OPERATIONCONTROLPROFILE",
"I_OPERATIONCONTROLPROFILETEXT",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"I_MATERIAL",
"I_MFGORDER",
"I_MFGORDEROPDOCINFORECDOBJLINK",
"I_OPERATIONCONTROLPROFILE",
"I_ORDINTERNALBILLOFOPERATIONS",
"I_PLANT",
"I_WORKCENTER",
"I_WORKCENTERTYPE"
],
"BASE":
[
"I_MFGORDER",
"I_MFGORDEROPERATION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/