I_MATERIALLEDGERPRICEOVERVIEW

@AbapCatalog.viewEnhancementCategory: [#NONE]
@Metadata.ignorePropagatedAnnotations: true

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #NOT_REQUIRED,
  privilegedAssociations: ['_CreatedBy','_ChangedBy']
}

@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XXL,
  dataClass: #MIXED
}
@ObjectModel.sapObjectNodeType.name: 'InventoryPriceChange'
@EndUserText.label: 'Material Price Change'
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
define root view entity I_MaterialLedgerPriceOverview
  as select from I_MaterialLedgerPrice

  association [0..1] to I_Plant                      as _Plant                      on  $projection.ValuationArea = _Plant.Plant
  association [1..1] to I_Material                   as _Material                   on  $projection.Material = _Material.Material
  association [1..1] to I_CompanyCode                as _CompanyCode                on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..1] to I_Ledger                     as _Ledger                     on  $projection.Ledger = _Ledger.Ledger
  association [0..1] to I_CurrencyRole               as _CurrencyRole               on  $projection.CurrencyRole = _CurrencyRole.CurrencyRole
  association [0..1] to I_UserContactCard            as _CreatedBy                  on  $projection.MaterialPriceCreatedByUser = _CreatedBy.ContactCardID
  association [0..1] to I_UserContactCard            as _ChangedBy                  on  $projection.MaterialPriceChangedByUser = _ChangedBy.ContactCardID
  association [0..1] to I_WBSElementBasicData        as _WBSElementBasicData        on  $projection.WBSElementInternalID = _WBSElementBasicData.WBSElementInternalID
  association [0..1] to I_InvtryValnSpecialStockType as _InvtryValnSpecialStockType on  $projection.InvtryValnSpecialStockType = _InvtryValnSpecialStockType.InvtryValnSpecialStockType
  association [0..1] to I_MatlPriceCostEstimateStage as _MatlPriceCostEstimateStage on  $projection.MaterialPriceCostEstimateStage = _MatlPriceCostEstimateStage.MaterialPriceCostEstimateStage
  association [0..1] to I_MaterialPriceControl       as _MaterialPriceControl       on  $projection.MaterialPriceControl = _MaterialPriceControl.MaterialPriceControl
  association [0..1] to I_StkMatlPriceValuationType  as _StkMatlPriceValuationType  on  $projection.StkMaterialPriceValuationType = _StkMatlPriceValuationType.StkMaterialPriceValuationType

  association [0..1] to R_MatlLedgerValnCrcyRole     as _LedgerValuationCrcyRole    on  $projection.CurrencyRole = _LedgerValuationCrcyRole.CurrencyRole
                                                                                    and $projection.Ledger       = _LedgerValuationCrcyRole.Ledger
                                                                                    and $projection.CompanyCode  = _LedgerValuationCrcyRole.CompanyCode
  association [1..1] to I_MaterialLedgerPriceType    as _PriceType                  on  $projection.MaterialPriceType = _PriceType.MaterialPriceType


