@EndUserText.label: 'Freight Order Management'
@ObjectModel: { representativeKey: 'TransportationOrderUUID',
semanticKey: ['FreightOrder'],
usageType: {serviceQuality: #C,
sizeCategory: #XL,
dataClass: #TRANSACTIONAL}}
@VDM: { viewType: #CONSUMPTION,
usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]}
@AccessControl: { authorizationCheck: #CHECK,
personalData.blocking:#('TRANSACTIONAL_DATA'),
privilegedAssociations: ['_TranspOrdSummary',
'_TranspChargeObject',
'_SourceStop',
'_FrtCostDistrRoot',
'_DestinationStop',
'_DeliveryRatio'
]}
@Metadata.allowExtensions: true
define root view entity C_FrtOrdManagement
as select from I_TransportationOrder
association [0..1] to E_TransportationOrder as _Extension on $projection.TransportationOrderUUID = _Extension.TransportationOrderUUID
association [1..1] to I_TranspOrdDeliveryRatio as _DeliveryRatio on $projection.TransportationOrderUUID = _DeliveryRatio.TransportationOrderUUID
association [0..1] to I_BusinessPartner as _ConsigneeParty on $projection.Consignee = _ConsigneeParty.BusinessPartner
association [0..1] to I_BusinessPartnerVH as _ConsigneePartyVH on $projection.Consignee = _ConsigneePartyVH.BusinessPartner
association [0..1] to I_BusinessPartner as _ShipperParty on $projection.Shipper = _ShipperParty.BusinessPartner
association [0..1] to I_BusinessPartner as _CarrierParty on $projection.Carrier = _CarrierParty.BusinessPartner
association [0..1] to I_BusinessPartnerVH as _CarrierPartyVH on $projection.Carrier = _CarrierPartyVH.BusinessPartner
association [0..1] to I_FreightOrderVH as _FreightOrderVH on $projection.FreightOrder = _FreightOrderVH.FreightOrder
association [0..1] to I_TransportationOrderItem as _AvrItem on $projection.TransportationOrderUUID = _AvrItem.TransportationOrderUUID
and _AvrItem.TranspOrdItemCategory = 'AVR'
// Type assocs
association [1..1] to I_UnitOfMeasure as _DisplayLengthUnit on _DisplayLengthUnit.UnitOfMeasureDimension = 'LENGTH'
and $projection.DisplayLengthUnit = _DisplayLengthUnit.UnitOfMeasure
// Integration of Charges
association [0..1] to C_TranspChargeObject as _TranspChargeObject on $projection.TransportationOrderUUID = _TranspChargeObject.TranspChargeHostDocumentUUID
// Integration of Cost Distribution
association [0..1] to C_FrtCostDistrRoot as _FrtCostDistrRoot on $projection.TransportationOrderUUID = _FrtCostDistrRoot.TransportationOrderUUID
{
// Root Attributes
key cast(TransportationOrderUUID as /scmtms/vdm_tor_db_key preserving type ) as TransportationOrderUUID,
TransportationOrder as FreightOrder,
@ObjectModel.text.element: ['TransportationOrderTypeDesc']
TransportationOrderType as TransportationOrderType,
@Semantics.text: true
_TransportationOrderType._Text[1:Language = $session.system_language ].TransportationOrderTypeDesc as TransportationOrderTypeDesc,
TranspOrdPartnerReference as TranspOrdPartnerReference,
_AvrItem.TranspOrdActvVehRscePltNmbr as TranspOrdActvVehRscePltNmbr,
@ObjectModel.text.element: ['PurchasingOrganizationName']
@Consumption.labelElement: 'PurchasingOrganizationName'
PurchasingOrgExternalID as PurchasingOrgExternalID,
//PurchasingOrganization,
@Semantics.text: true
_PurchasingOrganization._OrganizationalUnitText[1:Language = $session.system_language].OrganizationalUnitName as PurchasingOrganizationName,
@ObjectModel.text.element: ['PurchasingGroupName']
@Consumption.labelElement: 'PurchasingGroupName'
PurchasingGroupExternalID as PurchasingGroupExternalID,
//PurchasingGroup,
@Semantics.text: true
_PurchasingGroup._OrganizationalUnitText[1:Language = $session.system_language].OrganizationalUnitName as PurchasingGroupName,
cast(_PlngAndExecOrganization.OrganizationalUnitExternalID as /scmtms/exec_org_ext_id preserving type ) as PlngAndExecOrgExternalID,
cast(_PlngAndExecGroup.OrganizationalUnitExternalID as /scmtms/exec_grp_ext_id preserving type ) as PlngAndExecGroupExternalID,
@ObjectModel.text.element: ['PurgOrgCompanyCodeName']
PurgOrgCompanyCode as PurgOrgCompanyCode,
@Semantics.text: true
_PurchasingCompanyCode.CompanyCodeName as PurgOrgCompanyCodeName,
TranspOrdResponsiblePerson as TranspOrdResponsiblePerson,
@ObjectModel.text.element: ['TransportationModeDesc']
TransportationMode as TransportationMode,
@Semantics.text: true
_TransportationMode._Text[1:Language = $session.system_language].TransportationModeDesc as TransportationModeDesc,
TransportationOrderCrtnType as TransportationOrderCrtnType,
TransportationOrderCategory as TransportationOrderCategory,
@Semantics.quantity.unitOfMeasure: 'TranspOrdGrossWeightUnit'
cast(TranspOrdGrossWeight as /scmtms/quantity_13_3 ) as TranspOrdGrossWeight,
TranspOrdGrossWeightUnit as TranspOrdGrossWeightUnit,
@Semantics.quantity.unitOfMeasure: 'TranspOrdGrossVolumeUnit'
cast(TranspOrdGrossVolume as /scmtms/quantity_13_3 ) as TranspOrdGrossVolume,
TranspOrdGrossVolumeUnit as TranspOrdGrossVolumeUnit,
@Semantics.quantity.unitOfMeasure: 'TranspOrdQuantityUnit'
cast(TranspOrdQuantity as /scmtms/quantity_13_3 ) as TranspOrdQuantity,
TranspOrdQuantityUnit as TranspOrdQuantityUnit,
@Semantics.quantity.unitOfMeasure: 'TranspOrdPalletSpacesUnit'
cast(TranspOrdPalletSpacesQty as /scmtms/quantity_13_3 ) as TranspOrdPalletSpacesQty,
TranspOrdPalletSpacesUnit as TranspOrdPalletSpacesUnit,
@Semantics.quantity.unitOfMeasure: 'TranspOrdLoadMetersUnit'
cast(TranspOrdLoadMetersQty as /scmtms/quantity_13_3 ) as TranspOrdLoadMetersQty,
TranspOrdLoadMetersUnit as TranspOrdLoadMetersUnit,
TranspOrdMaxUtilznRatio as TranspOrdMaxUtilznRatio,
cast( case
when TranspOrdMaxUtilznRatio > 100 then 1
else 3
end as /scmtms/vdm_tor_util_critlty ) as TranspOrdMaxUtilznRatioCritlty,
@ObjectModel.foreignKey.association: '_CarrierParty'
@ObjectModel.text.element: ['CarrierName']
Carrier as Carrier,
// Only Temporary - to be removed if causing Performance issues
@Semantics.text: true
_Carrier.BusinessPartnerFullName as CarrierName,
// @ObjectModel.text.element: ['TranspSCACCodeDesc']
StandardCarrierAlphaCode as StandardCarrierAlphaCode,
// @Semantics.text: true
// _TranspSCACCode._Text[1:Language = $session.system_language].TranspSCACCodeDesc as TranspSCACCodeDesc,
//
@ObjectModel.foreignKey.association: '_ShipperParty'
Shipper as Shipper,
@ObjectModel.foreignKey.association: '_ConsigneeParty'
Consignee as Consignee,
// Status
@ObjectModel.text.element: ['TranspOrdLifeCycleStatusDesc']
TranspOrdLifeCycleStatus as TranspOrdLifeCycleStatus,
//Life Cycle status with color coding
cast( case TranspOrdLifeCycleStatus
when '10' then 1
when '01' then 0
when '02' then 0
when '05' then 3
end as /scmtms/vdm_tor_lc_sts_critlty ) as TranspOrdLifeCycStsCritlty,
@Semantics.text: true
_TranspOrdLifeCycleStatus._Text[1:Language = $session.system_language ].TranspOrdLifeCycleStatusDesc as TranspOrdLifeCycleStatusDesc,
@ObjectModel.text.element: ['TranspOrdPlanningStatusDesc']
TranspOrdPlanningStatus as TranspOrdPlanningStatus,
@Semantics.text: true
_TranspOrdPlanningStatus._Text[1:Language = $session.system_language ].TranspOrdPlanningStatusDesc as TranspOrdPlanningStatusDesc,
@ObjectModel.text.element: ['TransportationOrderExecStsDesc']
TransportationOrderExecSts as TransportationOrderExecSts,
@Semantics.text: true
_TransportationOrderExecSts._Text[1:Language = $session.system_language ].TransportationOrderExecStsDesc as TransportationOrderExecStsDesc,
@ObjectModel.text.element: ['TranspOrderDngrsGdsStsDesc']
TranspOrderDngrsGdsSts as TranspOrderDngrsGdsSts,
@Semantics.text: true
_TranspOrdDngrsGdsStatus._Text[1:Language = $session.system_language ].TranspOrderDngrsGdsStsDesc as TranspOrderDngrsGdsStsDesc,
@ObjectModel.text.element: ['TranspOrderSubcontrgStsDesc']
TranspOrderSubcontrgSts as TranspOrderSubcontrgSts,
@Semantics.text: true
_TranspOrdSubcontractingSts._Text[1:Language = $session.system_language ].TranspOrderSubcontrgStsDesc as TranspOrderSubcontrgStsDesc,
@ObjectModel.text.element: ['TransportationOrderConfStsDesc']
TransportationOrderConfSts as TransportationOrderConfSts,
@Semantics.text: true
_TranspOrdConfirmationStatus._Text[1:Language = $session.system_language ].TransportationOrderConfStsDesc as TransportationOrderConfStsDesc,
// Locations & Times
@ObjectModel.text.element: ['SourceLocationLabel']
_SourceStop.LocationId as SourceLocation,
@Semantics.text: true
_SourceStop._Locationdescr.AddressObjectDescription as SourceLocationLabel,
tstmp_to_dats(_SourceStop.TranspOrdStopPlanTranspDteTme,
abap_user_timezone( $session.user,$session.client,'NULL' ) ,
$session.client,
'NULL' ) as TranspOrdDepartureDate,
tstmp_to_tims(_SourceStop.TranspOrdStopPlanTranspDteTme,
abap_user_timezone( $session.user,$session.client,'NULL' ) ,
$session.client,
'NULL' ) as TranspOrdDepartureTime,
cast ( _SourceStop.TranspOrdStopPlanTranspDteTme as log_created_on preserving type ) as TranspOrdDepartureDateTime,
@ObjectModel.text.element: ['DestinationLocationLabel']
_DestinationStop.LocationId as DestinationLocation,
@Semantics.text: true
_DestinationStop._Locationdescr.AddressObjectDescription as DestinationLocationLabel,
tstmp_to_dats( _DestinationStop.TranspOrdStopPlanTranspDteTme,
abap_user_timezone( $session.user,$session.client,'NULL' ) ,
$session.client,
'NULL' ) as TranspOrdArrivalDate,
tstmp_to_tims(_DestinationStop.TranspOrdStopPlanTranspDteTme,
abap_user_timezone( $session.user,$session.client,'NULL' ) ,
$session.client,
'NULL' ) as TranspOrdArrivalTime,
cast ( _DestinationStop.TranspOrdStopPlanTranspDteTme as log_created_on preserving type ) as TranspOrdArrivalDateTime,
TranspOrdOrderDateTime as TranspOrdOrderDateTime,
tstmp_to_dats( TranspOrdOrderDateTime,
abap_user_timezone( $session.user,$session.client,'NULL' ) ,
$session.client,
'NULL' ) as TranspOrdOrderDate,
tstmp_to_tims( TranspOrdOrderDateTime,
abap_user_timezone( $session.user,$session.client,'NULL' ) ,
$session.client,
'NULL' ) as TranspOrdOrderTime,
case
// when _DeliveryRatio.TranspOrderNmbrOfDelivRlvtItm is initial then _DeliveryRatio.TranspOrderNmbrOfDelivRlvtItm
when _DeliveryRatio.TranspOrderNmbrOfDelivRlvtItm = 0 or _DeliveryRatio.TranspOrderNmbrOfDelivRlvtItm is null then 0
else ( division(_DeliveryRatio.TranspOrderNmbrOfItmWthDeliv * 100, _DeliveryRatio.TranspOrderNmbrOfDelivRlvtItm, 2) )
end as TranspOrdDelivCrtnPrgrsPct,
TranspOrdDistanceUnit as DisplayLengthUnit,
@Semantics.quantity.unitOfMeasure: 'DisplayLengthUnit'
cast(TranspOrdDistance as /scmtms/quantity_13_3 ) as TranspOrdDistanceInDspUnit,
// Integration of Charges
_TranspChargeObject.TransportationChargesObjUUID as TransportationChargesObjUUID,
@ObjectModel.text.element: ['TranspChargeCalcStatusDesc']
_TranspChargeObject.TranspChargeCalcStatus as TranspChargeCalcStatus,
@Semantics.text: true
_TranspChargeObject.TranspChargeCalcStatusDesc as TranspChargeCalcStatusDesc,
_TranspChargeObject.TranspChrgTotalAmtInDocCrcy as TranspChrgTotalAmtInDocCrcy,
_TranspChargeObject.TranspChargeDocumentCurrency as TranspChargeDocumentCurrency,
// //TransportationAgreementUUID is required for navigation to the agreement details page when the link on agreement is clicked
// _TranspChargeObject.TransportationAgreementUUID as TransportationAgreementUUID,
// _TranspChargeObject.TransportationAgreement as TransportationAgreement,
// Integration of Cost Distribution
_FrtCostDistrRoot.FrtCostDistrRootUUID as FrtCostDistrRootUUID,
@ObjectModel.text.element: ['FrtCostDistrStatusTxt']
_FrtCostDistrRoot.FrtCostDistrStatus as FrtCostDistrStatus,
@Semantics.text: true
_FrtCostDistrRoot.FrtCostDistrStatusTxt as FrtCostDistrStatusTxt,
_TranspOrdSummary.TranspOrdGoodsValueAmount as TranspOrdGoodsValueAmount,
_TranspOrdSummary.TranspOrdGoodsValueCrcy as TranspOrdGoodsValueCrcy,
@ObjectModel.text.element: ['TranspOrdExecutionBlockDesc']
TranspOrdExecutionIsBlocked as TranspOrdExecutionIsBlocked,
@Semantics.text: true
_TranspOrdExecutionIsBlocked._Text[1:Language = $session.system_language ].TranspOrdExecutionBlockDesc as TranspOrdExecutionBlockDesc,
/* Associations */
@Consumption.filter.hidden: true
_SourceStop,
@Consumption.filter.hidden: true
_DestinationStop,
@Consumption.filter.hidden: true
_TranspOrdPlanningStatus,
@Consumption.filter.hidden: true
_TranspOrdLifeCycleStatus,
@Consumption.filter.hidden: true
_TransportationOrderExecSts,
@Consumption.filter.hidden: true
_TranspOrdDngrsGdsStatus,
@Consumption.filter.hidden: true
_TranspOrdSubcontractingSts,
@Consumption.filter.hidden: true
_TranspOrdExecutionIsBlocked,
// @Consumption.filter.hidden: true
// _TranspOrdConfirmationStatus,
@Consumption.filter.hidden: true
_ConsigneeParty,
@Consumption.filter.hidden: true
_ConsigneePartyVH,
@Consumption.filter.hidden: true
_ShipperParty,
@Consumption.filter.hidden: true
_CarrierParty,
@Consumption.filter.hidden: true
_CarrierPartyVH,
@Consumption.filter.hidden: true
_FreightOrderVH,
@Consumption.filter.hidden: true
_DeliveryRatio,
@Consumption.filter.hidden: true
_TranspChargeObject,
@Consumption.filter.hidden: true
_TranspChargeObject._TranspChargeCalcStatus,
// Integration of Cost Distribution
@Consumption.filter.hidden: true
_FrtCostDistrRoot._DistrStatus,
@Consumption.filter.hidden: true
_FrtCostDistrRoot,
_TranspOrdSummary,
@Consumption.filter.hidden: true
_AvrItem
}
where
TransportationOrderCategory = 'TO' // /SCMTMS/IF_TOR_CONST=>SC_TOR_CATEGORY-ACTIVE
and TransportationOrder is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_FRTCOSTDISTRROOT",
"C_TRANSPCHARGEOBJECT",
"I_BUSINESSPARTNER",
"I_COMPANYCODE",
"I_TMLOCATIONDESCRIPTION",
"I_TRANSPORDCONFIRMATIONSTATUS",
"I_TRANSPORDCONFIRMATIONSTSTEXT",
"I_TRANSPORDDELIVERYRATIO",
"I_TRANSPORDDNGRSGDSSTATUS",
"I_TRANSPORDDNGRSGDSSTATUSTEXT",
"I_TRANSPORDEXECUTIONBLOCKTEXT",
"I_TRANSPORDEXECUTIONISBLOCKED",
"I_TRANSPORDLIFECYCLESTATUS",
"I_TRANSPORDLIFECYCLESTATUSTEXT",
"I_TRANSPORDPLANNINGSTATUS",
"I_TRANSPORDPLANNINGSTATUST",
"I_TRANSPORDSUBCONTRACTINGSTS",
"I_TRANSPORDSUBCONTRACTINGSTST",
"I_TRANSPORGANIZATIONALUNIT",
"I_TRANSPORGANIZATIONALUNITTEXT",
"I_TRANSPORTATIONMODE",
"I_TRANSPORTATIONMODETEXT",
"I_TRANSPORTATIONORDER",
"I_TRANSPORTATIONORDEREXECSTS",
"I_TRANSPORTATIONORDEREXECSTST",
"I_TRANSPORTATIONORDERITEM",
"I_TRANSPORTATIONORDERSMMRY",
"I_TRANSPORTATIONORDERSTOP",
"I_TRANSPORTATIONORDERTYPE",
"I_TRANSPORTATIONORDERTYPETEXT"
],
"ASSOCIATED":
[
"C_FRTCOSTDISTRROOT",
"C_TRANSPCHARGEOBJECT",
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNERVH",
"I_FREIGHTORDERVH",
"I_FRTCOSTDISTRSTATUS",
"I_TRANSPCHARGECALCSTATUS",
"I_TRANSPORDDELIVERYRATIO",
"I_TRANSPORDDNGRSGDSSTATUS",
"I_TRANSPORDEXECUTIONISBLOCKED",
"I_TRANSPORDLIFECYCLESTATUS",
"I_TRANSPORDPLANNINGSTATUS",
"I_TRANSPORDSUBCONTRACTINGSTS",
"I_TRANSPORTATIONORDEREXECSTS",
"I_TRANSPORTATIONORDERITEM",
"I_TRANSPORTATIONORDERSMMRY",
"I_TRANSPORTATIONORDERSTOP"
],
"BASE":
[
"C_FRTCOSTDISTRROOT",
"C_TRANSPCHARGEOBJECT",
"I_TRANSPORTATIONORDER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/