C_RealTmeWrkInProcOrderTypeVH

@AbapCatalog.sqlViewName: 'CRTWIPORDTYPEVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true

@VDM.viewType: #CONSUMPTION

@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.representativeKey: 'OrderType'

@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@Metadata.ignorePropagatedAnnotations: true

@Search.searchable: true
@Consumption.ranked: true

@EndUserText.label: 'Order Type'
define view C_RealTmeWrkInProcOrderTypeVH
  as select from I_OrderType
{
      @ObjectModel.text.element: ['OrderTypeName']
      @Search: {
        defaultSearchElement: true,
        ranking: #HIGH,
        fuzzinessThreshold: 0.8
      }
  key cast(OrderType as fco_rtwip_prod_order_type preserving type )                                                             as OrderType,

      @Search: {
        defaultSearchElement: true,
        ranking: #LOW
      }
      @Semantics.text: true
      cast(_Text[1:Language = $session.system_language].OrderTypeName as fco_rtwip_prod_order_type_name preserving type )       as OrderTypeName,

      @ObjectModel.text.element: ['OrderCategoryName']
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW
      }
      OrderCategory,

      @Search: {
        defaultSearchElement: true,
        ranking: #LOW
      }
      @Semantics.text: true
      cast(_OrderCategory._Text[1:Language = $session.system_language].OrderCategoryName as ordercategoryname preserving type ) as OrderCategoryName,

      // Associations

      _Text,
      _OrderCategory
}
where
     OrderCategory = '05'
  or OrderCategory = '10'
  or OrderCategory = '40'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ORDERCATEGORY",
"I_ORDERCATEGORYTEXT",
"I_ORDERTYPE",
"I_ORDERTYPETEXT"
],
"ASSOCIATED":
[
"I_ORDERCATEGORY",
"I_ORDERTYPETEXT"
],
"BASE":
[
"I_ORDERTYPE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/