I_SUBSTANCE

@EndUserText.label: 'Substance'
@VDM.viewType: #BASIC
@AbapCatalog.preserveKey:true

@AccessControl:
{
  authorizationCheck: #CHECK,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
}

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog: {
  sqlViewName:            'ISUB',
  compiler.compareFilter: true
}
@ObjectModel: {
  representativeKey: 'SubstanceUUID',
  usageType: {
    serviceQuality: #C,
    dataClass:      #MASTER,
    sizeCategory:   #M
  }
}
define view I_Substance
  as select from ehfndv_sub as Substance

  -- Company-specific names
  association [0..*] to I_SubstanceText             as _SubstanceText                 on Substance.substanceuuid = _SubstanceText.SubstanceUUID

  association [0..*] to I_SubstanceTradeSecretText  as _SubstanceTradeSecretText      on Substance.substanceuuid = _SubstanceTradeSecretText.SubstanceUUID

  -- Listed substance information
  -- Remark: Substance.substanceuuid is the active UUID => use _ListedSubstance.ActiveSubstanceUUID. If not no listed substance information is shown for draft
  association [0..1] to I_SubstActiveDraftLstdSubst as _ListedSubstance               on Substance.substanceuuid = _ListedSubstance.ActiveSubstanceUUID

  -- Admin data - Created by
  association [0..1] to I_User                      as _CreatedByUser                 on $projection.CreatedByUser = _CreatedByUser.UserID

  -- Admin data - Last changed by
  association [0..1] to I_User                      as _LastChangedByUser             on $projection.LastChangedByUser = _LastChangedByUser.UserID

  // Due to performance reasons for Tox, Ecotox, etc.

  association [1..1] to I_ResponsibleUnit           as _RespUnitForProductStewardship on $projection.ProdStewardshipRespUnit = _RespUnitForProductStewardship.ResponsibleUnit
  association [1..1] to I_ResponsibleUnitDngrsGds   as _RespUnitForDangerousGoods     on $projection.DngrsGdsRespUnit = _RespUnitForDangerousGoods.ResponsibleUnit
  association [0..1] to I_SubstNameFallbackLanguage as _SubstNameFallbackLanguage     on $projection.SubstanceUUID = _SubstNameFallbackLanguage.SubstanceUUID

{
  key Substance.substanceuuid                                                           as SubstanceUUID,

      @Semantics.systemDateTime.createdAt: true
      cast(Substance.creationutcdatetime as ehfnd_bo_crea_date_time preserving type )   as CreationUTCDateTime,
      @Semantics.user.createdBy: true
      cast(Substance.createdbyuser as ehfnd_bo_crea_uname preserving type )             as CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      cast(Substance.lastchangeutcdatetime as ehfnd_bo_lchg_date_time preserving type ) as LastChangeUTCDateTime,
      @Semantics.user.lastChangedBy: true
      cast(Substance.lastchangedbyuser as ehfnd_bo_lchg_uname preserving type )         as LastChangedByUser,

      Substance.listedsubstanceuuid                                                     as ListedSubstanceUUID,
      Substance.substanceinternalname                                                   as SubstanceInternalName,

      Substance.responsibleunit                                                         as ResponsibleUnit,

      Substance.specification                                                           as Specification,
      Substance.specificationinternalid                                                 as SpecificationInternalID,

      @ObjectModel.foreignKey.association: '_RespUnitForProductStewardship'
      Substance.responsibleunit                                                         as ProdStewardshipRespUnit,

      @ObjectModel.foreignKey.association: '_RespUnitForDangerousGoods'
      ''                                                                                as DngrsGdsRespUnit,
      Substance.polymerisbsdonoecddef                                                   as PolymerIsBsdOnOECDDef,

      //exposed associations

      _CreatedByUser,
      _LastChangedByUser,
      _SubstanceText,
      _SubstanceTradeSecretText,
      _ListedSubstance,
      _RespUnitForProductStewardship,
      _RespUnitForDangerousGoods,
      _SubstNameFallbackLanguage
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EHFNDV_SUB"
],
"ASSOCIATED":
[
"I_RESPONSIBLEUNIT",
"I_RESPONSIBLEUNITDNGRSGDS",
"I_SUBSTACTIVEDRAFTLSTDSUBST",
"I_SUBSTANCETEXT",
"I_SUBSTANCETRADESECRETTEXT",
"I_SUBSTNAMEFALLBACKLANGUAGE",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/