{
  key        cast(CostEstimate as fml_chmp_cost_estimate_number preserving type )                                    as CostEstimate,
  key        Ledger,
  key        CurrencyRole,
  key        MaterialPriceType,
  key        MaterialPriceSubtype,
  key
             cast( case dats_is_valid(MaterialPriceValidityStartDate)
              when 1 then MaterialPriceValidityStartDate
              else '00010101'
              end    as fml_date_from preserving type )                                                              as MaterialPriceValidityStartDate,
             //MaterialPriceValidityStartDate as MatlPrValdtyStrtDteForEd,

             cast(MaterialPriceValidityEndDate as fml_date_to preserving type )                                      as MaterialPriceValidityEndDate,
             @Semantics.fiscal.yearPeriod: true
             cast( MatlPrcValdtyStrtFsclYearPerd as fml_from_period_year preserving type )                           as MatlPrcValdtyStrtFsclYearPerd,
             @Semantics.calendar.year: true
             MatlPrcValidityStartFiscalYear,
             @Semantics.fiscal.period: true
             MatlPrcValdtyStartFiscalPeriod,
             @Semantics.fiscal.yearPeriod: true
             cast( MatlPrcValdtyEndFsclYearPeriod as fml_to_period_year preserving type )                            as MatlPrcValdtyEndFsclYearPeriod,
             @Semantics.calendar.year: true
             MatlPrcValidityEndFiscalYear,
             @Semantics.fiscal.period: true
             MatlPrcValdtyEndFiscalPeriod,
             @Semantics.amount.currencyCode: 'Currency'
             MaterialPrice,
             Currency,
             @Semantics.quantity.unitOfMeasure: 'ValuationQuantityUnit'
             cast(MaterialPriceUnitQty as fml_mpchd_price_unit preserving type )                                     as MaterialPriceUnitQty,
             ValuationQuantityUnit,
             cast(MaterialPriceControl as fml_mpchd_price_control preserving type )                                  as MaterialPriceControl,
             @Semantics.amount.currencyCode: 'Currency'
             FixedPortionOfMaterialPrice,
             cast(CurPlanProjSlsOrdValnStrategy as fml_chmp_lbwst preserving type )                                  as CurPlanProjSlsOrdValnStrategy,
             MaterialPriceCostEstimateStage,
             Material,
             ValuationArea,
             cast(ValuationArea as werks_d preserving type )                                                         as Plant,
             cast(InventoryValuationType as fml_mpchd_valuation_type preserving type )                               as InventoryValuationType,
             CompanyCode,
             InvtryValnSpecialStockType,
             cast(SalesOrder as vbeln preserving type )                                                              as SalesOrder,
             cast(SalesOrderItem as posnr preserving type )                                                          as SalesOrderItem,
             cast(WBSElementInternalID as ps_s4_pspnr preserving type )                                              as WBSElementInternalID,
             cast(Supplier as lifnr preserving type )                                                                as Supplier,
             StkMaterialPriceValuationType,
             MaterialPriceExtRefCategory,
             MaterialPriceExtReference,
             MaterialPriceCreatedByUser,
             MaterialPriceChangedByUser,
             cast(MaterialPriceCreationDateTime as fml_chmp_created_on preserving type )                             as MaterialPriceCreationDateTime,
             cast(MatlPriceLastChangeDateTime as fml_chmp_changed_on preserving type )                               as MatlPriceLastChangeDateTime,
             cast(_LedgerValuationCrcyRole.AcctgValnVwSubviewCombinedName as fml_umip_valuviewname preserving type ) as AcctgValnVwSubviewCombinedName,

             cast('' as fac_network_graph_group_id)                                                                  as UI5NetworkGraphGroup, //for testing


             _Plant,
             _Material,
             _CompanyCode,
             _Ledger,
             _CurrencyRole,
             _LedgerValuationCrcyRole,
             _CreatedBy,
             _ChangedBy,
             _WBSElementBasicData,
             _MaterialPriceControl,
             _InvtryValnSpecialStockType,
             _MatlPriceCostEstimateStage,
             _StkMatlPriceValuationType,
             _PriceType

}

where
      CostEstimate      <> '000000000000'
  and MaterialPriceType =  'INVPR'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIALLEDGERPRICE",
"R_MATLLEDGERVALNCRCYROLE"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCYROLE",
"I_INVTRYVALNSPECIALSTOCKTYPE",
"I_LEDGER",
"I_MATERIAL",
"I_MATERIALLEDGERPRICETYPE",
"I_MATERIALPRICECONTROL",
"I_MATLPRICECOSTESTIMATESTAGE",
"I_PLANT",
"I_STKMATLPRICEVALUATIONTYPE",
"I_USERCONTACTCARD",
"I_WBSELEMENTBASICDATA",
"R_MATLLEDGERVALNCRCYROLE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/