I_FIXEDASSETASSGMT

@Analytics: { technicalName: 'IFASSETASSGMT',
              dataCategory: #DIMENSION }
@EndUserText.label: 'Fixed Asset Time Dependent Data'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: { representativeKey: 'FixedAsset',
                usageType.serviceQuality: #A,
                usageType.sizeCategory: #XXL,
                usageType.dataClass: #MIXED,
                modelingPattern: #NONE,
                supportedCapabilities: [#ANALYTICAL_PROVIDER]
              }
@Metadata: {ignorePropagatedAnnotations: true, allowExtensions: true}

define view entity I_FixedAssetAssgmt
  as select from P_FixedAssetAssgmt

  //Association with Asset Master Reference

  association [1..1] to I_FixedAsset             as _FixedAsset             on  $projection.CompanyCode      = _FixedAsset.CompanyCode
                                                                            and $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset
                                                                            and $projection.FixedAsset       = _FixedAsset.FixedAsset

  association [0..1] to I_CompanyCode            as _CompanyCode            on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_MasterFixedAsset       as _MasterFixedAsset       on  $projection.CompanyCode      = _MasterFixedAsset.CompanyCode
                                                                            and $projection.MasterFixedAsset = _MasterFixedAsset.MasterFixedAsset
  association [0..*] to I_CostCenter             as _CostCenter             on  $projection.CostCenter      = _CostCenter.CostCenter
                                                                            and $projection.ControllingArea = _CostCenter.ControllingArea
  association [0..*] to I_CostCenter             as _ResponsibleCostCenter  on  $projection.ResponsibleCostCenter = _ResponsibleCostCenter.CostCenter
                                                                            and $projection.ControllingArea       = _ResponsibleCostCenter.ControllingArea
  association [0..*] to I_CostCenterActivityType as _CostCenterActivityType on  $projection.CostCtrActivityType = _CostCenterActivityType.CostCtrActivityType
                                                                            and $projection.ControllingArea     = _CostCenterActivityType.ControllingArea
  association [0..1] to I_Plant                  as _Plant                  on  $projection.Plant = _Plant.Plant
  association [0..1] to I_BusinessArea           as _BusinessArea           on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..1] to I_InternalOrder          as _InternalOrder          on  $projection.InternalOrder = _InternalOrder.InternalOrder
  association [0..1] to I_MaintenanceOrder       as _MaintenanceOrder       on  $projection.MaintenanceOrder = _MaintenanceOrder.MaintenanceOrder
  association [0..*] to I_ProfitCenter           as _ProfitCenter           on  $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
                                                                            and $projection.ControllingArea = _ProfitCenter.ControllingArea
  association [0..1] to I_Segment                as _Segment                on  $projection.Segment = _Segment.Segment
  association [0..1] to I_FunctionalArea         as _FunctionalArea         on  $projection.FunctionalArea = _FunctionalArea.FunctionalArea
  association [0..1] to I_ControllingArea        as _ControllingArea        on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_FunctionalLocation     as _FunctionalLocation     on  $projection.FunctionalLocation = _FunctionalLocation.FunctionalLocation
  association [0..1] to I_Location               as _AssetLocation          on  $projection.AssetLocation = _AssetLocation.Location
                                                                            and $projection.Plant         = _AssetLocation.Plant
  association [0..1] to I_Employment             as _Employment             on  $projection.PersonnelNumber = _Employment.EmploymentInternalID

  // Association to Extension View

  association [1..1] to E_FixedAssetAssgmt       as _Extension              on  $projection.CompanyCode      = _Extension.CompanyCode
                                                                            and $projection.MasterFixedAsset = _Extension.MasterFixedAsset
                                                                            and $projection.FixedAsset       = _Extension.FixedAsset
                                                                            and $projection.ValidityEndDate  = _Extension.ValidityEndDate
{
      //Key Fields

      @ObjectModel.foreignKey.association: '_CompanyCode'
  key CompanyCode,
      @ObjectModel.foreignKey.association: '_MasterFixedAsset'
  key MasterFixedAsset,

  key FixedAsset,
      @Semantics.businessDate.to: true
  key ValidityEndDate,

      @ObjectModel.foreignKey.association: '_ControllingArea'
      ControllingArea,

      //Relevant Fields

      @Semantics.businessDate.from: true
      ValidityStartDate,
      VehicleLicensePlateNumber,
      @ObjectModel.foreignKey.association: '_CostCenter'
      CostCenter,
      @ObjectModel.foreignKey.association: '_Plant'
      Plant,
      @ObjectModel.foreignKey.association: '_BusinessArea'
      @VDM.lifecycle: {status: #DEPRECATED}
      BusinessArea,
      @ObjectModel.foreignKey.association: '_AssetLocation'
      AssetLocation,
      Room,
      @ObjectModel.foreignKey.association: '_CostCenterActivityType'
      CostCtrActivityType,
      @ObjectModel.foreignKey.association: '_InternalOrder'
      InternalOrder,
      @VDM.lifecycle: {status: #DEPRECATED}
      IsShutDown, //Works in OP only, hence deprecated in cloud with CE1911, moved to I_AssetTimeBasedValuation.IsShutDown

      @ObjectModel.foreignKey.association: '_ResponsibleCostCenter'
      ResponsibleCostCenter,
      @ObjectModel.foreignKey.association: '_Employment'
      PersonnelNumber,
      @ObjectModel.foreignKey.association: '_MaintenanceOrder'
      @VDM.lifecycle: {status: #DEPRECATED}
      MaintenanceOrder,
      TaxJurisdiction,
      Fund,
      WBSElementInternalID_2,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:    'WBSElementInternalID_2'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'WBSElementInternalID_2'
      WBSElementInternalID,
      REInternalFinNumber,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:    'REInternalFinNumber'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'REInternalFinNumber'
      RealEstateObject,
      @ObjectModel.foreignKey.association: '_ProfitCenter'
      ProfitCenter,
      @ObjectModel.foreignKey.association: '_Segment'
      Segment,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      FunctionalArea,
      @VDM.lifecycle: {status: #DEPRECATED}
      ShiftOperationFactor, //Works in OP only, hence deprecated in cloud with CE1911, moved to I_AssetTimeBasedValuation.ShiftOperationFactor

      GrantID,
      BudgetPeriod,
      FundsCenter,
      @ObjectModel.foreignKey.association: '_FunctionalLocation'
      @VDM.lifecycle: {status: #DEPRECATED}
      FunctionalLocation, //Works in OP only, hence deprecated in cloud with CE1911, no longer available

      BusinessPlace,
      @Consumption.hidden: true
      AssetAuthorizationContext, //Needed for DCL

      ReferenceDocumentType,
      LogicalSystem,
      ReferenceDocumentContext,
      ReferenceDocument,

      // Define association to parent

      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _FixedAsset,
      _CompanyCode,
      _MasterFixedAsset,
      _CostCenter,
      _ResponsibleCostCenter,
      _CostCenterActivityType,
      _Plant,
      _BusinessArea,
      _InternalOrder,
      @VDM.lifecycle: {status: #DEPRECATED}
      _MaintenanceOrder,
      _ProfitCenter,
      _Segment,
      _FunctionalArea,
      _ControllingArea,
      _FunctionalLocation,
      _AssetLocation,
      _Employment
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_FIXEDASSETASSGMT"
],
"ASSOCIATED":
[
"I_BUSINESSAREA",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_COSTCENTERACTIVITYTYPE",
"I_EMPLOYMENT",
"I_FIXEDASSET",
"I_FUNCTIONALAREA",
"I_FUNCTIONALLOCATION",
"I_INTERNALORDER",
"I_LOCATION",
"I_MAINTENANCEORDER",
"I_MASTERFIXEDASSET",
"I_PLANT",
"I_PROFITCENTER",
"I_SEGMENT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/