C_PurOrdRefDocIR

@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CPURORDREFDOCIR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Reference Documents for PO Creation - Inforecord Items'
@Search.searchable: true
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MIXED

@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

define view C_PurOrdRefDocIR
  as select from    I_PurgInfoRecdOrgPlantData as eine
    left outer join I_PurchasingInfoRecord     as eina     on eine.PurchasingInfoRecord = eina.PurchasingInfoRecord
    left outer join I_Material                 as material on eina.Material = material.Material

  association [0..1] to I_Supplier                     as _Supplier                   on  $projection.Supplier = _Supplier.Supplier
  association [0..1] to I_Plant                        as _Plant                      on  $projection.Plant = _Plant.Plant
  association [0..1] to I_PurchasingGroup              as _PurgGrp                    on  $projection.PurchasingGroup = _PurgGrp.PurchasingGroup
  association [0..1] to I_MM_ControllingAreaVH         as _ControllingArea            on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_CostCenterText               as _CostCenterText             on  $projection.ControllingArea = _CostCenterText.ControllingArea
                                                                                      and $projection.CostCenter      = _CostCenterText.CostCenter
                                                                                      and $projection.ValidityEndDate = _CostCenterText.ValidityEndDate
                                                                                      and _CostCenterText.Language    = $session.system_language
  association [0..1] to I_MaterialText                 as _MaterialText               on  $projection.ManufacturerMaterial = _MaterialText.Material
                                                                                      and _MaterialText.Language           = $session.system_language
  association [0..1] to I_MaterialGroupText            as _MaterialGroupText          on  $projection.MaterialGroup   = _MaterialGroupText.MaterialGroup
                                                                                      and _MaterialGroupText.Language = $session.system_language
  association [0..1] to I_UnitOfMeasureText            as _UnitOfMeasureText          on  $projection.PurchaseOrderPriceUnit = _UnitOfMeasureText.UnitOfMeasure
                                                                                      and _UnitOfMeasureText.Language        = $session.system_language
  association [0..1] to I_BusinessPartner              as _BusinessPartner            on  $projection.ServicePerformer = _BusinessPartner.BusinessPartner
  association [0..1] to I_GlAccountTextInCompanycode   as _GlAccountTextInCompanycode on  $projection.GLAccount                = _GlAccountTextInCompanycode.GLAccount
                                                                                      and $projection.CompanyCode              = _GlAccountTextInCompanycode.CompanyCode
                                                                                      and _GlAccountTextInCompanycode.Language = $session.system_language

  -------------------------------------------------------------------------------------------
  -- Value-Help Associations                                                               --
  -------------------------------------------------------------------------------------------

  association [0..1] to C_PurchasingGroupValueHelp     as _PurchasingGroupVH          on  _PurchasingGroupVH.PurchasingGroup = $projection.PurchasingGroup

  association [0..*] to C_MM_SupplierValueHelp         as _SupplierValueHelp          on  _SupplierValueHelp.Supplier = $projection.Supplier

  association [0..*] to C_MM_MaterialValueHelp         as _MaterialValueHelp          on  _MaterialValueHelp.Material = $projection.ManufacturerMaterial

  association [0..*] to C_MM_ServicePerformerValueHelp as _ServicePerformerValueHelp  on  _ServicePerformerValueHelp.ServicePerformer = $projection.ServicePerformer

  association [0..1] to C_MM_MaterialGroupValueHelp    as _MaterialGroupVH            on  _MaterialGroupVH.MaterialGroup = $projection.MaterialGroup

  association [0..*] to C_MM_PlantValueHelp            as _PlantValueHelp             on  _PlantValueHelp.Plant = $projection.Plant

  association [0..1] to I_MM_SalesOrderValueHelp       as _SalesOrder                 on  _SalesOrder.SalesOrder = $projection.SalesOrder

  association [0..1] to I_MM_CostCenterValueHelp       as _CostCenter                 on  _CostCenter.CostCenter      = $projection.CostCenter
                                                                                      and _CostCenter.ControllingArea = $projection.ControllingArea
                                                                                      and _CostCenter.ValidityEndDate = $projection.ValidityEndDate

  association [0..1] to I_MM_WBSElementValueHelp       as _WBSElementVH               on  _WBSElementVH.WBSElementInternalID = $projection.WBSElementInternalID
                                                                                      and _WBSElementVH.WBSElementExternalID = $projection.WBSElement


