C_RO_MatlDocHeader

@AbapCatalog.sqlViewName: 'CMATDOCHEADER'
@EndUserText.label: 'View for material document header'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking:#REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
    usageType: {
        sizeCategory: #XXL,
        serviceQuality: #B,
        dataClass:#TRANSACTIONAL
    },

    representativeKey: 'MaterialDocument'
}
@Search.searchable: true
@VDM.private: false
@VDM.viewType: #CONSUMPTION

@Metadata: {
             ignorePropagatedAnnotations: true,
             allowExtensions: true
           }

define view C_RO_MatlDocHeader
  as select from I_MaterialDocumentRecord
  association [1..1] to I_MaterialDocumentYear as _MaterialDocumentYear on  $projection.MaterialDocumentYear = _MaterialDocumentYear.MaterialDocumentYear
  association [1..*] to I_RO_MatlDocItem       as _MaterialDocumentItem on  $projection.MaterialDocumentYear = _MaterialDocumentItem.MaterialDocumentYear
                                                                        and $projection.MaterialDocument     = _MaterialDocumentItem.MaterialDocument
  association [0..1] to I_DeliveryDocument     as _DeliveryDocument     on  $projection.DeliveryDocument = _DeliveryDocument.DeliveryDocument
  
{
      @ObjectModel.foreignKey.association: '_MaterialDocumentYear'
  key MaterialDocumentYear,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.9
      @Search.ranking: #HIGH
  key MaterialDocument, 

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.9
      @Search.ranking: #MEDIUM
      @Semantics.businessDate.at: true
      DocumentDate,
      MaterialDocumentHeaderText,
      Plant,
      StorageLocation,
      IssuingOrReceivingPlant,
      IssuingOrReceivingStorageLoc,
      DeliveryInMatlDocumentHeader as DeliveryDocument,
      ReferenceDocument,
      _MaterialDocumentYear,
      
       @ObjectModel.association.type:#TO_COMPOSITION_CHILD
       
      _MaterialDocumentItem,
      _DeliveryDocument
}

 where
      MaterialDocumentRecordType = 'MDOC'
      and IsMaterialDocumentHeader   = 1   
          
  
  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIALDOCUMENTRECORD"
],
"ASSOCIATED":
[
"I_DELIVERYDOCUMENT",
"I_MATERIALDOCUMENTYEAR",
"I_RO_MATLDOCITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/