C_PurOrdPricingElementTP

@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CPOPRICINGTP'
@EndUserText.label: 'Purchase Order Pricing with Draft'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK

@ObjectModel: {
   transactionalProcessingDelegated: true,
   semanticKey: ['PricingDocument', 'PurchaseOrder', 'PurchaseOrderItem', 'PricingDocument', 'PricingDocumentItem', 'PricingProcedureStep', 'PricingProcedureCounter'],
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true
}

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

define view C_PurOrdPricingElementTP
  as select from I_PurOrdPricingElementTP as Document
  association [1..1] to C_PurchaseOrderTP           as _PurchaseOrderTP          on  _PurchaseOrderTP.PurchaseOrder = $projection.PurchaseOrder
  association [1..1] to C_PurchaseOrderItemTP       as _PurchaseOrderItemTP      on  _PurchaseOrderItemTP.PurchaseOrder     = $projection.PurchaseOrder
                                                                                 and _PurchaseOrderItemTP.PurchaseOrderItem = $projection.PurchaseOrderItem
  association [1..1] to C_PricingElement            as _PricingElement           on  _PricingElement.PricingDocument         = $projection.PricingDocument
                                                                                 and _PricingElement.PricingDocumentItem     = $projection.PricingDocumentItem
                                                                                 and _PricingElement.PricingProcedureStep    = $projection.PricingProcedureStep
                                                                                 and _PricingElement.PricingProcedureCounter = $projection.PricingProcedureCounter
                                                                                 and _PricingElement.ConditionApplication    = 'M'  // 3377047

  association [0..*] to C_PricingConditionType_VH   as _PricingConditionTypeVH   on  $projection.ConditionType = _PricingConditionTypeVH.ConditionType
  //  association [0..1] to C_PricingConditionTypeName_VH  as _PricingConditionTypeName_VH  on  $projection.ConditionType = _PricingConditionTypeName_VH.ConditionType

  //                                                                               and $projection.ConditionApplication  = _PricingConditionTypeName_VH.ConditionApplication

  //                                                                               and $projection.ConditionTypeName     = _PricingConditionTypeName_VH.ConditionTypeName

  association [0..1] to C_ConditionRateValueUnit_VH as _ConditionRateValueUnitVH on  $projection.ConditionRateValueUnit = _ConditionRateValueUnitVH.ConditionRateValueUnit
  association [0..1] to C_ConditionQuantityUnit_VH  as _ConditionQuantityUnitVH  on  $projection.ConditionQuantityUnit = _ConditionQuantityUnitVH.ConditionQuantityUnit

{
      @ObjectModel.foreignKey.association: '_PurchaseOrderTP'
  key Document.PurchaseOrder,
      @ObjectModel.foreignKey.association: '_PurchaseOrderItemTP'
  key Document.PurchaseOrderItem,
  key Document.PricingDocument,
  key Document.PricingDocumentItem,
  key Document.PricingProcedureStep,
  key Document.PricingProcedureCounter,

      @ObjectModel.readOnly: true
      Document.ConditionApplication,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @UI: { identification.position: 20, lineItem : { position:20, importance:#HIGH } }
      @Consumption: { valueHelp: '_PricingConditionTypeVH' }
      Document.ConditionType,
      @ObjectModel.readOnly: true
      _PricingElement.ConditionTypeName,
      @ObjectModel.readOnly: true
      @Semantics.dateTime:false
      _PricingElement.PricingDateTime,
      Document.ConditionCalculationType,
      @ObjectModel.readOnly: true
      _PricingElement.ConditionBaseValue,
      @ObjectModel.readOnly: true
      _PricingElement.ConditionBaseValueIntlUnit,
      @ObjectModel.readOnly: true
      _PricingElement.ConditionBaseValueUnit,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @UI: { identification.position: 40, lineItem : { position:40, importance:#HIGH } }
      @Semantics.amount.currencyCode: 'ConditionRateValueIntlUnit'
      Document.ConditionRateValue,
//      cast( Document.ConditionRateValue      as          vfprc_rate_value_in_curr  )                       as ConditionRateValue,


      @ObjectModel.readOnly: true
      _PricingElement.ConditionRateValueIntlUnit,
      @Consumption: { valueHelp: '_ConditionRateValueUnitVH' }
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @Semantics.currencyCode: true
      Document.ConditionRateValueUnit,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @UI: { identification.position: 60, lineItem : { position:60, importance:#HIGH } }
      Document.ConditionQuantity,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @UI: { identification.position: 70, lineItem : { position:70, importance:#HIGH } }
      @Consumption: { valueHelp: '_ConditionQuantityUnitVH' }
      Document.ConditionQuantityUnit,
      @ObjectModel.readOnly: true
      _PricingElement.ConditionIsForStatistics,
      @ObjectModel.readOnly: true
      _PricingElement.IsGroupCondition,
      @ObjectModel.readOnly: true
      _PricingElement.TaxCode,
      @ObjectModel.readOnly: true
      _PricingElement.TaxCodeName,
      @UI: { identification.position: 100, lineItem : { position:100, importance:#HIGH } }
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      Document.ConditionAmount,
      @ObjectModel.readOnly: true
      _PricingElement.TransactionCurrency,
      @ObjectModel.readOnly: true
      _PricingElement.ConditionInactiveReason,
      @ObjectModel.readOnly: true
      _PricingElement.ConditionInactiveReasonName,
      @ObjectModel.readOnly: true
      _PricingElement.ConditionIsManuallyChanged,
      @ObjectModel.readOnly: true
      _PricingElement.ConditionIsDeletable,
      @ObjectModel.readOnly: true
      _PricingElement.PricingProcedure,
      @ObjectModel.readOnly: true
      _PricingElement.SuperordinateDocument,
      @ObjectModel.readOnly: true
      _PricingElement.SuperordinateDocumentItem,

      @ObjectModel.association.type: #TO_COMPOSITION_ROOT
      _PurchaseOrderTP,
      @ObjectModel.association.type: #TO_COMPOSITION_PARENT
      _PurchaseOrderItemTP,

      _ConditionApplication,

      _ConditionQuantityUnit,

      _PricingConditionTypeVH,
      _ConditionRateValueUnitVH,
      _ConditionQuantityUnitVH

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_PRICINGELEMENT",
"I_PURORDPRICINGELEMENTTP"
],
"ASSOCIATED":
[
"C_CONDITIONQUANTITYUNIT_VH",
"C_CONDITIONRATEVALUEUNIT_VH",
"C_PRICINGCONDITIONTYPE_VH",
"C_PRICINGELEMENT",
"C_PURCHASEORDERITEMTP",
"C_PURCHASEORDERTP",
"I_CONDITIONAPPLICATION",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_PURORDPRICINGELEMENTTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/