C_DspDocFlwSuplrInvcVH

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@VDM.viewType: #CONSUMPTION
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Supplier Invoices VH for DDF'
@Search.searchable: true
@Consumption.ranked: true
define view entity C_DspDocFlwSuplrInvcVH
  as select from I_SupplierInvoice

{
      @UI.selectionField: [ {position: 10 }]
      @UI.lineItem: [ {position: 10 }]
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.9 }
  key SupplierInvoice,
      @UI.selectionField: [ {position: 15 }]
      @UI.lineItem: [ {position: 15 }]
      @Search: { defaultSearchElement: true, ranking: #LOW }
  key FiscalYear,
      @UI.selectionField: [ {position: 20 }]
      @UI.lineItem: [ {position: 20 }]
      @Search: { defaultSearchElement: true, ranking: #LOW }
      AccountingDocumentType,
      @UI.selectionField: [ {position: 30 }]
      @UI.lineItem: [ {position: 30 }]
      @Search: { defaultSearchElement: true, ranking: #LOW }
      CompanyCode,
      @UI.selectionField: [ {position: 40 }]
      @UI.lineItem: [ {position: 40 }]
      @Search: { defaultSearchElement: true, ranking: #LOW }
      cast( CreationDate as fac_ddf_document_date preserving type )  as CreationDate,
      @ObjectModel.text.element: ['SupplierName']
      @UI.textArrangement: #TEXT_LAST
      @UI.selectionField: [ {position: 50 }]
      @UI.lineItem: [ {position: 50 }]      
      @Search: { defaultSearchElement: true, ranking: #LOW }
      I_SupplierInvoice._Supplier.Supplier,
      @UI.selectionField: [ {position: 60 }]
      @UI.lineItem: [ {position: 60 }]      
      @Semantics.text: true
      I_SupplierInvoice._Supplier.SupplierName,
      @UI.selectionField: [ {position: 70 }]
      @UI.lineItem: [ {position: 70 }]
      @Search: { defaultSearchElement: true, ranking: #LOW }
      SupplierInvoiceIDByInvcgParty,

      @UI.hidden: true
      cast( SupplierInvoice as fac_ddf_anchor_document )             as AnchorDocument,
      @UI.hidden: true
      cast( 'BUS2081' as swo_objtyp)                                 as ReferenceDocumentType,
      
      @Consumption.hidden: true
      IsEndOfPurposeBlocked            
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SUPPLIER",
"I_SUPPLIERINVOICE"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/