C_MaintNotificationItemTP_3

@AbapCatalog.sqlViewName: 'CNOTIFITTP3'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Maintenance Notification Item'
@VDM: {
    viewType: #CONSUMPTION
}
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@ClientHandling.algorithm: #SESSION_VARIABLE

define view C_MaintNotificationItemTP_3
  as select from R_MaintNotificationItemTP

{
      @EndUserText.label: 'Maintenance Notification'
  key MaintenanceNotification,

      @EndUserText.label: 'Maintenance Notification Item'
  key MaintenanceNotificationItem,

      //   Damage Description

      @UI.lineItem: [{position: 50 }]
      @EndUserText.label: 'Damage Description'
      MaintNotifItemText,

      // Damage Code Group

      @EndUserText.label: 'Damage Code Group'
      @Consumption.valueHelpDefinition: [
            { entity:  { name:    'I_InspectionCodeGroup',
                         element: 'InspectionCodeGroup' },
              additionalBinding: [{  localElement: 'MaintNotifDamageCodeCatalog', element: 'InspectionCatalog'}]
            }]
      MaintNotifDamageCodeGroup,

      // Damage Code Group Short text

      @EndUserText.label: 'Damage Code Group Text'
      _MaintNotifDamageCodeGroup._Text[1:Language=$session.system_language].InspSpecAddlCodeGroupText as MaintNotifDamageCodeGroupName,

      // Damage Code

      @EndUserText.label: 'Damage Code'
      @Consumption.valueHelpDefinition: [
            { entity:  { name:    'I_InspectionCode',
                         element: 'InspectionCode' },
              additionalBinding: [{  localElement: 'MaintNotifDamageCodeCatalog', element: 'InspectionCatalog'}]
            }]
      MaintNotificationDamageCode,

      // Damage Code Short text

      @UI.lineItem: [{position: 10 }]
      @EndUserText.label: 'Damage Code Description'
      _MaintNotificationDamageCode._Text[1:Language=$session.system_language].InspectionCodeText      as MaintNotifDamageCodeName,

      @Consumption: { hidden: true }
      //  Damage Code Catalog

      MaintNotifDamageCodeCatalog,

      // Object Part Code Group

      @EndUserText.label: 'Object Part Code Group'
      @Consumption.valueHelpDefinition: [
            { entity:  { name:    'I_InspectionCodeGroup',
                         element: 'InspectionCodeGroup' },
              additionalBinding: [{  localElement: 'MaintNotifObjPrtCodeCatalog', element: 'InspectionCatalog'}]
            }]
      MaintNotifObjPrtCodeGroup,

      // Object Part Code Group Short Text

      @EndUserText.label: 'Object Part Code Group Text'
      _MaintNotifObjPrtCodeGroup._Text[1:Language=$session.system_language].InspSpecAddlCodeGroupText as MaintNotifObjPrtCodeGroupName,

      // Object Part Code

      @EndUserText.label: 'Object Part Code'
      @Consumption.valueHelpDefinition: [
            { entity:  { name:    'I_InspectionCode',
                         element: 'InspectionCode' },
              additionalBinding: [{  localElement: 'MaintNotifObjPrtCodeCatalog', element: 'InspectionCatalog'}]
            }]
      MaintNotifObjPrtCode,

      // Object Part Code Short Text

      @UI.lineItem: [{position: 20 }]
      @EndUserText.label: 'Object Part Code Description'
      _MaintNotifObjPrtCode._Text[1:Language=$session.system_language].InspectionCodeText             as MaintNotifObjPrtCodeName,

      // Object Part Code Catalog

      @Consumption: { hidden: true }
      MaintNotifObjPrtCodeCatalog,

      @EndUserText.label: 'Cause'
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_MALFUNC_COUNT_EXIT'
      @UI.lineItem: [{position: 30 }]
      cast(0 as abap.int4 )                                                                           as NumberOfMaintNotifCauses,
      
      @EndUserText.label: 'Activity'
      @UI.lineItem: [{position: 40 }]
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_MALFUNC_COUNT_EXIT'
      cast(0 as abap.int4 )                                                                           as NumberOfMaintNotifActivities,
      
      @Consumption.hidden: true
      IsDeleted,
      
      @Consumption.hidden: true
      _MaintenanceNotification,

      _ItemCause,
      _ItemActivity

} where IsDeleted = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSPECTIONCODE",
"I_INSPECTIONCODEGROUP",
"I_INSPECTIONCODEGROUPTEXT",
"I_INSPECTIONCODETEXT",
"R_MAINTNOTIFICATIONITEMTP"
],
"ASSOCIATED":
[
"I_MAINTENANCENOTIFICATION",
"R_MAINTNOTIFICATIONITEMCAUSETP",
"R_MAINTNOTIFITEMACTIVITYTP"
],
"BASE":
[
"R_MAINTNOTIFICATIONITEMTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/