@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.allowExtensions: true
@VDM: {
viewType: #CONSUMPTION,
usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
}
@ObjectModel.usageType:{ serviceQuality: #D,
sizeCategory: #XXL,
dataClass: #MIXED }
@AccessControl.privilegedAssociations: ['_CreatedBy','_ChangedBy']
@Search.searchable: true
@EndUserText.label: 'Material Price Changes'
define root view entity C_MaterialLedgerPriceOverview
provider contract transactional_query
as projection on I_MaterialLedgerPriceOverview
{
key CostEstimate,
@ObjectModel.text.element: ['LedgerName']
@Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8 }
key Ledger,
key CurrencyRole,
@ObjectModel.text.element: ['MaterialPriceTypeName']
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
key MaterialPriceType,
key MaterialPriceSubtype,
key MaterialPriceValidityStartDate,
@Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.99 }
MaterialPriceValidityEndDate,
@ObjectModel: { virtualElement: true,
filter.transformedBy: 'ABAP:CL_FML_CHMP_FILTER_TRANSFORM'}
virtual ValidOnDate : fml_date_valid_on,
@Semantics.fiscal.yearPeriod: true
MatlPrcValdtyStrtFsclYearPerd,
@Semantics.calendar.year: true
MatlPrcValidityStartFiscalYear,
@Semantics.fiscal.period: true
MatlPrcValdtyStartFiscalPeriod,
@Semantics.fiscal.yearPeriod: true
MatlPrcValdtyEndFsclYearPeriod,
@Semantics.calendar.year: true
MatlPrcValidityEndFiscalYear,
@Semantics.fiscal.period: true
MatlPrcValdtyEndFiscalPeriod,
@Semantics.amount.currencyCode: 'Currency'
@Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.99 }
MaterialPrice,
FixedPortionOfMaterialPrice,
Currency,
@Semantics.quantity.unitOfMeasure: 'ValuationQuantityUnit'
@Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.9 }
MaterialPriceUnitQty,
ValuationQuantityUnit,
@ObjectModel.text.element: ['MaterialPriceControlName']
MaterialPriceControl,
@Semantics.text: true
_MaterialPriceControl._Text[1: Language = $session.system_language].MaterialPriceControlName as MaterialPriceControlName,
CurPlanProjSlsOrdValnStrategy,
@ObjectModel.text.element: ['MatlPriceCostEstimateStageName']
MaterialPriceCostEstimateStage,
@Semantics.text: true
_MatlPriceCostEstimateStage._Text[1: Language = $session.system_language].MatlPriceCostEstimateStageName as MatlPriceCostEstimateStageName,
@ObjectModel.text.element: ['MaterialName']
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
Material,
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
@Semantics.text: true
_Material._Text[1: Language = $session.system_language].MaterialName as MaterialName,
ValuationArea,
@ObjectModel.text.element: [ 'PlantName' ]
@Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8 }
Plant,
@Semantics.text: true
@Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8 }
_Plant.PlantName as PlantName,
InventoryValuationType,
@ObjectModel.text.element: [ 'CompanyCodeName' ]
CompanyCode,
@Semantics.text: true
_CompanyCode.CompanyCodeName as CompanyCodeName,
@ObjectModel.text.element: [ 'InventorySpecialStockTypeName' ]
InvtryValnSpecialStockType,
@Semantics.text: true
_InvtryValnSpecialStockType._Text[1: Language = $session.system_language].InventorySpecialStockTypeName as InventorySpecialStockTypeName,
SalesOrder,
SalesOrderItem,
@ObjectModel.text.element: [ 'WBSDescription' ]
_WBSElementBasicData.WBSElementExternalID,
@ObjectModel.text.element: ['Supplier']
Supplier,
@ObjectModel.text.element: [ 'StkMatlPriceValuationTypeName' ]
StkMaterialPriceValuationType,
@Semantics.text: true
_StkMatlPriceValuationType._Text[1: Language = $session.system_language].StkMatlPriceValuationTypeName as StkMatlPriceValuationTypeName,
MaterialPriceExtRefCategory,
MaterialPriceExtReference,
@Semantics.text: true
@Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8 }
_Ledger._Text[1: Language = $session.system_language].LedgerName as LedgerName,
@Semantics.text: true
_CurrencyRole._Text[1: Language = $session.system_language].CurrencyRoleName as CurrencyRoleName,
_LedgerValuationCrcyRole.LedgerValuationCurrencyRole,
@ObjectModel.text.element: [ 'LegalCurrencyRoleName' ]
@Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8 }
_LedgerValuationCrcyRole.LegalCurrencyRole,
@Semantics.text: true
@Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8 }
_LedgerValuationCrcyRole.LegalCurrencyRoleName,
@ObjectModel.text.element: ['AcctgValnVwSubviewCombinedName']
cast(_LedgerValuationCrcyRole.AcctgValnVwSubviewCombinedName as fml_umip_valuviewname preserving type ) as AcctgValnVwSubviewCombinedName,
@Semantics.text: true
@Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8 }
_PriceType._Text[1: Language = $session.system_language].MaterialPriceTypeName as MaterialPriceTypeName,
_LedgerValuationCrcyRole.LedgerValnCrcyRoleIsUsedInLogs,
@ObjectModel.text.element: [ 'MaterialPriceCreatedByUserName' ]
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_MatlLdgrPrCreatedByUserVH', element: 'MaterialPriceCreatedByUser' } }]
@Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8 }
MaterialPriceCreatedByUser,
@Semantics.text: true
_CreatedBy.FullName as MaterialPriceCreatedByUserName,
@ObjectModel.text.element: [ 'MaterialPriceChangedByUserName' ]
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_MatlLdgrPrChangedByUserVH', element: 'MaterialPriceChangedByUser' } }]
MaterialPriceChangedByUser,
@Semantics.text: true
_ChangedBy.FullName as MaterialPriceChangedByUserName,
@Semantics.text: true
_WBSElementBasicData.WBSDescription as WBSDescription,
MaterialPriceCreationDateTime,
MatlPriceLastChangeDateTime,
_Material,
_CreatedBy,
_ChangedBy
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_CURRENCYROLE",
"I_CURRENCYROLETEXT",
"I_INVTRYVALNSPECIALSTOCKTYPE",
"I_INVTRYVALNSPECIALSTOCKTYPET",
"I_LEDGER",
"I_LEDGERTEXT",
"I_MATERIAL",
"I_MATERIALLEDGERPRICEOVERVIEW",
"I_MATERIALLEDGERPRICETYPE",
"I_MATERIALLEDGERPRICETYPETEXT",
"I_MATERIALPRICECONTROL",
"I_MATERIALPRICECONTROLNAME",
"I_MATERIALTEXT",
"I_MATLPRCOSTESTIMATESTAGETEXT",
"I_MATLPRICECOSTESTIMATESTAGE",
"I_PLANT",
"I_STKMATLPRICEVALUATIONTYPE",
"I_STKMATLPRVALUATIONTYPETEXT",
"I_USERCONTACTCARD",
"I_WBSELEMENTBASICDATA",
"R_MATLLEDGERVALNCRCYROLE"
],
"ASSOCIATED":
[
"I_MATERIAL",
"I_USERCONTACTCARD"
],
"BASE":
[
"I_MATERIALLEDGERPRICEOVERVIEW"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/