@AbapCatalog: {
compiler.compareFilter: true,
sqlViewName: 'CQLTYCNTRLCHART'
}
@AccessControl: {
authorizationCheck: #CHECK,
personalData.blocking:#REQUIRED,
privilegedAssociations: [ '_CreatedByUserContactCard', '_LastChangedByUserContactCard' ]
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Quality Control Chart'
@Metadata.allowExtensions: true
@ObjectModel: {
usageType: { serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED },
semanticKey: [ 'QualityControlChart']
}
@Search.searchable: true
@VDM.viewType: #CONSUMPTION
define view C_QualityControlChart
as select from I_QualityCtrlChartTP as _QualityControlChart
association [0..*] to P_QualityControlChartResults as _QualityControlChartResults on $projection.QualityControlChart = _QualityControlChartResults.QualityControlChart
association [1..1] to P_InspCharcSmplSizeAggrgn as _InspCharcSmplSizeAggrgn on $projection.QualityControlChart = _InspCharcSmplSizeAggrgn.QualityControlChart
//*** Associations ***//
// Calcualtion View
association [1..1] to C_QltyCtrlChtCalc as _QltyCtrlChtCalc on $projection.QualityControlChart = _QltyCtrlChtCalc.QualityControlChart
association [0..1] to C_QltyCtrlChtCharcs as _QltyCtrlChtCharcs on $projection.LastCtrlChtInspectionLot = _QltyCtrlChtCharcs.InspectionLot
and $projection.LastCtrlChtInspPlanOplIntID = _QltyCtrlChtCharcs.InspPlanOperationInternalID
and $projection.LastCtrlChtInspCharacteristic = _QltyCtrlChtCharcs.InspectionCharacteristic
and $projection.LastCtrlChtInspSbstIntID = _QltyCtrlChtCharcs.InspectionSubsetInternalID
// Control Chart Track
association [0..*] to C_QualityControlChartTrack as _ControlChartTrack on $projection.QualityControlChart = _ControlChartTrack.QualityControlChart
// Control Chart Track-1
association [0..1] to C_QualityControlChartTrack as _QltyCtrlChtTrack1 on $projection.QualityControlChart = _QltyCtrlChtTrack1.QualityControlChart
and _QltyCtrlChtTrack1.QualityControlChartTrack = '1'
//*** Contact Card ***//
association [0..1] to I_UserContactCard as _CreatedByUserContactCard on $projection.QltyCtrlChartCreatedByUser = _CreatedByUserContactCard.ContactCardID
association [0..1] to I_UserContactCard as _LastChangedByUserContactCard on $projection.QltyCtrlChartLastChangedByUser = _LastChangedByUserContactCard.ContactCardID
//*** Visual Filters ***//
association [1..1] to C_QltyCtrlExcdLmtVislFltr as _QltyCtrlExcdLmtVislFltr on $projection.QualityControlChart = _QltyCtrlExcdLmtVislFltr.QualityControlChart
association [1..1] to C_QltyCtrlChartWrkCtrVislFltr as _QltyCtrlChartWrkCtrVislFltr on $projection.QualityControlChart = _QltyCtrlChartWrkCtrVislFltr.QualityControlChart
association [1..1] to C_QltyCtrlDvtnMatlVislFltr as _QltyCtrlDvtnMatlVislFltr on $projection.QualityControlChart = _QltyCtrlDvtnMatlVislFltr.QualityControlChart
association [1..1] to C_QltyCtrlNonActvVislFltr as _QltyCtrlNonActvVislFltr on $projection.QualityControlChart = _QltyCtrlNonActvVislFltr.QualityControlChart
{
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
key _QualityControlChart.QualityControlChart,
@Consumption.valueHelpDefinition: [
{
entity: { name: 'I_InspectionLotVH2', element: 'InspectionLot' }
}
]
key _QualityControlChartResults.InspectionLot,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChartResults.InspPlanOperationInternalID,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChartResults.InspectionSubsetInternalID,
//*** Table - Default Columns ***//
@Consumption.valueHelpDefinition: [
{
entity: { name: 'C_QltyControlChartTypeVH', element: 'QualityControlChartType' }
}
]
@ObjectModel.text.element: [ 'QualityControlChartTypeText' ]
cast (_QualityControlChart.QualityControlChartType as vdm_qmcharttype preserving type ) as QualityControlChartType,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
@Semantics.text: true
_QualityControlChart._QualityControlChartType._Text[1:Language=$session.system_language].QualityControlChartTypeText,
@ObjectModel.text.element: [ 'InspectionSpecificationText' ]
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChartResults.InspectionCharacteristic,
@Semantics.text: true
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChartResults.InspectionSpecificationText as InspectionSpecificationText,
@Consumption.valueHelpDefinition: [
{
entity: { name: 'C_QltyControlChartStatusVH', element: 'QualityControlChartStatus' }
}
]
@ObjectModel: {
text: {
element: [ 'QualityControlChartStatusText' ]
}
}
_QualityControlChart.QualityControlChartStatus,
@Semantics.text: true
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart._QualityControlChartStatus._Text[1:Language=$session.system_language].QualityControlChartStatusText,
@Consumption.valueHelpDefinition:[
{
entity: { name: 'C_WrkCtrVH', element: 'WorkCenter' },
additionalBinding:[ { localElement: 'MainWorkCenterPlant', element: 'Plant' } ]
}
]
@ObjectModel: {
foreignKey: {
association: '_WorkCenter'
},
text: {
element: [ 'ControlChartWorkCenterText' ]
}
//filter.enabled: false
}
@Consumption.filter.hidden: true
_QualityControlChart.WorkCenter as ControlChartWorkCenter,
@Semantics.text: true
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart._WorkCenter._WorkCenterTextBySemanticKey[1:Language=$session.system_language].WorkCenterText as ControlChartWorkCenterText,
@Consumption.valueHelpDefinition: [
{
entity: { name: 'I_PlantStdVH',element: 'Plant' }
}
]
@ObjectModel.text.element: [ 'PlantName' ]
_QualityControlChart.Plant,
@Semantics.text: true
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart._Plant.PlantName,
@Consumption.valueHelpDefinition: [
{
entity: { name: 'I_MaterialStdVH', element: 'Material' }
}
]
@ObjectModel: {
foreignKey: {
association: '_Material'
},
text: {
element: [ 'ControlChartMaterialText' ]
}
//filter.enabled: false
}
@Consumption.filter.hidden: true
_QualityControlChart.Material as ControlChartMaterial,
@Semantics.text: true
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart._Material._Text[1:Language=$session.system_language].MaterialName as ControlChartMaterialText,
//***************************************************************************************************************************************************************//
//*** Selection Fields ***//
@Consumption.valueHelpDefinition: [
{
entity: { name: 'I_ProductVH',element: 'Product' }
}
]
@ObjectModel.text.element: [ 'MaterialName' ]
_QualityControlChart._InspectionLot.Material,
@Semantics.text: true
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart._InspectionLot._Material._Text[1:Language=$session.system_language].MaterialName,
@Consumption.valueHelpDefinition:[
{
entity: { name: 'C_WrkCtrVH', element: 'WorkCenter' },
additionalBinding:[ { localElement: 'MainWorkCenterPlant', element: 'Plant' } ]
}
]
@ObjectModel.text.element: [ 'WorkCenterText' ]
_QualityControlChartResults.WorkCenter,
@Semantics.text: true
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChartResults.WorkCenterText,
@Consumption.valueHelpDefinition: [
{
entity: { name: 'C_QltyCtrlChtAggrgnCritrnVH', element: 'QltyCtrlChartAggrgnCriterion' }
}
]
@ObjectModel.text.element: [ 'QltyCtrlChtAggrgnCriterionTxt' ]
_QualityControlChart.QltyCtrlChartAggrgnCriterion,
@Semantics.text: true
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart._QltyCtrlChartAggrgnCriterion._Text[1:Language=$session.system_language].QltyCtrlChtAggrgnCriterionTxt,
@Consumption: {
filter:{ selectionType: #SINGLE, multipleSelections: false },
valueHelpDefinition: [
{
entity: { name: 'I_QltyCtrlChtDvtnSts', element: 'QltyCtrlChtDvtnSts' }
}
]
}
@ObjectModel.text.element: [ 'QltyCtrlChtDvtnStsTxt' ]
_QltyCtrlChtCalc.QltyCtrlChtDvtnSts,
@Semantics.text: true
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QltyCtrlChtCalc._QltyCtrlChtDvtnSts._QltyCtrlChtDvtnStsTxt[1:Language=$session.system_language].QltyCtrlChtDvtnStsTxt,
@Consumption.valueHelpDefinition:[
{
entity: { name: 'C_InspSpecVH', element: 'InspectionSpecification' },
additionalBinding: [ { localElement: 'InspectionSpecificationPlant', element: 'InspectionSpecificationPlant' } ]
}
]
@ObjectModel.text.element: [ 'InspectionSpecificationText' ]
_QualityControlChart.InspectionSpecification,
@Consumption.valueHelpDefinition: [
{
entity: { name: 'C_MngQltyLvlBOOTypeVH',element: 'BillOfOperationsType' }
}
]
@ObjectModel.text.element: [ 'BillOfOperationsTypeName' ]
_QualityControlChartResults.BillOfOperationsType,
@Consumption.valueHelpDefinition: [
{
entity: { name: 'C_MngQltyLvlBOOGrpVH', element: 'BillOfOperationsGroup' }
}
]
_QualityControlChartResults.BillOfOperationsGroup,
@Consumption.valueHelpDefinition: [
{
entity: { name: 'C_BOOGrpCntrVH', element: 'BillOfOperationsVariant' },
additionalBinding:[
{ localElement: 'BillOfOperationsGroup', element: 'BillOfOperationsGroup' },
{ localElement: 'BillOfOperationsType', element: 'BillOfOperationsType' }
]
}
]
_QualityControlChartResults.BillOfOperationsVariant,
@Consumption: {
valueHelpDefinition: [
{
entity: { name: 'C_NmbrOfRsltsRecordedCatVH', element: 'DomainValue' }
}
]
}
case
when _InspCharcSmplSizeAggrgn.InspectionPartialSampleSize > 70 then cast ( '3' as vdm_qeifstpanz )
when _InspCharcSmplSizeAggrgn.InspectionPartialSampleSize >= 31 and _InspCharcSmplSizeAggrgn.InspectionPartialSampleSize <= 70 then cast ( '2' as vdm_qeifstpanz )
else cast ( '1' as vdm_qeifstpanz )
end as NmbrOfRsltsRecordedCat,
//***************************************************************************************************************************************************************//
//*** Additional Fields & Columns ***//
@Consumption.valueHelpDefinition: [
{
entity: { name: 'I_PlantStdVH',element: 'Plant' }
}
]
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart.InspectionSpecificationPlant,
@Consumption.valueHelpDefinition: [
{
entity: { name: 'I_PlantStdVH',element: 'Plant' }
}
]
@ObjectModel: {
foreignKey: {
association: '_MainWorkCenterPlant'
}
//filter.enabled: false
}
@Consumption.filter.hidden: true
_QualityControlChart.MainWorkCenterPlant,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart.Equipment,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart.FunctionalLocation,
@Consumption.valueHelpDefinition: [
{
entity: { name: 'I_Supplier_VH', element: 'Supplier'}
}
]
@EndUserText.quickInfo: 'Account Number of Supplier'
_QualityControlChartResults.Supplier as InspLotSelectionSupplier,
@Consumption.valueHelpDefinition: [
{
entity: { name: 'I_Customer_VH', element: 'Customer' }
}
]
@ObjectModel: {
foreignKey: {
association: '_Customer'
}
}
_QualityControlChart._InspectionLot.Customer,
@Consumption.valueHelpDefinition: [
{
entity: { name: 'C_InspectionLotOriginValueHelp', element: 'InspectionLotOrigin' }
}
]
@ObjectModel: {
foreignKey: {
association: '_InspectionLotOrigin'
}
}
_QualityControlChart._InspectionLot.InspectionLotOrigin,
@Consumption.valueHelpDefinition: [
{
entity: { name: 'I_InspectionLotType', element: 'InspectionLotType' }
}
]
@ObjectModel: {
foreignKey: {
association: '_InspectionLotType'
},
text: {
element: [ 'InspectionLotTypeText' ]
}
}
_QualityControlChart._InspectionLot.InspectionLotType,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart._InspectionLot._InspectionLotType._Text[1:Language=$session.system_language].InspectionLotTypeText,
@Consumption.valueHelpDefinition: [
{
entity: { name: 'I_Supplier_VH', element: 'Supplier' }
}
]
@ObjectModel: {
foreignKey: {
association: '_Manufacturer'
}
}
_QualityControlChart._InspectionLot.Manufacturer,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart.QualityControlChartText,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart._QualityControlChartType.ControlChartAxisType,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart.InspSpecUpperLimit,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart.InspSpecHasUpperLimit,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart.InspSpecLowerLimit,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart.InspSpecHasLowerLimit,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QltyCtrlChtCalc.QualityControlChartTracks,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
cast( 0 as vdm_qmsmplsize ) as InspectionSampleSize,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
cast( 0 as qvarianz ) as InspResultVariance,
// @DefaultAggregation: #SUM
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
// _QualityControlChartResults.ActionLimitDeviations,
_QualityControlChartResults.InspectionValuationResult,
@Consumption.filter.hidden: true
_QualityControlChartResults.InspSubsetResultValuation,
@DefaultAggregation: #SUM
@Consumption.filter.hidden: true
case
when (_QualityControlChartResults.InspectionValuationResult='R' and _QualityControlChartResults.InspectionSubsetInternalID='000000')
then cast( 1 as vdm_actionlmtdeviationscount )
when _QualityControlChartResults.InspectionValuationResult= 'R' and _QualityControlChartResults.InspSubsetResultValuation='R' and _QualityControlChartResults.InspectionSubsetInternalID != '000000'
then cast( 1 as vdm_actionlmtdeviationscount )
when ( _QualityControlChartResults.InspectionValuationResult ='R' and _QualityControlChartResults.InspSubsetResultValuation='A'and _QualityControlChartResults.InspectionSubsetInternalID != '000000')
then cast(0 as vdm_actionlmtdeviationscount)
end as ActionLimitDeviations,
@Consumption: { filter:{ selectionType: #INTERVAL, multipleSelections: false} }
cast ( _QualityControlChartResults.InspectionEndDate as vdm_qpruefdatb preserving type ) as InspectionEndDate,
@Consumption.filter.hidden: true
cast ( _QualityControlChartResults.InspectionEndTime as qpruefztb preserving type ) as InspectionEndTime,
//***************************************************************************************************************************************************************//
//*** Object Page Header (Data filled from CL_QM_CHARTS_DPC_EXT~C_QUALITYCONTROL_GET_ENTITYSET) ***//
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
cast( '' as vdm_qqrkcpc ) as CtrlChartProcessCapability,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
cast( '' as vdm_qqrkcpkc ) as CtrlChartMeanProcessCapability,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
cast( '' as qqrkpc ) as InspectionNonconformingRatio,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
cast( 0 as qanzstipro ) as InspectionPartialSampleSize,
//***************************************************************************************************************************************************************//
//*** Facet - Statistical Information ***//
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
cast( _QltyCtrlChtTrack1.CtrlChartLowerActionLimit as vdm_qqrkueg1 preserving type ) as CtrlChartLowerActionLimit,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
cast( _QltyCtrlChtTrack1.CtrlChartLowerWarningLimit as vdm_qqrkuwg1 preserving type ) as CtrlChartLowerWarningLimit,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
cast( _QltyCtrlChtTrack1.CtrlChartMeanValue as vdm_qqrkmil1 preserving type ) as CtrlChartMeanValue,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
cast( _QltyCtrlChtTrack1.CtrlChartUpperActionLimit as vdm_qqrkoeg1 preserving type ) as CtrlChartUpperActionLimit,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
cast( _QltyCtrlChtTrack1.CtrlChartUpperWarningLimit as vdm_qqrkowg1 preserving type ) as CtrlChartUpperWarningLimit,
//*** Facet - Bill of Operations ***//
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
@ObjectModel.text.element: [ 'BillOfOperationsTypeName' ]
_QualityControlChart.BillOfOperationsType as CtrlChartBillOfOperationsType,
@Semantics.text: true
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart._BillOfOperationsType._Text[1:Language=$session.system_language].BillOfOperationsTypeName,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart.BillOfOperationsGroup as CtrlChartBillOfOperationsGroup,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart.BillOfOperationsVariant as CtrlChtBillOfOperationsVariant,
//*** Facet - Administrative Data ***//
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart.QltyCtrlChartCreatedByUser,
@Consumption: { filter:{ selectionType: #INTERVAL, multipleSelections: false} }
cast( _QualityControlChart.QltyCtrlChartCreationDate as vdm_erdat preserving type ) as QltyCtrlChartCreationDate,
@ObjectModel: { filter.enabled: false }
_QualityControlChart.QltyCtrlChartCreationTime,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart.QltyCtrlChartLastChangedByUser,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChart.QltyCtrlChartLastChangedDate,
@ObjectModel: { filter.enabled: false }
_QualityControlChart.QltyCtrlChartLastChangedTime,
//***************************************************************************************************************************************************************//
//Fields to fetch Last Inspection Lot to display in char section - Start
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QltyCtrlChtCalc.LastCtrlChtInspectionLot as LastCtrlChtInspectionLot,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QltyCtrlChtCalc.LastCtrlChtInspPlanOplIntID as LastCtrlChtInspPlanOplIntID,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QltyCtrlChtCalc.LastCtrlChtInspCharacteristic as LastCtrlChtInspCharacteristic,
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QltyCtrlChtCalc.LastCtrlChtInspSbstIntID as LastCtrlChtInspSbstIntID,
//Fields to fetch Last Inspection Lot to display in char section - End
//***************************************************************************************************************************************************************//
//@ObjectModel: { filter.enabled: false }
@Consumption.filter.hidden: true
_QualityControlChartResults.Supplier,
//*** Contact Card Associations ***//
@Consumption.filter.hidden: true
_CreatedByUserContactCard,
@Consumption.filter.hidden: true
_LastChangedByUserContactCard,
//*** Associations ***//
@Consumption.filter.hidden: true
_QltyCtrlChtCalc,
@Consumption.filter.hidden: true
_ControlChartTrack,
@Consumption.filter.hidden: true
_QltyCtrlChtTrack1,
@Consumption.filter.hidden: true
_QltyCtrlChtCharcs,
//*** Visual Filters Associations ***//
@Consumption.filter.hidden: true
_QltyCtrlExcdLmtVislFltr,
@Consumption.filter.hidden: true
_QltyCtrlChartWrkCtrVislFltr,
@Consumption.filter.hidden: true
_QltyCtrlDvtnMatlVislFltr,
@Consumption.filter.hidden: true
_QltyCtrlNonActvVislFltr,
//*** Exposed Associations ***//
@Consumption.filter.hidden: true
_QualityControlChart._QualityControlChartStatus,
@Consumption.filter.hidden: true
_QualityControlChart._WorkCenter,
@Consumption.filter.hidden: true
_QualityControlChart._QltyCtrlChartAggrgnCriterion,
@Consumption.filter.hidden: true
_QualityControlChartType,
@Consumption.filter.hidden: true
_Plant,
@Consumption.filter.hidden: true
_QualityControlChart._Material,
@Consumption.filter.hidden: true
_QualityControlChart._MainWorkCenterPlant,
@Consumption.filter.hidden: true
_QualityControlChart._InspectionLot._Customer,
@Consumption.filter.hidden: true
_QualityControlChart._InspectionLot._InspectionLotType,
@Consumption.filter.hidden: true
_QualityControlChart._InspectionLot._InspectionLotOrigin,
@Consumption.filter.hidden: true
_QualityControlChart._InspectionLot._Manufacturer,
//*** DCL/DPP related ***//
@UI.hidden: true
_QualityControlChart._Supplier.IsBusinessPurposeCompleted,
@UI.hidden: true
_QualityControlChart._Supplier.AuthorizationGroup
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_QLTYCTRLCHTCALC",
"C_QUALITYCONTROLCHARTTRACK",
"I_BILLOFOPERATIONSTYPE",
"I_BILLOFOPERATIONSTYPETEXT",
"I_INSPECTIONLOT",
"I_INSPECTIONLOTTYPE",
"I_INSPECTIONLOTTYPETEXT",
"I_MATERIAL",
"I_MATERIALTEXT",
"I_PLANT",
"I_QLTYCTRLCHARTAGGRGNCRITERION",
"I_QLTYCTRLCHARTAGGRGNCRITTEXT",
"I_QLTYCTRLCHTDVTNSTS",
"I_QLTYCTRLCHTDVTNSTSTXT",
"I_QUALITYCONTROLCHARTSTATUS",
"I_QUALITYCONTROLCHARTSTATUSTXT",
"I_QUALITYCONTROLCHARTTYPE",
"I_QUALITYCONTROLCHARTTYPETEXT",
"I_QUALITYCTRLCHARTTP",
"I_SUPPLIER",
"I_WORKCENTERBYSEMANTICKEY",
"I_WORKCENTERTEXTBYSEMANTICKEY",
"P_INSPCHARCSMPLSIZEAGGRGN",
"P_QUALITYCONTROLCHARTRESULTS"
],
"ASSOCIATED":
[
"C_QLTYCTRLCHARTWRKCTRVISLFLTR",
"C_QLTYCTRLCHTCALC",
"C_QLTYCTRLCHTCHARCS",
"C_QLTYCTRLDVTNMATLVISLFLTR",
"C_QLTYCTRLEXCDLMTVISLFLTR",
"C_QLTYCTRLNONACTVVISLFLTR",
"C_QUALITYCONTROLCHARTTRACK",
"I_CUSTOMER",
"I_INSPECTIONLOTORIGIN",
"I_INSPECTIONLOTTYPE",
"I_MATERIAL",
"I_PLANT",
"I_QLTYCTRLCHARTAGGRGNCRITERION",
"I_QUALITYCONTROLCHARTSTATUS",
"I_QUALITYCONTROLCHARTTYPE",
"I_SUPPLIER",
"I_USERCONTACTCARD",
"I_WORKCENTERBYSEMANTICKEY",
"P_INSPCHARCSMPLSIZEAGGRGN",
"P_QUALITYCONTROLCHARTRESULTS"
],
"BASE":
[
"I_INSPECTIONLOT",
"I_QUALITYCTRLCHARTTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/