P_QualityControlChartResults

@AbapCatalog.sqlViewName: 'PQLTYCTRLRESULTS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Inspection Results'
@VDM: {
    private: true,
    viewType: #CONSUMPTION 
} 

define view P_QualityControlChartResults
  as select from I_InspSubsetCharacteristic

 association [0..1] to I_InspSubsetResult as _SubsetResult on  $projection.InspectionLot               = _SubsetResult.InspectionLot
                                                                and $projection.InspPlanOperationInternalID = _SubsetResult.InspPlanOperationInternalID
                                                                and $projection.InspectionCharacteristic    = _SubsetResult.InspectionCharacteristic
                                                             and $projection.InspectionSubsetInternalID = _SubsetResult.InspectionSubsetInternalID
  association [0..1] to I_InspectionResult as _InspectionResult on  $projection.InspectionLot               = _InspectionResult.InspectionLot
                                                                and $projection.InspPlanOperationInternalID = _InspectionResult.InspPlanOperationInternalID
                                                                and $projection.InspectionCharacteristic    = _InspectionResult.InspectionCharacteristic
                                                          
  association [1..1] to I_Supplier         as _Supplier         on  $projection.supplier = _Supplier.Supplier
{
  key I_InspSubsetCharacteristic.InspectionLot,
  key I_InspSubsetCharacteristic.InspPlanOperationInternalID,
  key I_InspSubsetCharacteristic.InspectionCharacteristic,
  key I_InspSubsetCharacteristic.InspectionSubsetInternalID,
      QualityControlChart,
      _InspectionResult.InspectionValuationResult,//non samplebased

      _SubsetResult.InspectionValuationResult  as InspSubsetResultValuation,
      _InspectionResult.InspectionEndDate,
      _InspectionResult.InspectionEndTime,
      // I_InspectionLot fields [1..1]

      I_InspSubsetCharacteristic._InspectionLot.Plant,
      I_InspSubsetCharacteristic._InspectionLot.Material,
      I_InspSubsetCharacteristic._InspectionLot.InspectionLotOrigin,
      I_InspSubsetCharacteristic._InspectionLot.InspectionLotType,
      I_InspSubsetCharacteristic._InspectionLot.BillOfOperationsType,
      I_InspSubsetCharacteristic._InspectionLot.BillOfOperationsGroup,
      I_InspSubsetCharacteristic._InspectionLot.BillOfOperationsVariant,
      I_InspSubsetCharacteristic._InspectionLot.Supplier,
      I_InspSubsetCharacteristic._InspectionLot.Customer,
      I_InspSubsetCharacteristic._InspectionLot.Manufacturer,
      I_InspSubsetCharacteristic._InspectionLot.InspLotHasSubsets,

      // I_InspectionCharacteristic fields [1..1]

      I_InspSubsetCharacteristic._InspectionCharacteristic.InspectionSpecificationText,

      // I_InspectionOperation fields [1..1]

      I_InspSubsetCharacteristic._InspectionOperation._WorkCenter.WorkCenter,
      I_InspSubsetCharacteristic._InspectionOperation._WorkCenter._Text[1:Language=$session.system_language].WorkCenterText,

      // Associations

      I_InspSubsetCharacteristic._InspectionLot,
      _Supplier
}
where
  (
        _InspectionLot.InspLotHasSubsets = 'X'
    and InspectionSubsetInternalID != '000000'
  )
  or(
        _InspectionLot.InspLotHasSubsets = ''
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSPECTIONCHARACTERISTIC",
"I_INSPECTIONLOT",
"I_INSPECTIONOPERATION",
"I_INSPECTIONRESULT",
"I_INSPSUBSETCHARACTERISTIC",
"I_INSPSUBSETRESULT",
"I_WORKCENTER",
"I_WORKCENTERTEXT"
],
"ASSOCIATED":
[
"I_INSPECTIONLOT",
"I_INSPECTIONRESULT",
"I_INSPSUBSETRESULT",
"I_SUPPLIER"
],
"BASE":
[
"I_INSPSUBSETCHARACTERISTIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/