{
       @UI.hidden: true
  key  eine.PurchasingInfoRecord                as PurchasingInfoRecord,
  key  eine.PurchasingOrganization              as PurchasingOrganization,
       @EndUserText.label: 'Purchasing Info Record Category'
  key  eine.PurchasingInfoRecordCategory        as PurchasingInfoRecordCategory,
       //@UI.selectionField: {position: 40 }

       @Consumption: { valueHelp: '_PlantValueHelp' }
       @ObjectModel.foreignKey.association: '_PlantValueHelp'
  key  eine.Plant                               as Plant,
       @UI.hidden: true
       cast('' as abap.char(10))                as PurchaseRequisition,
       @UI.hidden: true
       cast('' as abap.numc(5))                 as PurchaseRequisitionItem,
       @UI.hidden: true
       ''                                       as PurchaseOrder,
       @UI.hidden: true
       cast('' as abap.numc(5))                 as PurchaseOrderItem,
       ''                                       as AccountAssignmentNumber,
       @EndUserText.label: 'Fixed Vendor'
       cast('' as abap.char(10))                 as FixedSupplier,
       @EndUserText.label: 'Desired Vendor'
       cast('' as abap.char(10))                 as FixedSupplierName,
       @UI.hidden: true
       _Plant.PlantName                         as PlantName,
       @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
       eine.PurchasingInfoRecord                as PurchasingDocument,
       @UI.hidden: true
       'I'                                      as PurchasingDocumentCategory,
       @ObjectModel: {
        readOnly: true
       }
       ''                                       as IsAdvancedPurchaseOrder,
       @UI.hidden: true
       ''                                       as PurchasingDocumentDeletionCode,
       ''                                       as StorageLocation, //will be taken from I_MaterialPlant (=MARC-LGFSB) once available

       @UI.selectionField: { position: 20 }
       @Consumption: { valueHelp: '_MaterialValueHelp' }
       @ObjectModel.foreignKey.association: '_MaterialValueHelp'
       @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
       eina.Material                            as ManufacturerMaterial,
       @UI.hidden: true
       eina.Material                            as Material,
       @UI.hidden: true
       _MaterialText.MaterialName               as MaterialName,
       material._MaterialType.MaterialType      as MaterialType,
       @EndUserText.label: 'Purchase Requisition Item Text'
       cast('' as abap.char(40))                 as PurchaseRequisitionItemText,
       //@UI.selectionField: { position: 30 }

       @Consumption: { valueHelp: '_MaterialGroupVH' }
       @ObjectModel.foreignKey.association: '_MaterialGroupVH'
       case eina.MaterialGroup
         when '' then
             eina._Material.MaterialGroup
         else
             eina.MaterialGroup
       end                                      as MaterialGroup,
       @UI.hidden: true
       case eina.MaterialGroup
         when '' then
             eina._Material._MaterialGroup._Text[1: Language = $session.system_language].MaterialGroupName
         else
             eina._MaterialGroup._Text[1: Language = $session.system_language].MaterialGroupName
       end                                      as MaterialGroupName,
       @UI.selectionField: { position: 10 }
       @Consumption: { valueHelp: '_SupplierValueHelp',filter.mandatory: true }
       @ObjectModel.foreignKey.association: '_SupplierValueHelp'
       eina.Supplier                            as Supplier,
       @UI.hidden: true
       _Supplier.SupplierName                   as SupplierName,
       cast('' as abap.char(4))                 as PurchasingDocumentType,
       @UI.hidden: true
       cast('' as abap.char(4))                 as PurchasingDocumentSubtype,
       eina.PurchasingInfoRecordDesc            as PurchasingDocumentItemText,
       @Semantics: { quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit' }
       eine.StandardPurchaseOrderQuantity       as PurchaseOrderQty,
       @Semantics: { unitOfMeasure: true }
       @UI.hidden: true
       eina.PurgDocOrderQuantityUnit            as PurchaseOrderQuantityUnit,
       @Semantics: { amount.currencyCode: 'Currency' }
       eine.NetPriceAmount                      as PurchaseOrderNetPriceAmount,
       @Semantics: { currencyCode: true }
       @UI.hidden: true
       eine.Currency                            as Currency,
       @Semantics: { quantity.unitOfMeasure: 'PurchaseOrderPriceUnit' }
       eine.MaterialPriceUnitQty                as PurchaseOrderNetPriceQuantity,
       @Semantics: { unitOfMeasure: true }
       @UI.hidden: true
       eine.PurchaseOrderPriceUnit              as PurchaseOrderPriceUnit,
       @UI.hidden: true
       _UnitOfMeasureText.UnitOfMeasureLongName as PurchaseOrderPriceUnitName,
       //@UI.selectionField: { position: 60 }

       @Consumption: { valueHelp: '_PurchasingGroupVH' }
       @ObjectModel.foreignKey.association: '_PurchasingGroupVH'
       eine.PurchasingGroup                     as PurchasingGroup,
       @UI.hidden: true
       _PurgGrp.PurchasingGroupName             as PurchasingGroupName,
       cast('' as abap.char(4))                 as CompanyCode,
       @UI.hidden: true
       cast('' as abap.char(25))                as CompanyCodeName,
       @UI.hidden: true
       cast('' as abap.char(10))                as PurchasingDocumentCondition,
       @UI.hidden: true
       ''                                       as PricingProcedure,
       @Semantics.businessDate.from: true
       @UI.hidden: true
       cast('00000000' as vdm_validitystart)    as ValidityStartDate,
       @Semantics.businessDate.to: true
       @UI.hidden: true
       eine.PriceValidityEndDate                as ValidityEndDate,
       @UI.hidden: true
       0                                        as ContractConsumptionInPct,
       @UI.hidden: true
       cast('' as abap.char(1))                 as GoodsReceiptIsExpected,
       @UI.hidden: true
       cast('' as abap.char(1))                 as GoodsReceiptIsNonValuated,
       @UI.hidden: true
       cast('' as abap.char(1))                 as InvoiceIsExpected,
       @UI.hidden: true
       eine.InvoiceIsGoodsReceiptBased          as InvoiceIsGoodsReceiptBased,
       @UI.hidden: true
       eine.OverdelivTolrtdLmtRatioInPct        as OverdelivTolrtdLmtRatioInPct,
       @UI.hidden: true
       eine.UnlimitedOverdeliveryIsAllowed      as UnlimitedOverdeliveryIsAllowed,
       @UI.hidden: true
       eine.UnderdelivTolrtdLmtRatioInPct       as UnderdelivTolrtdLmtRatioInPct,
       @UI.hidden: true
       eina.OrderItemQtyToBaseQtyNmrtr          as OrderItemQtyToBaseQtyNmrtr,
       @UI.hidden: true
       eina.OrderItemQtyToBaseQtyDnmntr         as OrderItemQtyToBaseQtyDnmntr,
       @UI.hidden: true
       ''                                       as PurchaseOrderItemCategory,
       @UI.hidden: true
       eine.IsMarkedForDeletion                 as IsDeleted,
       //@UI.selectionField: { position: 50 }

       @Consumption: { valueHelp: '_ServicePerformerValueHelp' }
       @ObjectModel.foreignKey.association: '_ServicePerformerValueHelp'
       ''                                       as ServicePerformer,
       @UI.hidden: true
       ''                                       as ServicePerformerName,
       ''                                       as ProductType,
       @UI.hidden: true
       cast('' as abap.char(10))                as RefPurchaseOutlineAgreement,
       @UI.hidden: true
       cast('00000' as abap.numc(5))            as RefPurchOutlineAgrmtItem,
       @UI.hidden: true
       eina.SupplierMaterialNumber              as SupplierMaterialNumber,
       @UI.hidden: true
       cast('00000000' as abap.dats)            as DeliveryDate,
       @UI.hidden: true
       cast('00000000' as abap.dats)            as PerformancePeriodStartDate,
       @UI.hidden: true
       cast('00000000' as abap.dats)            as PerformancePeriodEndDate,
       @UI.hidden: true
       eine.OrderPriceUnitToOrderUnitNmrtr      as OrderPriceUnitToOrderUnitNmrtr,
       @UI.hidden: true
       eine.OrdPriceUnitToOrderUnitDnmntr       as OrdPriceUnitToOrderUnitDnmntr,
       ''                                       as CustomerProjectName,
       cast('' as abap.char(10))                as ProfitCenter,
       @UI.hidden: true
       cast('' as abap.numc(8))                 as WBSElementInternalID,
       //@UI.selectionField: { position: 90 }

       @Consumption: { valueHelp: '_WBSElementVH' }
       @ObjectModel.foreignKey.association: '_WBSElementVH'
       @EndUserText.label: 'WBS Element'
       cast('' as abap.numc(10))                as WBSElement,
       cast('' as abap.char(16))                as FunctionalArea,
       cast('' as abap.char(10))                as GLAccount,
       @UI.hidden: true
       ''                                       as GLAccountName,
       //@UI.selectionField: { position: 80 }

       @ObjectModel.foreignKey.association: '_CostCenter'
       cast('' as abap.char(10))                as CostCenter,
       @UI.hidden: true
       ''                                       as CostCenterName,
       @Consumption.valueHelp: '_ControllingArea'
       @ObjectModel.foreignKey.association: '_ControllingArea'
       cast('' as abap.char(4))                 as ControllingArea,
       //@UI.selectionField: { position: 70 }

       @ObjectModel.foreignKey.association: '_SalesOrder'
       cast('' as abap.char(10))                as SalesOrder,
       cast('' as abap.numc(6))                 as SalesOrderItem,
        @Consumption.filter.hidden: true
        @EndUserText.label:'Purchase Requisition Description'
        cast('' as abap.char(4))                                             as PurReqnDescription,
       _ControllingArea,

       @Consumption.hidden: true
       _BusinessPartner,
       //_Supplier,


       _PurchasingGroupVH,
       _SupplierValueHelp,
       _MaterialValueHelp,
       _ServicePerformerValueHelp,
       _MaterialGroupVH,
       _PlantValueHelp,
       _WBSElementVH,
       _CostCenter,
       _SalesOrder
}
where
      PurchasingInfoRecordCategory = '0' //only IRs with cat. "Standard" allowed as reference (due to pricing issues with other categories)

  and eine.IsMarkedForDeletion     = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIAL",
"I_MATERIALGROUP",
"I_MATERIALGROUPTEXT",
"I_MATERIALTEXT",
"I_MATERIALTYPE",
"I_PLANT",
"I_PURCHASINGGROUP",
"I_PURCHASINGINFORECORD",
"I_PURGINFORECDORGPLANTDATA",
"I_SUPPLIER",
"I_UNITOFMEASURETEXT"
],
"ASSOCIATED":
[
"C_MM_MATERIALGROUPVALUEHELP",
"C_MM_MATERIALVALUEHELP",
"C_MM_PLANTVALUEHELP",
"C_MM_SERVICEPERFORMERVALUEHELP",
"C_MM_SUPPLIERVALUEHELP",
"C_PURCHASINGGROUPVALUEHELP",
"I_BUSINESSPARTNER",
"I_COSTCENTERTEXT",
"I_GLACCOUNTTEXTINCOMPANYCODE",
"I_MATERIALGROUPTEXT",
"I_MATERIALTEXT",
"I_MM_CONTROLLINGAREAVH",
"I_MM_COSTCENTERVALUEHELP",
"I_MM_SALESORDERVALUEHELP",
"I_MM_WBSELEMENTVALUEHELP",
"I_PLANT",
"I_PURCHASINGGROUP",
"I_SUPPLIER",
"I_UNITOFMEASURETEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/