C_PurOrdSchedLineSolution

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'CPOSCHEDLINESOL'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Purchase Order Schedule Line Solution'

@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.representativeKey: 'ScheduleLine'

@VDM.viewType: #CONSUMPTION

define view C_PurOrdSchedLineSolution
  as select from I_PurchaseOrderScheduleLine
  association [1..1] to C_PurchaseOrderSolution     as _PurchaseOrder     on  $projection.PurchaseOrder = _PurchaseOrder.PurchaseOrder
  association [1..1] to C_PurchaseOrderItemSolution as _PurchaseOrderItem on  $projection.PurchaseOrder     = _PurchaseOrderItem.PurchaseOrder
                                                                          and $projection.PurchaseOrderItem = _PurchaseOrderItem.PurchaseOrderItem
  association [0..1] to I_UnitOfMeasure           as _PurchaseOrderQuantityUnit on  $projection.PurchaseOrderQuantityUnit = _PurchaseOrderQuantityUnit.UnitOfMeasure
{
      @ObjectModel.foreignKey.association: '_PurchaseOrder'
  key PurchaseOrder,
      @ObjectModel.foreignKey.association: '_PurchaseOrderItem'
  key PurchaseOrderItem,
  key ScheduleLine,
      ScheduleLineDeliveryDate,
      cast( 00000000 as date ) as AvailabilityDate,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_PurchaseOrderQuantityUnit'
      _PurchaseOrderItem.PurchaseOrderQuantityUnit       as PurchaseOrderQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      @DefaultAggregation: #SUM
      (ScheduleLineOrderQuantity - RoughGoodsReceiptQty) as OpenPurchaseOrderQuantity,


      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      @DefaultAggregation: #SUM
      ScheduleLineOrderQuantity,

      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      @DefaultAggregation: #SUM
      RoughGoodsReceiptQty,

      _PurchaseOrder,
      _PurchaseOrderItem,
      _PurchaseOrderQuantityUnit
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_PURCHASEORDERITEMSOLUTION",
"I_PURCHASEORDERSCHEDULELINE"
],
"ASSOCIATED":
[
"C_PURCHASEORDERITEMSOLUTION",
"C_PURCHASEORDERSOLUTION",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/