C_FrtOrdExecution

@EndUserText.label: 'Freight Orders Execution'
@ObjectModel:   {   representativeKey:  'TransportationOrderUUID',
                    semanticKey:        ['FreightOrder'],
                    usageType:          {serviceQuality: #C,
                                         sizeCategory:   #XL,
                                         dataClass:      #TRANSACTIONAL}}

@VDM:           {   viewType:           #CONSUMPTION,
                    usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]}
@AccessControl: {   authorizationCheck: #CHECK,
                    personalData.blocking:#('TRANSACTIONAL_DATA'),
                    privilegedAssociations: [ '_DeliveryRatio',
                                              '_SourceStop',
                                              '_DestinationStop',
                                              '_TranspChargeObject',
                                              '_FrtCostDistrRoot',
                                              '_LastReportedEvent',
                                              '_LastReportedCheckOutEvent'

                     ]}
@Metadata.allowExtensions:  true

define root view entity C_FrtOrdExecution

  as select from I_TransportationOrder

  association [1..1] to I_TranspOrdDeliveryRatio       as _DeliveryRatio             on  $projection.TransportationOrderUUID = _DeliveryRatio.TransportationOrderUUID
  association [0..1] to I_BusinessPartner              as _ConsigneeParty            on  $projection.Consignee = _ConsigneeParty.BusinessPartner
  association [0..1] to I_BusinessPartnerVH            as _ConsigneePartyVH          on  $projection.Consignee = _ConsigneePartyVH.BusinessPartner
  association [0..1] to I_BusinessPartner              as _ShipperParty              on  $projection.Shipper = _ShipperParty.BusinessPartner
  association [0..1] to I_BusinessPartnerVH            as _ShipperPartyVH            on  $projection.Shipper = _ShipperPartyVH.BusinessPartner
  association [0..1] to I_BusinessPartner              as _CarrierParty              on  $projection.Carrier = _CarrierParty.BusinessPartner
  association [0..1] to I_BusinessPartnerVH            as _CarrierPartyVH            on  $projection.Carrier = _CarrierPartyVH.BusinessPartner
  association [0..1] to I_FreightOrderVH               as _FreightOrderVH            on  $projection.FreightOrder = _FreightOrderVH.FreightOrder
  association [0..1] to I_TranspOrdLastRptdEvent       as _LastReportedEvent         on  $projection.TransportationOrderUUID = _LastReportedEvent.TransportationOrderUUID
  association [0..1] to I_TranspOrdLastRptdCheckOutEvt as _LastReportedCheckOutEvent on  $projection.TransportationOrderUUID = _LastReportedCheckOutEvent.TransportationOrderUUID
  association [0..1] to I_TranspChargeObject           as _TranspChargeObject        on  $projection.TransportationOrderUUID = _TranspChargeObject.TranspChargeHostDocumentUUID
  association [0..1] to I_TransportationOrderItem      as _AvrItem                   on  $projection.TransportationOrderUUID = _AvrItem.TransportationOrderUUID
                                                                                     and _AvrItem.TranspOrdItemCategory      = 'AVR'

  // Integration of Cost Distribution

  association [0..1] to C_FrtCostDistrRoot             as _FrtCostDistrRoot          on  $projection.TransportationOrderUUID = _FrtCostDistrRoot.TransportationOrderUUID

{
      //  Root Attributes

  key cast(TransportationOrderUUID     as /scmtms/vdm_tor_db_key preserving type )                                         as TransportationOrderUUID,
      TransportationOrder                                                                                                  as FreightOrder,
      TransportationOrderCategory                                                                                          as TransportationOrderCategory,
      @ObjectModel.text.element: ['TransportationOrderTypeDesc']
      TransportationOrderType                                                                                              as TransportationOrderType,
      @Semantics.text: true
      _TransportationOrderType._Text[1:Language = $session.system_language ].TransportationOrderTypeDesc                   as TransportationOrderTypeDesc,
      TranspOrdPartnerReference                                                                                            as TranspOrdPartnerReference,
      _AvrItem.TranspOrdActvVehRscePltNmbr                                                                                 as TranspOrdActvVehRscePltNmbr,

      @ObjectModel.text.element: ['PurchasingOrganizationName']
      @Consumption.labelElement: 'PurchasingOrganizationName'
      PurchasingOrgExternalID                                                                                              as PurchasingOrgExternalID,
      PurchasingOrganization                                                                                               as PurchasingOrganization,
      @Semantics.text: true
      _PurchasingOrganization._OrganizationalUnitText[1:Language = $session.system_language].OrganizationalUnitName        as PurchasingOrganizationName,

      @ObjectModel.text.element: ['PurchasingGroupName']
      @Consumption.labelElement: 'PurchasingGroupName'
      PurchasingGroupExternalID                                                                                            as PurchasingGroupExternalID,
      PurchasingGroup                                                                                                      as PurchasingGroup,
      @Semantics.text: true
      _PurchasingGroup._OrganizationalUnitText[1:Language = $session.system_language].OrganizationalUnitName               as PurchasingGroupName,

      _PlngAndExecOrganization.OrganizationalUnitExternalID                                                                as PlngAndExecOrganization,
      _PlngAndExecGroup.OrganizationalUnitExternalID                                                                       as PlngAndExecGroup,
      @ObjectModel.text.element: ['PurgOrgCompanyCodeName']
      PurgOrgCompanyCode                                                                                                   as PurgOrgCompanyCode,
      @Semantics.text: true
      _PurchasingCompanyCode.CompanyCodeName                                                                               as PurgOrgCompanyCodeName,
      TranspOrdResponsiblePerson                                                                                           as TranspOrdResponsiblePerson,
      TransportationMode                                                                                                   as TransportationMode,

      @ObjectModel.foreignKey.association: '_CarrierParty'
      @ObjectModel.text.element: ['CarrierName']
      Carrier                                                                                                              as Carrier,
      @Semantics.text: true
      _Carrier.BusinessPartnerFullName                                                                                     as CarrierName,

      StandardCarrierAlphaCode                                                                                             as StandardCarrierAlphaCode,
      @ObjectModel.foreignKey.association: '_ShipperParty'
      Shipper                                                                                                              as Shipper,
      @ObjectModel.foreignKey.association: '_ConsigneeParty'
      Consignee                                                                                                            as Consignee,
      @ObjectModel.text.element: ['SourceLocationLabel']
      _SourceStop.LocationId                                                                                               as SourceLocation,
      @Semantics.text: true
      _SourceStop._Locationdescr.AddressObjectDescription                                                                  as SourceLocationLabel,

      @Consumption.filter.selectionType: #INTERVAL
      tstmp_to_dats(_SourceStop.TranspOrdStopPlanTranspDteTme,
                     abap_user_timezone(   $session.user,$session.client,'NULL' ) ,
                     $session.client,
                     'NULL' )                                                                                              as TranspOrdDepartureDate,

      tstmp_to_tims(_SourceStop.TranspOrdStopPlanTranspDteTme,
                     abap_user_timezone(   $session.user,$session.client,'NULL' ) ,
                     $session.client,
                     'NULL' )                                                                                              as TranspOrdDepartureTime,

      cast ( _SourceStop.TranspOrdStopPlanTranspDteTme as log_created_on preserving type )                                 as TranspOrdDepartureDateTime,

      @ObjectModel.text.element: ['DestinationLocationLabel']
      _DestinationStop.LocationId                                                                                          as DestinationLocation,
      @Semantics.text: true
      _DestinationStop._Locationdescr.AddressObjectDescription                                                             as DestinationLocationLabel,

      @Consumption.filter.selectionType: #INTERVAL
      tstmp_to_dats( _DestinationStop.TranspOrdStopPlanTranspDteTme,
                     abap_user_timezone(   $session.user,$session.client,'NULL' ) ,
                     $session.client,
                     'NULL' )                                                                                              as TranspOrdArrivalDate,
      tstmp_to_tims(_DestinationStop.TranspOrdStopPlanTranspDteTme,
                     abap_user_timezone(   $session.user,$session.client,'NULL' ) ,
                     $session.client,
                     'NULL' )                                                                                              as TranspOrdArrivalTime,

      cast ( _DestinationStop.TranspOrdStopPlanTranspDteTme  as log_created_on preserving type )                           as TranspOrdArrivalDateTime,

      //  Status

      @ObjectModel.text.element: ['TranspOrdLifeCycleStatusDesc']
      TranspOrdLifeCycleStatus                                                                                             as TranspOrdLifeCycleStatus,
      @Semantics.text: true
      _TranspOrdLifeCycleStatus._Text[1:Language = $session.system_language ].TranspOrdLifeCycleStatusDesc                 as TranspOrdLifeCycleStatusDesc,
      @ObjectModel.text.element: ['TransportationOrderExecStsDesc']
      TransportationOrderExecSts                                                                                           as TransportationOrderExecSts,
      @Semantics.text: true
      _TransportationOrderExecSts._Text[1:Language = $session.system_language ].TransportationOrderExecStsDesc             as TransportationOrderExecStsDesc,

      // Charges

      _TranspChargeObject.TransportationChargesObjUUID                                                                     as TransportationChargesObjUUID,
      @ObjectModel.text.element: ['TranspChargeCalcStatusDesc']
      _TranspChargeObject.TranspChargeCalcStatus                                                                           as TranspChargeCalcStatus,
      @Semantics.text: true
      _TranspChargeObject._TranspChargeCalcStatus._Text[1:Language = $session.system_language ].TranspChargeCalcStatusDesc as TranspChargeCalcStatusDesc,
      @ObjectModel.text.element: ['InvoicingStatusDesc']
      _TranspChargeObject.InvoicingStatus                                                                                  as InvoicingStatus,
      @Semantics.text: true
      _TranspChargeObject._InvoicingStatus._Text[1:Language = $session.system_language ].InvoicingStatusDesc               as InvoicingStatusDesc,
      @Semantics.amount.currencyCode: 'TranspChargeDocumentCurrency'
      _TranspChargeObject.TranspChrgTotalAmtInDocCrcy                                                                      as TranspChrgTotalAmtInDocCrcy,
      _TranspChargeObject.TranspChargeDocumentCurrency                                                                     as TranspChargeDocumentCurrency,

      @Semantics.amount.currencyCode: 'TranspOrdGoodsValueCrcy'
      _TranspOrdSummary.TranspOrdGoodsValueAmount                                                                          as TranspOrdGoodsValueAmount,
      _TranspOrdSummary.TranspOrdGoodsValueCrcy                                                                            as TranspOrdGoodsValueCrcy,

      TranspOrdGrossWeightUnit                                                                                             as TranspOrdGrossWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdGrossWeightUnit'
      cast(TranspOrdGrossWeight         as /scmtms/quantity_13_3 )                                                         as TranspOrdGrossWeight,

      TranspOrdGrossVolumeUnit                                                                                             as TranspOrdGrossVolumeUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdGrossVolumeUnit'
      cast(TranspOrdGrossVolume         as /scmtms/quantity_13_3 )                                                         as TranspOrdGrossVolume,

      TranspOrdQuantityUnit                                                                                                as TranspOrdQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdQuantityUnit'
      cast(TranspOrdQuantity            as /scmtms/quantity_13_3 )                                                         as TranspOrdQuantity,

      TranspOrdDistanceUnit                                                                                                as DisplayLengthUnit,
      @Semantics.quantity.unitOfMeasure: 'DisplayLengthUnit'
      cast(TranspOrdDistance            as /scmtms/quantity_13_3 )                                                         as TranspOrdDistanceInDspUnit,

      @ObjectModel.text.element: ['TranspOrdEventCodeDesc']
      _LastReportedEvent.TranspOrdEventCode                                                                                as TranspOrdEventCode,
      @Semantics.text: true
      _LastReportedEvent._TranspOrdEventCode._Text[1:Language = $session.system_language ].TranspOrdEventCodeDesc          as TranspOrdEventCodeDesc,

      // Delivery count calculation

      concat(
            concat( cast(_DeliveryRatio.TranspOrderNmbrOfItmWthDeliv as abap.char( 100 )), '/'),
                    cast(_DeliveryRatio.TranspOrderNmbrOfDelivRlvtItm as abap.char( 100 ))  )                              as TranspOrdDelivCrtnPrgrsRatio,

      case
      //        when _DeliveryRatio.TranspOrderNmbrOfDelivRlvtItm is initial then _DeliveryRatio.TranspOrderNmbrOfDelivRlvtItm

        when _DeliveryRatio.TranspOrderNmbrOfDelivRlvtItm = 0 or _DeliveryRatio.TranspOrderNmbrOfDelivRlvtItm is null then 0
        else ( division(_DeliveryRatio.TranspOrderNmbrOfItmWthDeliv * 100, _DeliveryRatio.TranspOrderNmbrOfDelivRlvtItm, 2) )
      end                                                                                                                  as TranspOrdDelivCrtnPrgrsPct,

      _LastReportedCheckOutEvent.TransportationOrderEventUUID                                                              as TranspOrdLastCheckOutUUID,

      _LastReportedCheckOutEvent.TranspOrdEvtActualDateTime                                                                as TranspOrdEvtActualDateTime,

      @Semantics.text: true
      _LastReportedCheckOutEvent._TransportationOrderStop._Locationdescr.AddressObjectDescription                          as TranspOrdLastCheckOutLocDesc,

      // Integration of Cost Distribution

      _FrtCostDistrRoot.FrtCostDistrRootUUID                                                                               as FrtCostDistrRootUUID,
      @ObjectModel.text.element: ['FrtCostDistrStatusTxt']
      _FrtCostDistrRoot.FrtCostDistrStatus                                                                                 as FrtCostDistrStatus,
      @Semantics.text: true
      _FrtCostDistrRoot._DistrStatus._Text[1: Language = $session.system_language].FrtCostDistrStatusTxt                   as FrtCostDistrStatusTxt,

      /* Associations */
      @Consumption.filter.hidden: true
      _PurchasingOrganization,
      @Consumption.filter.hidden: true
      _PurchasingGroup,
      @Consumption.filter.hidden: true
      _TransportationOrderType,
      @Consumption.filter.hidden: true
      _TransportationOrderCategory,
      @Consumption.filter.hidden: true
      _TransportationMode,
      @Consumption.filter.hidden: true
      _DeliveryRatio,
      @Consumption.filter.hidden: true
      _ConsigneeParty,
      @Consumption.filter.hidden: true
      _ConsigneePartyVH,
      @Consumption.filter.hidden: true
      _ShipperParty,
      @Consumption.filter.hidden: true
      _ShipperPartyVH,
      @Consumption.filter.hidden: true
      _CarrierParty,
      @Consumption.filter.hidden: true
      _CarrierPartyVH,
      @Consumption.filter.hidden: true
      _TranspOrdLifeCycleStatus,
      @Consumption.filter.hidden: true
      _TransportationOrderExecSts,
      @Consumption.filter.hidden: true
      _TranspChargeObject,
      @Consumption.filter.hidden: true
      _TranspChargeObject._TranspChargeCalcStatus,
      @Consumption.filter.hidden: true
      _TranspChargeObject._InvoicingStatus,
      @Consumption.filter.hidden: true
      _TranspChargeObject._TranspChargeDocumentCurrency,
      @Consumption.filter.hidden: true
      _TranspOrdGrossWeightUnit,
      @Consumption.filter.hidden: true
      _TranspOrdGrossVolumeUnit,
      @Consumption.filter.hidden: true
      _TranspOrdQuantityUnit,
      @Consumption.filter.hidden: true
      _PurchasingCompanyCode,
      @Consumption.filter.hidden: true
      _LastReportedEvent,
      @Consumption.filter.hidden: true
      _LastReportedEvent._TranspOrdEventCode,
      _LastReportedCheckOutEvent,
      @Consumption.filter.hidden: true
      _FrtCostDistrRoot._DistrStatus,
      @Consumption.filter.hidden: true
      _FrtCostDistrRoot,
      @Consumption.filter.hidden: true
      _SourceStop,
      @Consumption.filter.hidden: true
      _DestinationStop,
      @Consumption.filter.hidden: true
      _FreightOrderVH

}
where
      TransportationOrderCategory =  'TO' // /SCMTMS/IF_TOR_CONST=>SC_TOR_CATEGORY-ACTIVE

  and TransportationOrder         is not initial
  and TranspOrdLifeCycleStatus    <> '10' // /SCMTMS/IF_TOR_STATUS_C=>sc_root-lifecycle-v_canceled

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_FRTCOSTDISTRROOT",
"I_BUSINESSPARTNER",
"I_COMPANYCODE",
"I_FRTCOSTDISTRSTATUS",
"I_FRTCOSTDISTRSTATUSTEXT",
"I_INVOICINGSTATUS",
"I_INVOICINGSTATUSTEXT",
"I_TMLOCATIONDESCRIPTION",
"I_TRANSPCHARGECALCSTATUS",
"I_TRANSPCHARGECALCSTATUSTEXT",
"I_TRANSPCHARGEOBJECT",
"I_TRANSPORDDELIVERYRATIO",
"I_TRANSPORDEVENTCODE",
"I_TRANSPORDEVENTCODETEXT",
"I_TRANSPORDLASTRPTDCHECKOUTEVT",
"I_TRANSPORDLASTRPTDEVENT",
"I_TRANSPORDLIFECYCLESTATUS",
"I_TRANSPORDLIFECYCLESTATUSTEXT",
"I_TRANSPORGANIZATIONALUNIT",
"I_TRANSPORGANIZATIONALUNITTEXT",
"I_TRANSPORTATIONORDER",
"I_TRANSPORTATIONORDEREXECSTS",
"I_TRANSPORTATIONORDEREXECSTST",
"I_TRANSPORTATIONORDERITEM",
"I_TRANSPORTATIONORDERSMMRY",
"I_TRANSPORTATIONORDERSTOP",
"I_TRANSPORTATIONORDERTYPE",
"I_TRANSPORTATIONORDERTYPETEXT"
],
"ASSOCIATED":
[
"C_FRTCOSTDISTRROOT",
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNERVH",
"I_COMPANYCODE",
"I_CURRENCY",
"I_FREIGHTORDERVH",
"I_FRTCOSTDISTRSTATUS",
"I_INVOICINGSTATUS",
"I_TRANSPCHARGECALCSTATUS",
"I_TRANSPCHARGEOBJECT",
"I_TRANSPORDDELIVERYRATIO",
"I_TRANSPORDEVENTCODE",
"I_TRANSPORDLASTRPTDCHECKOUTEVT",
"I_TRANSPORDLASTRPTDEVENT",
"I_TRANSPORDLIFECYCLESTATUS",
"I_TRANSPORGANIZATIONALUNIT",
"I_TRANSPORTATIONMODE",
"I_TRANSPORTATIONORDERCATEGORY",
"I_TRANSPORTATIONORDEREXECSTS",
"I_TRANSPORTATIONORDERSTOP",
"I_TRANSPORTATIONORDERTYPE",
"I_UNITOFMEASURE"
],
"BASE":
[
"C_FRTCOSTDISTRROOT",
"I_TRANSPCHARGEOBJECT",
"I_TRANSPORDLASTRPTDEVENT",
"I_TRANSPORTATIONORDER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/