C_FixedAssetsForFundsMgmt

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CFASETSFORFM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Fixed Assets for Funds Management ObjP'
@UI.headerInfo: {
  typeName: 'Fixed Asset',
  typeNamePlural: 'Fixed Assets'
}
define view C_FixedAssetsForFundsMgmt
  as select distinct from I_FixedAssetAssgmt

  association [1..1] to I_CompanyCode as _CompanyCode on  I_FixedAssetAssgmt.CompanyCode = _CompanyCode.CompanyCode
  
  association [0..1] to I_Location    as _Location    on  $projection.AssetLocation = _Location.Location
                                                      and I_FixedAssetAssgmt.Plant  = _Location.Plant


{
      @EndUserText.label: 'Company Code'
  key _CompanyCode.CompanyCode,
      @Consumption.semanticObject: 'FixedAsset'
      @EndUserText.label: 'Master Fixed Asset' 
  key I_FixedAssetAssgmt.MasterFixedAsset,
      @EndUserText.label: 'Fixed Asset'
      @UI.hidden: true
  key I_FixedAssetAssgmt.FixedAsset,
      @EndUserText.label: 'Validity End Date'
  key I_FixedAssetAssgmt.ValidityEndDate,
      @EndUserText.label: 'Financial Management Area'
      @Consumption.filter.hidden: true
      _CompanyCode.FinancialManagementArea,
      
      @Semantics.text: true
      @EndUserText.label: 'Company Code Name'
      _CompanyCode.CompanyCodeName,
      @Semantics.text: true
      @Consumption.hidden: true
      cast( concat_with_space(_CompanyCode.CompanyCode, _CompanyCode.CompanyCodeName, 1) as fmis_companycodeextendedname )                         as CompanyCodeExtendedName,


     // @Consumption.semanticObject:'FixedAsset'

      @EndUserText.label: 'Fixed Asset Description'
      I_FixedAssetAssgmt._FixedAsset.FixedAssetDescription,
      @Consumption.hidden: true
      cast( concat_with_space(I_FixedAssetAssgmt.FixedAsset, I_FixedAssetAssgmt._FixedAsset.FixedAssetDescription, 1) as fmis_assetsextendedescr ) as AssetExtendedDescription,

      //Asset Class


      @EndUserText.label: 'Asset Class'
      I_FixedAssetAssgmt._FixedAsset.AssetClass,
      @Semantics.text: true
      @EndUserText.label: 'Asset Class Name'
      I_FixedAssetAssgmt._FixedAsset._AssetClass._Text[1:Language = $session.system_language].AssetClassName,
      //@Semantics.text: true

      @Consumption.hidden: true
      cast( concat_with_space(I_FixedAssetAssgmt._FixedAsset.AssetClass, I_FixedAssetAssgmt._FixedAsset._AssetClass._Text[1:Language = $session.system_language].AssetClassName, 1) as fmis_fixedasstesextendedname )
                                                                                                                                                   as FixedAssetsExtendedName,
      @Semantics.text: true
      @EndUserText.label: 'Class Description'
      @UI.hidden:true
      I_FixedAssetAssgmt._FixedAsset._AssetClass._Text[1:Language = $session.system_language].AssetClassDescription,

      //Location

      @EndUserText.label: 'Asset Location'
      I_FixedAssetAssgmt.AssetLocation,
      @EndUserText.label: 'Location Name'
      _Location.LocationName,
      @Consumption.hidden: true
      cast( concat_with_space(I_FixedAssetAssgmt.AssetLocation, _Location.LocationName, 1) as fmis_extendedlocationname )                          as ExtendedLocationName,

      // FMAA

      @EndUserText.label: 'Fund'
      I_FixedAssetAssgmt.Fund,
      @EndUserText.label: 'Funds Center'
      I_FixedAssetAssgmt.FundsCenter,
      @EndUserText.label: 'Budget Period'
      I_FixedAssetAssgmt.BudgetPeriod,
      @EndUserText.label: 'Functional Area'
      I_FixedAssetAssgmt.FunctionalArea,
      @EndUserText.label: 'Grant'
      I_FixedAssetAssgmt.GrantID,

      //Auth.

      @EndUserText.label: 'Business Area'
      I_FixedAssetAssgmt.BusinessArea,
      @EndUserText.label: 'Cost Center'
      I_FixedAssetAssgmt.CostCenter,
      @EndUserText.label: 'Plant'
      I_FixedAssetAssgmt.Plant

}









/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ASSETCLASS",
"I_ASSETCLASSTEXT",
"I_COMPANYCODE",
"I_FIXEDASSET",
"I_FIXEDASSETASSGMT",
"I_LOCATION"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_LOCATION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/