C_ConditionQuantityUnit_VH

@AbapCatalog.sqlViewName: 'CCONDQUANUNITVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.representativeKey: 'ConditionQuantityUnit'
@ObjectModel.dataCategory: #VALUE_HELP
@Search.searchable:true
@Consumption.ranked:true
@EndUserText.label: 'Condition Quantity Unit Value Help'
define view C_ConditionQuantityUnit_VH
  as select from I_UnitOfMeasure as UnitOfMeasure
{

    @ObjectModel.text.element:  [ 'UnitOfMeasureLongName' ]
    @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
    @UI.lineItem.position: 10
    @UI.selectionField.position: 10
    key UnitOfMeasure.UnitOfMeasure                                                 as ConditionQuantityUnit,
    @Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8 }
    @UI.lineItem.position: 20
    @UI.selectionField.position: 20
    cast( UnitOfMeasure._Text[ 1: Language = $session.system_language ].UnitOfMeasure_E as fis_mseh3 preserving type ) as UnitOfMeasure_E,
    @Semantics.text: true
    @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7 }
    @UI.lineItem.position: 30
    @UI.selectionField.position: 30
    UnitOfMeasure._Text[ 1: Language = $session.system_language ].UnitOfMeasureLongName  as UnitOfMeasureLongName
}

where  UnitOfMeasure._Text[ 1: Language = $session.system_language ].UnitOfMeasure_E <> '';       
               
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_UNITOFMEASURE",
"I_UNITOFMEASURETEXT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/