C_PlmrCompositionVH

--Label of view
@EndUserText.label: 'Polymer Composition'

@AbapCatalog:
{
  -- SQL view name (16 characters)
  sqlViewName: 'CPLMRCOMPSTVH',

  --If it's true, the filter conditions are compared and, if they match, the associated join expression is evaluated only once
  compiler.compareFilter: true,
  preserveKey: true
}
--Access Control: Authorizations Checks
@AccessControl:
{
  // no authorization check required because view only reads customizing for which a check is not needed

  authorizationCheck: #NOT_REQUIRED
}

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

--VDM view type
@VDM.viewType: #CONSUMPTION

@ObjectModel:
{
  dataCategory: #VALUE_HELP,
  --Value help as DropDown
  resultSet.sizeCategory: #XS,
  representativeKey: 'PolymerCompositionIntIDRef',
  --Performance Annotations
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #C
  }

}
@Metadata.ignorePropagatedAnnotations: true

define view C_PlmrCompositionVH
  as select from I_Substance       as Substance

    inner join   I_ChmlComposition as _PlmrComposition on  Substance.SubstanceUUID                = _PlmrComposition.SubstanceUUID
                                                       and _PlmrComposition.ChmlCompositionStatus = 'RE'
{
      --SubstanceUUID
      @UI.hidden: true
  key Substance.SubstanceUUID                  as SubstanceUUID,

      --PolymerCompositionIntIDRef
      @ObjectModel.text.element:  [ 'PolymerCompositionName' ]
  key _PlmrComposition.PolymerCompositionIntID as PolymerCompositionIntIDRef,

      --PolymerCompositionName
      @Semantics.text: true
      _PlmrComposition.PolymerCompositionName  as PolymerCompositionName,

      --ResponsibleUnit
      Substance.ResponsibleUnit                as ResponsibleUnit
}

union all select from I_Substance as Substance

/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] } */
association [0..1] to I_PlmrCompositionNotRqdText as _PlmrCompositionNotRqdText on _PlmrCompositionNotRqdText.Language = $session.system_language
{
      --SubstanceUUID
      @UI.hidden: true
  key Substance.SubstanceUUID                       as SubstanceUUID,

      --PolymerCompositionIntIDRef
      @ObjectModel.text.element:  [ 'PolymerCompositionName' ]
  key 0                                             as PolymerCompositionIntIDRef,

      --PolymerCompositionName
      @Semantics.text: true
      _PlmrCompositionNotRqdText.ABAPLongFieldLabel as PolymerCompositionName,

      --ResponsibleUnit
      Substance.ResponsibleUnit                     as ResponsibleUnit
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHMLCOMPOSITION",
"I_PLMRCOMPOSITIONNOTRQDTEXT",
"I_SUBSTANCE"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/