C_RFQValueHelp

@ObjectModel.representativeKey: 'RequestForQuotation'
@ObjectModel.semanticKey: 'RequestForQuotation'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ClientHandling.algorithm: #SESSION_VARIABLE //Inserted by VDM CDS Suite Plugin

@AbapCatalog.sqlViewName: 'CRFQVALUEHELP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@EndUserText.label: 'Request for Quotation Value Help'

//@AccessControl.privilegedAssociations: [ '_UserContactCard' ]


define view C_RFQValueHelp
  as select from I_RequestForQuotation

  association [0..*] to I_PurchasingDocumentTypeText as _RFQTypeText     on  _RFQTypeText.PurchasingDocumentType     = $projection.RFQType
                                                                         and _RFQTypeText.PurchasingDocumentCategory = $projection.RFQCategory

  association [0..1] to I_UserContactCard            as _UserContactCard on  _UserContactCard.ContactCardID = $projection.CreatedByUser
{

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
      @ObjectModel.text.association: '_RFQTypeText'
  key I_RequestForQuotation.RequestForQuotation,

      I_RequestForQuotation.PurchasingDocumentType     as RFQType,
      I_RequestForQuotation.PurchasingDocumentCategory as RFQCategory,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
      @Semantics.text: true
      I_RequestForQuotation.RequestForQuotationName,

      @ObjectModel.text.element:  [ 'FullName' ]
      @UI.textArrangement: #TEXT_ONLY
      I_RequestForQuotation.CreatedByUser,

      cast( _UserContactCard.FullName as vdm_full_name preserving type) as FullName,
      
      //DCL

      @UI.hidden: true
      PurchasingOrganization,
      @UI.hidden: true
      PurchasingGroup,
      @UI.hidden: true
      PurchasingDocumentType,
      @UI.hidden: true
      IsEndOfPurposeBlocked,

      _RFQTypeText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_REQUESTFORQUOTATION",
"I_USERCONTACTCARD"
],
"ASSOCIATED":
[
"I_PURCHASINGDOCUMENTTYPETEXT",
"I_USERCONTACTCARD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/