I_RO_MatlDocItem

@AbapCatalog.sqlViewName: 'IMATLDOCITEM'
@AbapCatalog.preserveKey: true
@EndUserText.label: 'Basic view for MATDOC table'
@AccessControl.personalData.blocking: #REQUIRED 
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass:#TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
        private: false,
        viewType: #BASIC,
         lifecycle.contract.type: #SAP_INTERNAL_API
        }
@Metadata: {
             ignorePropagatedAnnotations: true
           }
define view I_RO_MatlDocItem
  as select from matdoc

  association [0..1] to I_Material                  as _Material                      on  $projection.Material                     = _Material.Material
 
  association [0..1] to I_Plant                     as _Plant                         on  $projection.Plant = _Plant.Plant
  association [0..1] to I_Plant                     as _IssuingOrReceivingPlant       on  $projection.IssuingOrReceivingPlant      = _IssuingOrReceivingPlant.Plant
  association [0..1] to I_StorageLocation           as _StorageLocation               on  $projection.StorageLocation              = _StorageLocation.StorageLocation
                                                                                      and $projection.Plant                        = _StorageLocation.Plant
  association [0..1] to I_StorageLocation           as _IssuingOrReceivingStorageLoc  on  $projection.IssuingOrReceivingStorageLoc = _IssuingOrReceivingStorageLoc.StorageLocation
                                                                                      and $projection.IssuingOrReceivingPlant      = _IssuingOrReceivingStorageLoc.Plant
 
  association [0..1] to I_Supplier                  as _Supplier                      on  $projection.Supplier                     = _Supplier.Supplier
 
  association [0..1] to I_UnitOfMeasure             as _MaterialBaseUnit              on  $projection.MaterialBaseUnit             = _MaterialBaseUnit.UnitOfMeasure
 
  association [0..*] to I_CostCenter                as _CostCenter                    on  $projection.CostCenter                   = _CostCenter.CostCenter
                                                                                   
  association [0..1] to I_DeliveryDocumentItem      as _DeliveryDocumentItem          on  $projection.DeliveryDocument             = _DeliveryDocumentItem.DeliveryDocument
                                                                                      and $projection.DeliveryDocumentItem         = _DeliveryDocumentItem.DeliveryDocumentItem
  association [0..1] to I_Currency                  as _Currency                      on  $projection.CompanyCodeCurrency          = _Currency.Currency
  
  //association [0..1] to I_WBSElementByInternalKey   as _WBSElement                    on  $projection.WBSElementInternalID         = _WBSElement.WBSElementInternalID

  
{
    -- with records of type MDOC_CP, AG_MDOC_CF etc there is no unique key except the technical GUID key, so we don't use any key fields at all
   mblnr as MaterialDocument,
  
   mjahr  as MaterialDocumentYear,
 
   zeile  as MaterialDocumentItem,
  @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
  lsmng      as QuantityInDeliveryQtyUnit,
  lfbnr      as ReferenceDocumentNumber,
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  _DeliveryDocumentItem.NetPriceAmount as NetPriceAmount,
  _Supplier.OrganizationBPName1        as OrganizationBPName1,
  _Supplier.CityName                   as CityName,
  _Material._Text[1:Language = $session.system_language].MaterialName         as MaterialDescription,
  werks             as Plant,
  matnr             as Material,
  lgort             as StorageLocation,
  lifnr             as Supplier,
  ebeln             as PurchasingDocument,
  ebelp             as PurchaseOrderItem,
  charg             as Batch,
  ps_psp_pnr        as WBSElementInternalID,
  cast(ummat as nsdm_umat preserving type)          as IssgOrRcvgMaterial,
  umwrk             as IssuingOrReceivingPlant,
  umlgo             as IssuingOrReceivingStorageLoc,
  
  @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
  @DefaultAggregation: #NONE
  menge             as QuantityInBaseUnit,
  @Semantics.unitOfMeasure: true
  meins             as MaterialBaseUnit,
  
  //@DefaultAggregation:#NONE

  //@Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'

  
  @Semantics.businessDate.at: true
  bldat             as DocumentDate,
  vbeln_im          as DeliveryDocument,
  vbelp_im          as DeliveryDocumentItem,
  kostl             as CostCenter,
  xblnr             as ReferenceDocument,
  bprme             as OrderPriceUnit,
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  dmbtr             as TotalGoodsMvtAmtInCCCrcy,
  
  cast(waers as nsdm_comp_code_currency preserving type)  as CompanyCodeCurrency,
  
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  @DefaultAggregation: #NONE
  
  _Material,
  _Plant,
  _IssuingOrReceivingPlant,
  _StorageLocation,
  _IssuingOrReceivingStorageLoc,
  _Supplier,
  _MaterialBaseUnit,
  _CostCenter,
  _Currency
}

 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DELIVERYDOCUMENTITEM",
"I_MATERIAL",
"I_MATERIALTEXT",
"I_SUPPLIER",
"MATDOC"
],
"ASSOCIATED":
[
"I_COSTCENTER",
"I_CURRENCY",
"I_DELIVERYDOCUMENTITEM",
"I_MATERIAL",
"I_PLANT",
"I_STORAGELOCATION",
"I_SUPPLIER",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/