I_ORDERTYPE

CDS View

Order Type

I_ORDERTYPE is a CDS View in S/4HANA. Order Type. It contains 2 fields. 10 CDS views read from this table.

Used by 10 CDS view(s) 2 fields

CDS Views using this table (10)

ViewTypeJoinVDMDescription
A_MfgOrderType view from BASIC Production Order Type
C_EvtBsdMfgOrderTypeVH view from CONSUMPTION Order Type
C_MaintItemMaintOrderTypeVH view from CONSUMPTION Maintenance Item Maintenance Order Type
C_MaintOrderTypeVH view from CONSUMPTION Maintenance Order Type Value Help
C_RealTmeWrkInProcOrderTypeVH view from CONSUMPTION Order Type
FAC_AUDIT_Z3_OrderType view from Order Type
I_MfgOrderType view from BASIC Manufacturing Order Type
I_MfgOrderTypeVH view from COMPOSITE Manufacturing Order Type Value Help
I_OrderTypeVH view from COMPOSITE Order Type
I_ProdnAcctAssgmtObjTypeVH view from COMPOSITE Production Account Assignment Object Type

Fields (2)

KeyField CDS FieldsUsed in Views
KEY OrderType MaintenanceOrderType,OrderType 4
OrderCategory OrderCategory 1 
@AbapCatalog.sqlViewName: 'IPPORDERTYPE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.buffering: {status: #ACTIVE, type: #GENERIC, numberOfKeyFields: 001}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.dataExtraction.enabled: true
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Consumption.ranked: true
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.compositionRoot: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY, #EXTRACTION_DATA_SOURCE]
@ObjectModel.representativeKey: 'OrderType'
@ObjectModel.semanticKey: ['OrderType']
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Order Type'

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_OrderType
  as select from t003o as typ

  association [0..*] to I_OrderTypeText          as _Text                   on $projection.OrderType = _Text.OrderType
  association [0..1] to I_OrderCategory          as _OrderCategory          on $projection.OrderCategory = _OrderCategory.OrderCategory
  association [0..1] to I_FunctionalArea         as _FunctionalArea         on $projection.FunctionalArea = _FunctionalArea.FunctionalArea
  association [0..1] to I_ControllingObjectClass as _ControllingObjectClass on $projection.ControllingObjectClass = _ControllingObjectClass.ControllingObjectClass
  association [0..1] to I_StatusProfile          as _OrderStatusProfile     on $projection.StatusProfile = _OrderStatusProfile.StatusProfile
  association [0..1] to I_StatusProfile          as _OperationStatusProfile on $projection.OperationStatusProfile = _OperationStatusProfile.StatusProfile

{
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      @ObjectModel.text.association: '_Text'
  key typ.auart                                           as OrderType,
      @ObjectModel.foreignKey.association: '_OrderCategory'
      cast(typ.autyp as pph_autyp preserving type)        as OrderCategory,

      // Assignments

      typ.numkr                                           as OrderNumberRange,
      typ.obligo                                          as CommitmentsMgmtActvtnStatus,
      @ObjectModel.foreignKey.association: '_OrderStatusProfile'
      typ.stsma                                           as StatusProfile,
      @ObjectModel.foreignKey.association: '_OperationStatusProfile'
      cast(typ.vrg_stsma as vdm_stsma_op preserving type) as OperationStatusProfile,
      typ.aprof                                           as ControllingSettlementProfile,
      typ.pprof                                           as PlanningProfile,
      typ.bprof                                           as BudgetProfile,
      typ.exec_profile                                    as ExecutionServiceProfile,
      cast(typ.scope as pph_scope preserving type)        as ControllingObjectClass,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      typ.func_area                                       as FunctionalArea,
      typ.copar                                           as CtrlgTotalsRecordActvtnStatus,
      typ.resz1                                           as ResidenceTime1,
      typ.resz2                                           as ResidenceTime2,
      typ.layout                                          as OrderMasterDataLayout,
      typ.tdform                                          as TextObjectForm,
      typ.configurationdeprecationcode                    as ConfigDeprecationCode,

      // Indicators

      typ.aufkl                                           as OrderIsToBeClassified,
      typ.relkz                                           as OrderIsReleasedUponCreation,
      typ.chgkz                                           as OrderHasStatusChangeDocuments,
      typ.nabpf                                           as SettlementIsNotRequired,
      typ.plint                                           as OrdIsUsedInIntegratedPlanning,
      typ.vorpl                                           as NetworkIsForPlanning,
      cast(typ.erloese    as vdm_pp_erloese preserving type) as RevenuePostingIsAllowed,
      cast(typ.colordproc as vdm_colordproc preserving type) as CollectiveOrderHasAutoGoodsMvt,

      // Associations

      _OrderCategory,
      _FunctionalArea,
      _ControllingObjectClass,
      _OrderStatusProfile,
      _OperationStatusProfile,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _Text
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T003O"
],
"ASSOCIATED":
[
"I_CONTROLLINGOBJECTCLASS",
"I_FUNCTIONALAREA",
"I_ORDERCATEGORY",
"I_ORDERTYPETEXT",
"I_STATUSPROFILE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More