I_FreightOrderVH

@AbapCatalog.sqlViewName: 'IFREIGHTORDER_VH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #COMPOSITE
@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.representativeKey: 'TransportationOrderUUID'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER //to do

@Search.searchable: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'TM Freight Order value help'
define view I_FreightOrderVH
  as select distinct from I_TransportationOrder
{
      @Consumption.filter.hidden: true
      @UI.hidden: true
      key cast(TransportationOrderUUID     as /scmtms/vdm_tor_db_key preserving type )      as TransportationOrderUUID,
        
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @EndUserText.label: 'Freight Order'
      TransportationOrder                 as FreightOrder,
      @EndUserText.label: 'Freight Order Type'
      TransportationOrderType,
      @EndUserText.label: 'Partner Reference Number'
      TranspOrdPartnerReference,
      @Semantics.user.createdBy: true
      @EndUserText.label: 'Created By'
      CreatedByUser,
      @EndUserText.label: 'Created On'
      CreationDateTime,
      @EndUserText.label: 'Life Cycle Status'
      TranspOrdLifeCycleStatus,
      @EndUserText.label: 'Dangerous Goods Status'
      TranspOrderDngrsGdsSts,
      @EndUserText.label: 'Purch. Organization'
      PurchasingOrganization,
      @EndUserText.label: 'Carrier'
      Carrier,
      @EndUserText.label: 'Purchazing Group'
      PurchasingGroup,
      @EndUserText.label: 'Shipper'
      Shipper,
      @EndUserText.label: 'Ship-to Party'
      Consignee,
      @EndUserText.label: 'Plan. and Exec. Org'
      @UI: {lineItem: [ {hidden: true} ]}
      PlngAndExecOrganization,
      @EndUserText.label: 'Plan. Exec. Group'
      PlngAndExecGroup,
      @EndUserText.label: 'Planning Status'
      TranspOrdPlanningStatus,
      @EndUserText.label: 'Source Location ID'
      @Consumption.valueHelpDefinition: [{ entity: {name: 'I_TransportationLocationVH' , element: 'Location'}}]
      _SourceStop.LocationId as SourceLocation, 
      @EndUserText.label: 'Destination Location ID'
      @Consumption.valueHelpDefinition: [{ entity: {name: 'I_TransportationLocationVH' , element: 'Location'}}]
      _DestinationStop.LocationId as DestinationLocation,
      @UI.hidden: true
      MeansOfTransport,
      @UI.hidden: true
      TranspOrdResponsiblePerson

}
where
      TransportationOrderCategory = 'TO' // /SCMTMS/IF_TOR_CONST=>SC_TOR_CATEGORY-ACTIVE

  and TransportationOrder         is not initial
  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_TRANSPORTATIONORDER",
"I_TRANSPORTATIONORDERSTOP"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/