R_MAINTNOTIFICATIONITEMTP

CDS View

Maintenance Notification Item

R_MAINTNOTIFICATIONITEMTP is a CDS View in S/4HANA. Maintenance Notification Item. It contains 2 fields. 4 CDS views read from this table.

Used by 4 CDS view(s) 2 fields

CDS Views using this table (4)

ViewTypeJoinVDMDescription
A_MaintNotificationItem view_entity projection COMPOSITE Maintenance Notification Item
C_MaintNotificationItemTP_2 view_entity projection CONSUMPTION Maintenance Notification Item
C_MaintNotificationItemTP_3 view from CONSUMPTION Maintenance Notification Item
I_MaintNotificationItemTP_2 view_entity projection TRANSACTIONAL Maintenance Notification Item TP

Fields (2)

KeyField CDS FieldsUsed in Views
MaintNotifItemChangedDateTime MaintNotifItemChangedDateTime 1
MaintNotifItemCreationDateTime MaintNotifItemCreationDateTime 1 
//@AbapCatalog.sqlViewName: 'RMAINTNTFITEMTP'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Notification Item'
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true
//@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #TRANSACTIONAL

@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MASTER}

define view entity R_MaintNotificationItemTP
  as select from I_MaintenanceNotificationItem

  //Parent

  association to parent R_MaintenanceNotificationTP    as _Notif on _Notif.MaintenanceNotification = $projection.MaintenanceNotification

  // Child

  composition [0..*] of R_MaintNotificationItemCauseTP as _ItemCause

  composition [0..*] of R_MaintNotifItemActivityTP     as _ItemActivity

  composition [0..*] of R_MaintNotificationItemTaskTP  as _ItemTask
{

      //   Maintenance Notification

  key MaintenanceNotification,

      //   Maintenance Notification Item

  key MaintenanceNotificationItem,

      //   Damage Description

      MaintNotifItemText,

      // Damage Code Group

      MaintNotifDamageCodeGroup,

      // Damage Code

      MaintNotificationDamageCode,


      @Consumption: { hidden: true }
      //  Damage Code Catalog

      MaintNotifDamageCodeCatalog,

      // Object Part Code Group

      MaintNotifObjPrtCodeGroup,


      // Object Part Code

      MaintNotifObjPrtCode,


      @Consumption: { hidden: true }
      // Object Part Code Catalog

      MaintNotifObjPrtCodeCatalog,
      @Semantics.booleanIndicator: true
      IsDeleted,
       cast (dats_tims_to_tstmp( CreationDate, CreationTime, abap_system_timezone( $session.client,'NULL' ) , $session.client, 'NULL') as  tzntstmps preserving type )         as MaintNotifItemCreationDateTime, 
       cast (dats_tims_to_tstmp( LastChangeDate, LastChangeTime, abap_system_timezone( $session.client,'NULL' ) , $session.client, 'NULL') as  tzntstmps preserving type )         as MaintNotifItemChangedDateTime,                       

      // Root View

      _Notif,

      // Child

      _ItemCause,
      _ItemActivity,
      _ItemTask,

      // Association

      _MaintNotifDamageCodeGroup,
      _MaintNotifObjPrtCodeGroup,
      _MaintNotificationDamageCode,
      _MaintNotifObjPrtCode,
      _MaintenanceNotification,
      _IsDeleted

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MAINTENANCENOTIFICATIONITEM"
],
"ASSOCIATED":
[
"I_INDICATOR",
"I_INSPECTIONCODE",
"I_INSPECTIONCODEGROUP",
"I_MAINTENANCENOTIFICATION",
"R_MAINTENANCENOTIFICATIONTP",
"R_MAINTNOTIFICATIONITEMCAUSETP",
"R_MAINTNOTIFICATIONITEMTASKTP",
"R_MAINTNOTIFITEMACTIVITYTP"
],
"BASE":
[
"I_MAINTENANCENOTIFICATIONITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More