C_REIntegObjMsmtByKeyDate

DDL: C_REINTEGOBJMSMTBYKEYDATE Type: view_entity CONSUMPTION

Integration Object Measurement by Keydate

C_REIntegObjMsmtByKeyDate is a Consumption CDS View that provides data about "Integration Object Measurement by Keydate" in SAP S/4HANA. It reads from 3 data sources (I_CalendarDate, I_REIntegObjectSubObjValidity, I_REIntegrationObjectBasicData) and exposes 6 fields with key fields InternalRealEstateNumber, REMeasurementType, REKeyDate. It has 1 association to related views.

3 data source(s) 6 fields

Data Sources (3)

SourceAliasJoin Type
I_CalendarDate _CalendarDate cross
I_REIntegObjectSubObjValidity _REIntegObjectSubObjValidity inner
I_REIntegrationObjectBasicData _REIntegrationObject from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_REMeasurement _REMeasurement _REIntegObjectSubObjValidity.InternalRealEstateNumberLvl3 = _REMeasurement.InternalRealEstateNumber and _REMeasurement.ValidityStartDate <= _CalendarDate.CalendarDate and _REMeasurement.ValidityEndDate >= _CalendarDate.CalendarDate

Annotations (7)

NameValueLevelField
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Integration Object Measurement by Keydate view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #MIXED view
VDM.viewType #CONSUMPTION view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY InternalRealEstateNumber I_REIntegrationObjectBasicData InternalRealEstateNumber
KEY REMeasurementType _REMeasurement REMeasurementType
KEY REKeyDate
REMeasurementUnit _REMeasurement REMeasurementUnit
REMeasurementQuantity
_REMeasurementType _REMeasurement _REMeasurementType 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Integration Object Measurement by Keydate'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #L,
  dataClass: #MIXED
}
@VDM.viewType: #CONSUMPTION
define view entity C_REIntegObjMsmtByKeyDate
  as select from I_REIntegrationObjectBasicData as _REIntegrationObject
    cross join   I_CalendarDate                 as _CalendarDate
    inner join   I_REIntegObjectSubObjValidity  as _REIntegObjectSubObjValidity on (
       _REIntegObjectSubObjValidity.InternalRealEstateNumberLvl0                                                                         =  _REIntegrationObject.InternalRealEstateNumber
       or _REIntegObjectSubObjValidity.InternalRealEstateNumberLvl1                                                                      =  _REIntegrationObject.InternalRealEstateNumber
       or _REIntegObjectSubObjValidity.InternalRealEstateNumberLvl2                                                                      =  _REIntegrationObject.InternalRealEstateNumber
       or _REIntegObjectSubObjValidity.InternalRealEstateNumberLvl3                                                                      =  _REIntegrationObject.InternalRealEstateNumber
     )
                                                                                and(
                                                                                  (
                                                                                    _REIntegObjectSubObjValidity.ValidityStartDateLvl0   <= _CalendarDate.CalendarDate
                                                                                    and _REIntegObjectSubObjValidity.ValidityEndDateLvl0 >= _CalendarDate.CalendarDate
                                                                                  )
                                                                                  and(
                                                                                    _REIntegObjectSubObjValidity.ValidityStartDateLvl1   <= _CalendarDate.CalendarDate
                                                                                    and _REIntegObjectSubObjValidity.ValidityEndDateLvl1 >= _CalendarDate.CalendarDate
                                                                                  )
                                                                                  and(
                                                                                    _REIntegObjectSubObjValidity.ValidityStartDateLvl2   <= _CalendarDate.CalendarDate
                                                                                    and _REIntegObjectSubObjValidity.ValidityEndDateLvl2 >= _CalendarDate.CalendarDate
                                                                                  )
                                                                                  and(
                                                                                    _REIntegObjectSubObjValidity.ValidityStartDateLvl3   <= _CalendarDate.CalendarDate
                                                                                    and _REIntegObjectSubObjValidity.ValidityEndDateLvl3 >= _CalendarDate.CalendarDate
                                                                                  )
                                                                                )
  association [0..1] to I_REMeasurement as _REMeasurement on  _REIntegObjectSubObjValidity.InternalRealEstateNumberLvl3 =  _REMeasurement.InternalRealEstateNumber
                                                          and _REMeasurement.ValidityStartDate                          <= _CalendarDate.CalendarDate
                                                          and _REMeasurement.ValidityEndDate                            >= _CalendarDate.CalendarDate
{
  key _REIntegrationObject.InternalRealEstateNumber                      as InternalRealEstateNumber,
  key _REMeasurement.REMeasurementType,
  key cast ( _CalendarDate.CalendarDate as recakeydate preserving type ) as REKeyDate,
      _REMeasurement.REMeasurementUnit,
      @Semantics.quantity.unitOfMeasure: 'REMeasurementUnit'
      @DefaultAggregation: #SUM
      sum(_REMeasurement.REMeasurementQuantity)                          as REMeasurementQuantity,

      /* Associations */
      _REMeasurement._REMeasurementType
}
group by
  _REIntegrationObject.InternalRealEstateNumber,
  _CalendarDate.CalendarDate,
  _REMeasurement.REMeasurementType,
  _REMeasurement.REMeasurementUnit
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CALENDARDATE",
"I_REINTEGOBJECTSUBOBJVALIDITY",
"I_REINTEGRATIONOBJECTBASICDATA",
"I_REMEASUREMENT"
],
"ASSOCIATED":
[
"I_REMEASUREMENTTYPE"
],
"BASE":
[
"I_REMEASUREMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More