C_PurchaseOrderItemSolution

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'CPURCHORDTEMSOL'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Purchase Order Item Solution'

@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.representativeKey: 'PurchaseOrderItem'

@VDM.viewType: #CONSUMPTION

define view C_PurchaseOrderItemSolution
  as select from I_PurchaseOrderItem as PurchaseOrderItem

  association [1..1] to C_PurchaseOrderSolution    as _PurchaseOrder             on  _PurchaseOrder.PurchaseOrder = $projection.PurchaseOrder

  association [0..*] to C_PurOrdAcctAsgmntSolution as _PurOrdAcctAssignment      on  _PurOrdAcctAssignment.PurchaseOrder     = $projection.PurchaseOrder
                                                                                 and _PurOrdAcctAssignment.PurchaseOrderItem = $projection.PurchaseOrderItem

  association [0..*] to C_PurOrdSchedLineSolution  as _PurchaseOrderScheduleLine on  _PurchaseOrderScheduleLine.PurchaseOrder     = $projection.PurchaseOrder
                                                                                 and _PurchaseOrderScheduleLine.PurchaseOrderItem = $projection.PurchaseOrderItem
{
      @ObjectModel.foreignKey.association: '_PurchaseOrder'
  key PurchaseOrder,
  key PurchaseOrderItem,
      AccountAssignmentCategory,
      @ObjectModel.foreignKey.association: '_PurchaseContract'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PurchaseContractStdVH', element: 'PurchaseContract' } } ]
      PurchaseContract,
      @ObjectModel.foreignKey.association: '_PurchaseContractItem'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PurchaseContractItemStdVH', element: 'PurchaseContractItem' } } ]
      PurchaseContractItem,
      cast( 0 as pph_webaz ) as MaterialGoodsReceiptDuration,
      @ObjectModel.foreignKey.association: '_PurchasingInfoRecord'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PurchasingInfoRecordStdVH', element: 'PurchasingInfoRecord' } } ]
      PurchasingInfoRecord,
      @ObjectModel.foreignKey.association: '_PurgDocumentItemCategory'
      PurchaseOrderItemCategory,
      @ObjectModel.foreignKey.association: '_Material'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      Material,
      cast( '' as werks_d ) as ReceivingPlant,
      @Semantics.unitOfMeasure:true
      @ObjectModel.foreignKey.association: '_OrderQuantityUnit'
      PurchaseOrderQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      @DefaultAggregation: #NONE
      OrderQuantity,
      @ObjectModel.foreignKey.association: '_PurchaseRequisition'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PurchaserequisitionStdVH', element: 'PurchaseRequisition' } } ]
      PurchaseRequisition,
      cast( '' as lgort_d ) as SupplyingStorageLocation,
      cast( '' as lgort_d ) as ReceivingStorageLocation,

      @Semantics.currencyCode: true
      DocumentCurrency,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _PurchaseOrderPricingElement,
      _PurchaseOrder,
      _PurchaseOrderItemCalcFields,

      _PurOrdAcctAssignment,
      _PurchaseOrderScheduleLine,

      _Material,
      _PurgDocumentItemCategory,
      _PurchasingInfoRecord,
      _PurchaseRequisition,
      _PurchaseContract,
      _PurchaseContractItem,
      _OrderQuantityUnit
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCHASEORDERITEM"
],
"ASSOCIATED":
[
"C_PURCHASEORDERSOLUTION",
"C_PURORDACCTASGMNTSOLUTION",
"C_PURORDSCHEDLINESOLUTION",
"I_MATERIAL",
"I_PURCHASECONTRACT",
"I_PURCHASECONTRACTITEM",
"I_PURCHASEORDERITEMCALCFIELDS",
"I_PURCHASEREQUISITION",
"I_PURCHASINGINFORECORDAPI01",
"I_PURGDOCUMENTITEMCATEGORY",
"I_PURORDPRICINGELEMENT",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_PURCHASEORDERITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/