I_REINTEGRATIONOBJECTBASICDATA
Real Estate Integration Object
I_REINTEGRATIONOBJECTBASICDATA is a CDS View in S/4HANA. Real Estate Integration Object. It contains 10 fields. 20 CDS views read from this table.
CDS Views using this table (20)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_REIntegObjMsmtByKeyDate | view_entity | from | CONSUMPTION | Integration Object Measurement by Keydate |
| I_REIntegObject2SpaceGrpHier | view | inner | COMPOSITE | Real Estate Integ Object to Space Group Hierarchy |
| I_REIntegObjectObjectAssgmt | view | inner | COMPOSITE | Real Estate Integration Object Assignment |
| I_REIntegObjectValidity | view | from | COMPOSITE | Real Estate Integ Obj Validity |
| I_REIntegObjectValidity | view | union_all | COMPOSITE | Real Estate Integ Obj Validity |
| I_REIntegrationObject | view | from | COMPOSITE | Real Estate Integration Object |
| I_REIntegrationObjectStatusObj | view | from | COMPOSITE | Real Estate Integration Object Status |
| I_REIntegrationObjectSubObj | view | from | COMPOSITE | Real Estate Integ Object Subobject |
| P_REIntegObjectMsmtByKeyDate | view_entity | from | COMPOSITE | Integration Object Measurement by Keydate |
| P_REIntegObjectValidityCalc1 | view | inner | COMPOSITE | |
| P_REIntegObjectValidityCalc2 | view | union | COMPOSITE | |
| P_REIntegObjectValidityCalc3 | view | inner | COMPOSITE | |
| P_REIntegObjectValidityCalc4 | view | inner | COMPOSITE | |
| P_REIntegObjectValidityCalc4 | view | union | COMPOSITE | |
| P_REIntegObjMsmtHierCalc4 | view_entity | from | COMPOSITE | Integration Object Measurement Hierarchy Date Calc View 4 |
| P_REIntegObjMsmtHierCalc4 | view_entity | union_all | COMPOSITE | Integration Object Measurement Hierarchy Date Calc View 4 |
| P_REIntegObjMsmtHierDateCalc2 | view_entity | union_all | COMPOSITE | Integration Object Measurement Hierarchy Date Calc View 2 |
| P_REIntegObjMsmtSliceByKeyDate | view_entity | from | COMPOSITE | Integration Object Measurement Time Slices by Keydate |
| P_REIntegObjOccpcyHierCalc1 | view_entity | union_all | COMPOSITE | Integration Object Occupancy Hierarchy Calc View 1 |
| P_REIntegObjOccpcyHierCalc4 | view_entity | inner | COMPOSITE | Integration Object Occupancy Hierarchy Calc View 4 |
Fields (10)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | InternalRealEstateNumber | InternalRealEstateNumber,InternalRealEstateNumberLvl0 | 9 |
| KEY | REStatusObject | REStatusObject | 1 |
| _UnitOfMeasureArea | _UnitOfMeasureArea | 1 | |
| RealEstateExternalID | RealEstateExternalID,RealEstateExternalIDLvl0 | 6 | |
| REAreaUnit | REAreaUnit | 1 | |
| REIntegObjSpaceGroupType | REIntegObjSpaceGroupType | 1 | |
| REIntegrationObjectName | REIntegObjectSiteName | 1 | |
| REIntegrationObjectNumber | REIntegrationObjectNumberLvl0 | 1 | |
| REIntegrationObjectType | REIntegrationObjectType,REIntegrationObjectTypeLvl0 | 4 | |
| REInternalNumberForUseEnable | REInternalNumberForUseEnable | 1 |
@AbapCatalog.sqlViewName: 'IREINTOBJECTBSC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Real Estate Integration Object'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'InternalRealEstateNumber'
@ObjectModel.semanticKey: ['RealEstateExternalID']
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
//@Analytics.internalName:#LOCAL
//@Analytics:{
// dataCategory: #DIMENSION,
// dataExtraction: {
// enabled: true,
// delta.changeDataCapture: {
// automatic: true
// }
// }
//}
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [ #ANALYTICAL_DIMENSION,
#CDS_MODELING_ASSOCIATION_TARGET,
#SQL_DATA_SOURCE,
#CDS_MODELING_DATA_SOURCE,
#SEARCHABLE_ENTITY ]
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true
@VDM.viewType: #BASIC
define view I_REIntegrationObjectBasicData
as select from viipobject
association [0..1] to I_User as _CreatedByUser on $projection.CreatedByUser = _CreatedByUser.UserID
association [0..1] to I_User as _ChangedByUser on $projection.LastChangedByUser = _ChangedByUser.UserID
association [0..1] to I_User as _ResponsibleUser on $projection.Responsible = _ResponsibleUser.UserID
association [0..1] to I_UnitOfMeasure as _UnitOfMeasureArea on $projection.REAreaUnit = _UnitOfMeasureArea.UnitOfMeasure
association [1..1] to I_REKeyAssgmt as _REKeyAssgmt on $projection.InternalRealEstateNumber = _REKeyAssgmt.InternalRealEstateNumber
association [0..1] to I_REAuthorizationGroup as _REAuthorizationGroup on $projection.REAuthorizationGroup = _REAuthorizationGroup.REAuthorizationGroup
and _REAuthorizationGroup.RealEstateObjectType = 'J5'
association [1..1] to I_REIntegObjectType as _REIntegObjectType on $projection.REIntegrationObjectType = _REIntegObjectType.REIntegrationObjectType
association [1..1] to I_REIntegObjectType as _REParentIntegObjectType on $projection.REParentIntegObjectType = _REParentIntegObjectType.REIntegrationObjectType
association [1..1] to I_REIntegObjCtrlgObjType as _REIntegObjCtrlgObjType on $projection.REIntegObjectCtrlgObjectType = _REIntegObjCtrlgObjType.REIntegObjectCtrlgObjectType
association [1..1] to I_REIntegObjSpaceGroupType as _REIntegObjSpaceGroupType on $projection.REIntegObjSpaceGroupType = _REIntegObjSpaceGroupType.REIntegObjSpaceGroupType
association [1..1] to I_RESpaceGroupUsageType as _RESpaceGroupUsageType on $projection.RESpaceGroupUsageType = _RESpaceGroupUsageType.RESpaceGroupUsageType
association [1..1] to I_RESpaceGrpEnableUseType as _RESpaceGrpEnableUseType on $projection.RESpaceGrpEnableUseType = _RESpaceGrpEnableUseType.RESpaceGrpEnableUseType
association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_StatusObject as _StatusObject on $projection.REStatusObject = _StatusObject.StatusObject
association [1..*] to I_StatusObjectStatus as _StatusObjectStatus on $projection.REStatusObject = _StatusObjectStatus.StatusObject
association [0..1] to I_REObjectAddress as _REObjectAddress on $projection.InternalRealEstateNumber = _REObjectAddress.InternalRealEstateNumber
association [1..*] to I_REIntegObjectOccupancy as _REIntegObjectOccupancy on $projection.InternalRealEstateNumber = _REIntegObjectOccupancy.REIntegObjectInternalNumber
association [1..*] to I_REIntegObjToContractAssgmt as _REIntegObjToContractAssgmt on $projection.REStatusObject = _REIntegObjToContractAssgmt.REStatusObjectSource
association [1..1] to I_REIntegrationObjectSubObj as _REIntegrationObjSubObj on _REIntegrationObjSubObj.InternalRealEstateNumberLvl0 = $projection.InternalRealEstateNumber
or _REIntegrationObjSubObj.InternalRealEstateNumberLvl1 = $projection.InternalRealEstateNumber
or _REIntegrationObjSubObj.InternalRealEstateNumberLvl2 = $projection.InternalRealEstateNumber
or _REIntegrationObjSubObj.InternalRealEstateNumberLvl3 = $projection.InternalRealEstateNumber
// parent
association [0..1] to I_REIntegrationObject as _REParentIntegrationObject on $projection.REParentIntegObjectExternalID = _REParentIntegrationObject.RealEstateExternalID
association [0..1] to I_REIntegrationObjectBasicData as _REUseEnableIntegrationObject on $projection.REInternalNumberForUseEnable = _REUseEnableIntegrationObject.InternalRealEstateNumber
// children
association [0..*] to I_REIntegrationObjectRelation as _REIntegrationObjectRelation on $projection.InternalRealEstateNumber = _REIntegrationObjectRelation.InternalRealEstateNumber
association [0..*] to I_REIntegObjectRelationPartial as _REIntegObjectRelationPartial on $projection.InternalRealEstateNumber = _REIntegObjectRelationPartial.InternalRealEstateNumber
association [0..*] to I_REPartnerAssgmt as _REPartnerAssgmt on $projection.InternalRealEstateNumber = _REPartnerAssgmt.InternalRealEstateNumber
association [0..*] to I_REObjectAssgmt as _REObjectAssgmt on $projection.REStatusObject = _REObjectAssgmt.REStatusObjectSource
association [0..*] to I_REReminderObjRule as _REReminderRule on $projection.InternalRealEstateNumber = _REReminderRule.InternalRealEstateNumber
association [0..*] to I_REIntegObjectMeasurement as _REMeasurement on $projection.InternalRealEstateNumber = _REMeasurement.InternalRealEstateNumber
association [0..*] to I_REIntegObjectAcctObjAssgmt as _REIntegObjectAcctObjAssgmt on $projection.InternalRealEstateNumber = _REIntegObjectAcctObjAssgmt.InternalRealEstateNumber
association [0..*] to I_REIntegrationObjectTimeline as _REIntegrationObjectTimeline on $projection.InternalRealEstateNumber = _REIntegrationObjectTimeline.InternalRealEstateNumber
// Extensibility
association [1..1] to E_REIntegrationObject as _Extension on $projection.InternalRealEstateNumber = _Extension.InternalRealEstateNumber
{
key intreno as InternalRealEstateNumber,
extid as RealEstateExternalID,
@ObjectModel.foreignKey.association: '_StatusObject'
objnr as REStatusObject,
ionr as REIntegrationObjectNumber,
@ObjectModel.foreignKey.association: '_REIntegObjectType'
iotype as REIntegrationObjectType,
@ObjectModel.foreignKey.association: '_REIntegObjCtrlgObjType'
iocoobjtype as REIntegObjectCtrlgObjectType,
xsobject as REIntegrationObjectName,
xlobject as REIntegObjectLongName,
@ObjectModel.foreignKey.association: '_REIntegObjSpaceGroupType'
iosgtype as REIntegObjSpaceGroupType,
@ObjectModel.foreignKey.association: '_RESpaceGroupUsageType'
iosgusagetype as RESpaceGroupUsageType,
@ObjectModel.foreignKey.association: '_RESpaceGrpEnableUseType'
iosgenableusetype as RESpaceGrpEnableUseType,
@ObjectModel.foreignKey.association: '_REUseEnableIntegrationObject'
intrenoenableuse as REInternalNumberForUseEnable,
@ObjectModel.foreignKey.association: '_CompanyCode'
bukrs as CompanyCode,
@ObjectModel.foreignKey.association: '_REParentIntegObjectType'
ioparenttype as REParentIntegObjectType,
ioparentextid as REParentIntegObjectExternalID,
@ObjectModel.foreignKey.association: '_UnitOfMeasureArea'
areaunit as REAreaUnit,
// @ObjectModel.foreignKey.association: '_CreatedByUser'
rerf as CreatedByUser,
derf as CreationDate,
terf as CreationTime,
reher as RESourceOfCreation,
// @ObjectModel.foreignKey.association: '_ChangedByUser'
rbear as LastChangedByUser,
dbear as LastChangeDate,
tbear as LastChangeTime,
rbher as RESourceOfChange,
// @ObjectModel.foreignKey.association: '_ResponsibleUser'
responsible as Responsible,
@ObjectModel.foreignKey.association: '_REAuthorizationGroup'
authgrp as REAuthorizationGroup,
_CreatedByUser,
_ChangedByUser,
_ResponsibleUser,
_UnitOfMeasureArea,
_REAuthorizationGroup,
_REIntegObjectType,
_REIntegObjCtrlgObjType,
_REParentIntegObjectType,
_REIntegObjSpaceGroupType,
_RESpaceGroupUsageType,
_RESpaceGrpEnableUseType,
_REKeyAssgmt,
_StatusObject,
_StatusObjectStatus,
_REObjectAddress,
_REIntegObjectOccupancy,
_REIntegObjToContractAssgmt,
_REIntegrationObjSubObj,
_REParentIntegrationObject,
_REUseEnableIntegrationObject,
_CompanyCode,
_REIntegrationObjectRelation,
_REIntegObjectRelationPartial,
_REPartnerAssgmt,
_REObjectAssgmt,
_REReminderRule,
_REMeasurement,
_REIntegObjectAcctObjAssgmt,
_REIntegrationObjectTimeline
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"VIIPOBJECT"
],
"ASSOCIATED":
[
"E_REINTEGRATIONOBJECT",
"I_COMPANYCODE",
"I_REAUTHORIZATIONGROUP",
"I_REINTEGOBJCTRLGOBJTYPE",
"I_REINTEGOBJECTACCTOBJASSGMT",
"I_REINTEGOBJECTMEASUREMENT",
"I_REINTEGOBJECTOCCUPANCY",
"I_REINTEGOBJECTRELATIONPARTIAL",
"I_REINTEGOBJECTTYPE",
"I_REINTEGOBJSPACEGROUPTYPE",
"I_REINTEGOBJTOCONTRACTASSGMT",
"I_REINTEGRATIONOBJECT",
"I_REINTEGRATIONOBJECTRELATION",
"I_REINTEGRATIONOBJECTSUBOBJ",
"I_REINTEGRATIONOBJECTTIMELINE",
"I_REKEYASSGMT",
"I_REOBJECTADDRESS",
"I_REOBJECTASSGMT",
"I_REPARTNERASSGMT",
"I_REREMINDEROBJRULE",
"I_RESPACEGROUPUSAGETYPE",
"I_RESPACEGRPENABLEUSETYPE",
"I_STATUSOBJECT",
"I_STATUSOBJECTSTATUS",
"I_UNITOFMEASURE",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/