I_SUPPLIERINVOICE
Supplier Invoice
I_SUPPLIERINVOICE is a CDS View in S/4HANA. Supplier Invoice. It contains 45 fields. 39 CDS views read from this table.
CDS Views using this table (39)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| A_SupplierInvoice | view | from | CONSUMPTION | Header Data |
| C_APProcessFlowSupplierInvoice | view | union_all | CONSUMPTION | AP Process Flow Supplier Invoice |
| C_BSOrdProcFlwSuplrInvc | view | from | CONSUMPTION | Supplier Invoice Attrib for BSOrd Prgrs |
| C_BSQPMSupplierInvoice | view_entity | from | CONSUMPTION | BSQ Progress Monitor Supplier Invoice |
| C_CN_TaxInvcSuplrInvcRef | view | from | CONSUMPTION | VAT Invoice Supplier Invoice Reference |
| C_DspDocFlwSuplrInvcAttrib | view | from | CONSUMPTION | Supplier Invoices Attributes for DDF |
| C_DspDocFlwSuplrInvcVH | view_entity | from | CONSUMPTION | Supplier Invoices VH for DDF |
| C_PurgDocSuplrInvcSts | view | from | CONSUMPTION | Status of a Supplier Invoice |
| C_SameUsrCrteSuplrProcInvc | view | from | CONSUMPTION | Same User Create Supplier Manage Invoice |
| C_SSPSupplierInvoice | view | from | CONSUMPTION | Self Service Procurement Supplier Invoice Document |
| C_SuplrInvcBlkdSitn | view | from | CONSUMPTION | Situation for Blocked Supplier Invoices |
| ESH_N_INC_INVOICE | view | from | ||
| I_APProcessFlowDocumentVH | view | union | COMPOSITE | Document Number |
| I_CFinSupplierInvoice | view | union_all | COMPOSITE | CFin Supplier Invoice: Header |
| I_MpProcHistoryInvoiceStatus | view | from | BASIC | Procurement History Invoice Status |
| I_PT_SAFTSelfBillgSuplrInvcHdr | view | inner | COMPOSITE | SAF-T PT Self-Billing SupplierInv Header |
| I_SuplrInvcItemLogsUnion | view | inner | BASIC | SI Item union of batch and online items |
| I_SupplierInvoiceAccountAssgmt | view | inner | BASIC | Supplier Invoice Account Assignments |
| I_SupplierInvoiceAPI01 | view | from | BASIC | Supplier Invoice |
| I_SupplierInvoiceEnh | view | from | COMPOSITE | Supplier Invoice Enhanced |
| I_SupplierInvoiceStsAndOrign | view | from | COMPOSITE | Supplier Invoice Status and Origin Determination |
| I_SupplierInvoiceTaskUI | view | from | COMPOSITE | Supplier Invoice General Header Data |
| I_TaxItemProcessFlow | view_entity | inner | COMPOSITE | Tax Item Process Flow |
| N_SupplierInvoiceItemPurOrdRef | view | inner | Search Model Supplier Invoice Item Purchase Order Reference | |
| P_APProcessFlowSupplierInvoice | view | from | COMPOSITE | |
| P_HU_MMInvoice | view | from | COMPOSITE | |
| P_ImportSupplierInvoice | view | inner | BASIC | |
| P_InbDelivProcFlowChildren | view | inner | COMPOSITE | Inbound Delivery Process Flow Successors |
| P_InvoicesCreatedBeforePO | view | inner | CONSUMPTION | |
| P_InvoicesCreatedBeforePO1 | view | inner | CONSUMPTION | |
| P_InvoicesCreatedBeforePO2 | view | inner | CONSUMPTION | |
| P_RU_PurchaseOrderHistoryIR | view | inner | CONSUMPTION | |
| P_RU_ReltdSupplierInvoiceItem1 | view | inner | CONSUMPTION | |
| P_SupInvToAccDoc | view | from | CONSUMPTION | Supplier Invoice to Accounting Document |
| P_SuplrInvcItm | view | inner | CONSUMPTION | Supplier Invoice Item Details |
| P_SuplrInvcItmOverview | view | inner | CONSUMPTION | Supplier Invoice Item Overview |
| P_SupplierInvoiceForAutomation | view | from | CONSUMPTION | Supplier Invoice For Automation |
| P_SupplierInvoiceTaxMerge | view | from | BASIC | |
| R_SupplierInvoiceTP | view_entity | from | TRANSACTIONAL | RAP based Supplier Invoice |
Fields (45)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | FiscalYear | FiscalYear,InvoiceReferenceFiscalYear | 9 |
| KEY | SupplierInvoice | MaterialDocument,ProcessFlowNodeDocument,SupplierInvoice,UI5NetworkGraphAttributeValue | 9 |
| _CompanyCode | _CompanyCode | 2 | |
| _Supplier | _Supplier | 2 | |
| AccountingDocumentType | AccountingDocumentType | 1 | |
| AssignmentReference | AssignmentReference | 1 | |
| BusinessNetworkOrigin | BusinessNetworkOrigin | 1 | |
| BusinessPlace | BusinessPlace | 1 | |
| CashDiscount1Days | CashDiscount1Days | 2 | |
| CashDiscount1Percent | CashDiscount1Percent | 2 | |
| CashDiscount2Days | CashDiscount2Days | 2 | |
| CashDiscount2Percent | CashDiscount2Percent | 2 | |
| CompanyCode | CompanyCode | 10 | |
| CreatedByUser | CreatedByUser | 2 | |
| CreationDate | AccountingDocumentCreationDate,CreationDate | 2 | |
| DocumentCurrency | DocumentCurrency | 6 | |
| DocumentDate | DocumentDate,InvoiceDate | 5 | |
| DocumentHeaderText | DocumentHeaderText | 1 | |
| DueCalculationBaseDate | DueCalculationBaseDate | 2 | |
| FixedCashDiscount | FixedCashDiscount | 1 | |
| InvoiceGrossAmount | InvoiceGrossAmount | 3 | |
| InvoiceReceiptDate | InvoiceReceiptDate | 1 | |
| InvoiceReference | InvoiceReference | 1 | |
| InvoiceReferenceFiscalYear | InvoiceReferenceFiscalYear | 1 | |
| InvoicingParty | InvoicingParty,RelatedSupplier,Supplier | 7 | |
| IsEndOfPurposeBlocked | IsEndOfPurposeBlocked | 7 | |
| LastChangedByUser | LastChangedByUser | 1 | |
| ManualCashDiscount | ManualCashDiscount | 1 | |
| NetPaymentDays | NetPaymentDays | 1 | |
| PaymentBlockingReason | PaymentBlockingReason | 2 | |
| PaymentMethod | PaymentMethod | 1 | |
| PaymentReference | PaymentReference | 1 | |
| PaymentTerms | PaymentTerms | 2 | |
| PaytSlipWthRefCheckDigit | PaytSlipWthRefCheckDigit | 1 | |
| PaytSlipWthRefReference | PaytSlipWthRefReference | 1 | |
| PaytSlipWthRefSubscriber | PaytSlipWthRefSubscriber | 1 | |
| PostingDate | PostingDate | 5 | |
| SupplierInvoiceIDByInvcgParty | SupplierInvoiceIDByInvcgParty | 2 | |
| SupplierInvoiceOrigin | SupplierInvoiceOrigin | 1 | |
| SupplierInvoiceStatus | InvoiceListStatus,SupplierInvoiceStatus | 4 | |
| SupplierInvoiceUUID | RootDraftKey | 1 | |
| SupplierPostingLineItemText | SupplierPostingLineItemText | 1 | |
| UnplannedDeliveryCost | UnplannedDeliveryCost | 1 | |
| UnplannedDeliveryCostTaxCode | UnplannedDeliveryCostTaxCode | 1 | |
| UnplndDelivCostTaxJurisdiction | UnplndDelivCostTaxJurisdiction | 1 |
@EndUserText.label: 'Supplier Invoice'
@VDM.viewType : #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AbapCatalog.sqlViewName: 'ISUPPLIERINVOICE'
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: [ '_CreatedByUser' ]
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.modelCategory: #BUSINESS_OBJECT
@ObjectModel.compositionRoot:true
@ObjectModel.representativeKey: 'SupplierInvoice'
@ObjectModel.uniqueIdField: 'SupplierInvoiceUUID'
@ObjectModel.semanticKey:['SupplierInvoice', 'FiscalYear']
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
define view I_SupplierInvoice
as select from rbkp
association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_SupplierInvoiceFiscalYear as _FiscalYear on $projection.FiscalYear = _FiscalYear.FiscalYear
association [0..1] to I_User as _CreatedByUser on $projection.CreatedByUser = _CreatedByUser.UserID
association [0..1] to I_Supplier as _Supplier on $projection.InvoicingParty = _Supplier.Supplier
association [0..1] to I_Currency as _Currency on $projection.DocumentCurrency = _Currency.Currency
association [0..1] to I_PaymentTerms as _PaymentTerms on $projection.PaymentTerms = _PaymentTerms.PaymentTerms
association [0..*] to I_SupplierInvoiceBlock as _BlockingRecord on $projection.SupplierInvoice = _BlockingRecord.SupplierInvoice
and $projection.FiscalYear = _BlockingRecord.FiscalYear
association [0..*] to I_SupplierInvoiceItemPurOrdRef as _SupplierInvoiceItemPurOrdRef on $projection.SupplierInvoice = _SupplierInvoiceItemPurOrdRef.SupplierInvoice
and $projection.FiscalYear = _SupplierInvoiceItemPurOrdRef.FiscalYear
association [0..*] to I_SuplrInvcItemConsignment as _SuplrInvcItemConsignment on $projection.SupplierInvoice = _SuplrInvcItemConsignment.SupplierInvoice
and $projection.FiscalYear = _SuplrInvcItemConsignment.FiscalYear
association [0..*] to I_SupplierInvoiceTax as _SupplierInvoiceTax on $projection.SupplierInvoice = _SupplierInvoiceTax.SupplierInvoice
and $projection.FiscalYear = _SupplierInvoiceTax.FiscalYear
association [0..*] to I_SupplierInvoiceItemGLAcct as _SupplierInvoiceItemGLAcct on $projection.SupplierInvoice = _SupplierInvoiceItemGLAcct.SupplierInvoice
and $projection.FiscalYear = _SupplierInvoiceItemGLAcct.FiscalYear
association [0..*] to I_SupplierInvoiceItemMaterial as _SupplierInvoiceItemMaterial on $projection.SupplierInvoice = _SupplierInvoiceItemMaterial.SupplierInvoice
and $projection.FiscalYear = _SupplierInvoiceItemMaterial.FiscalYear
association [0..*] to I_SupplierInvoiceItemAsset as _SupplierInvoiceItemAsset on $projection.SupplierInvoice = _SupplierInvoiceItemAsset.SupplierInvoice
and $projection.FiscalYear = _SupplierInvoiceItemAsset.FiscalYear
association [0..*] to I_SuplrInvcSeldPurgDocument as _SelectedPurchaseOrders on $projection.SupplierInvoice = _SelectedPurchaseOrders.SupplierInvoice
and $projection.FiscalYear = _SelectedPurchaseOrders.FiscalYear
association [0..*] to I_SuplrInvcSeldInbDeliveryNote as _SelectedDeliveryNotes on $projection.SupplierInvoice = _SelectedDeliveryNotes.SupplierInvoice
and $projection.FiscalYear = _SelectedDeliveryNotes.FiscalYear
association [0..*] to I_SuplrInvcSeldInbBillOfLading as _SelectedBillOfLadings on $projection.SupplierInvoice = _SelectedBillOfLadings.SupplierInvoice
and $projection.FiscalYear = _SelectedBillOfLadings.FiscalYear
association [0..*] to I_SuplrInvcSeldSrvcEntrySheet as _SelectedServiceEntrySheets on $projection.SupplierInvoice = _SelectedServiceEntrySheets.SupplierInvoice
and $projection.FiscalYear = _SelectedServiceEntrySheets.FiscalYear
association [0..*] to I_SuplrInvcSeldSrvcEntrShtLean as _SelectedServiceEntryShtLean on $projection.SupplierInvoice = _SelectedServiceEntryShtLean.SupplierInvoice
and $projection.FiscalYear = _SelectedServiceEntryShtLean.FiscalYear
association [0..*] to I_SuplrInvcHeaderWhldgTax as _WithholdingTax on $projection.SupplierInvoice = _WithholdingTax.SupplierInvoice
and $projection.FiscalYear = _WithholdingTax.FiscalYear
association [0..*] to I_SupplierInvoiceAmountSplit as _AmountSplit on $projection.SupplierInvoice = _AmountSplit.SupplierInvoice
and $projection.FiscalYear = _AmountSplit.FiscalYear
association [1..1] to I_SupplierInvoiceStatus as _SupplierInvoiceStatus on $projection.SupplierInvoiceStatus = _SupplierInvoiceStatus.SupplierInvoiceStatus
association [1..1] to I_SupplierInvoiceStsAndOrign as _SupplierInvoiceStsAndOrign on $projection.SupplierInvoice = _SupplierInvoiceStsAndOrign.SupplierInvoice
and $projection.FiscalYear = _SupplierInvoiceStsAndOrign.FiscalYear
association [0..1] to I_SupplierInvoicePrelimData as _SupplierInvoicePrelimData on $projection.SupplierInvoice = _SupplierInvoicePrelimData.SupplierInvoice
and $projection.FiscalYear = _SupplierInvoicePrelimData.FiscalYear
association [1..1] to I_SuplrInvoiceAdditionalData as _SuplrInvoiceAdditionalData on $projection.SupplierInvoice = _SuplrInvoiceAdditionalData.SupplierInvoice
and $projection.FiscalYear = _SuplrInvoiceAdditionalData.FiscalYear
association [0..1] to E_SupplierInvoice as _HeaderExtension on $projection.SupplierInvoice = _HeaderExtension.SupplierInvoice
and $projection.FiscalYear = _HeaderExtension.FiscalYear
{
key rbkp.belnr as SupplierInvoice,
@ObjectModel.foreignKey.association: '_FiscalYear'
key rbkp.gjahr as FiscalYear,
rbkp.root_key as SupplierInvoiceUUID,
@ObjectModel.foreignKey.association: '_CompanyCode'
rbkp.bukrs as CompanyCode,
@Semantics.businessDate.at: true
cast( rbkp.bldat as invdt preserving type) as DocumentDate,
@Semantics.businessDate.at: true
rbkp.budat as PostingDate,
@Semantics.businessDate.at: true
rbkp.reindat as InvoiceReceiptDate,
rbkp.xblnr as SupplierInvoiceIDByInvcgParty,
rbkp.lifnr as InvoicingParty,
@ObjectModel.foreignKey.association: '_Currency'
@Semantics.currencyCode: true
rbkp.waers as DocumentCurrency,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation:#NONE
rbkp.rmwwr as InvoiceGrossAmount,
rbkp.xrech as IsInvoice,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation:#NONE
rbkp.beznk as UnplannedDeliveryCost,
@Semantics.text: true
rbkp.bktxt as DocumentHeaderText,
@Semantics.user.createdBy: true
rbkp.erfnam as CreatedByUser,
rbkp.usnam as LastChangedByUser,
rbkp.ername as SuplrInvcExtCreatedByUser, //External user that entered the invoice
@Semantics.businessDate.createdAt: true
rbkp.cpudt as CreationDate,
@Semantics.amount.currencyCode: 'DocumentCurrency'
rbkp.wskto as ManualCashDiscount,
// Payment Terms
@ObjectModel.foreignKey.association: '_PaymentTerms'
rbkp.zterm as PaymentTerms,
@Semantics.businessDate.at:true
cast( rbkp.zfbdt as mmiv_zfbdt preserving type ) as DueCalculationBaseDate,
rbkp.zbd1p as CashDiscount1Percent,
rbkp.zbd1t as CashDiscount1Days,
rbkp.zbd2p as CashDiscount2Percent,
rbkp.zbd2t as CashDiscount2Days,
rbkp.zbd3t as NetPaymentDays,
//PaymentBlockingReason is the manually entered blocking reason in invoice header
//This field does not reflect the actual blocking status of the invoice in all cases.
//This functionality is not available.
rbkp.zlspr as PaymentBlockingReason,
rbkp.blart as AccountingDocumentType,
@ObjectModel.foreignKey.association: '_SupplierInvoiceStatus'
rbkp.rbstat as SupplierInvoiceStatus,
rbkp.ivtyp as SupplierInvoiceOrigin,
rbkp.business_network_origin as BusinessNetworkOrigin,
rbkp.stblg as ReverseDocument,
rbkp.stjah as ReverseDocumentFiscalYear,
rbkp.vgart as SuplrInvcTransactionCategory,
// Invoice Reduction
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation:#NONE
rbkp.lieffn as SuplrInvcManuallyReducedAmount,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation:#NONE
rbkp.lieffmw as SuplrInvcManualReductionTaxAmt,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation:#NONE
rbkp.arkuen as SuplrInvcAutomReducedAmount,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation:#NONE
rbkp.arkuemw as SuplrInvcAutomReductionTaxAmt,
rbkp.bvtyp as BPBankAccountInternalID,
rbkp.kursf as ExchangeRate,
rbkp.lzbkz as StateCentralBankPaymentReason,
rbkp.landl as SupplyingCountry,
rbkp.zlsch as PaymentMethod,
rbkp.uzawe as PaymentMethodSupplement,
rbkp.kidno as PaymentReference,
rbkp.rebzg as InvoiceReference,
rbkp.rebzj as InvoiceReferenceFiscalYear,
rbkp.zbfix as FixedCashDiscount,
rbkp.mwskz_bnk as UnplannedDeliveryCostTaxCode,
rbkp.txjcd_bnk as UnplndDelivCostTaxJurisdiction,
rbkp.zuonr as AssignmentReference,
cast ( rbkp.sgtxt as farp_sgtxt preserving type ) as SupplierPostingLineItemText,
rbkp.xmwst as TaxIsCalculatedAutomatically,
rbkp.bupla as BusinessPlace,
rbkp.esrnr as PaytSlipWthRefSubscriber,
rbkp.esrpz as PaytSlipWthRefCheckDigit,
rbkp.esrre as PaytSlipWthRefReference,
rbkp.iseopblocked as IsEndOfPurposeBlocked,
rbkp.secco as BusinessSectionCode,
rbkp.gsber as BusinessArea,
rbkp.logmx_uuid as ElectronicInvoiceUUID,
rbkp.txdat as TaxDeterminationDate, //Time dependent taxes
rbkp.egmld as DeliveryOfGoodsReportingCntry,
rbkp.stceg as SupplierVATRegistration,
rbkp.xegdr as IsEUTriangularDeal,
rbkp.xinve as SuplrInvcIsCapitalGoodsRelated,
@Semantics.businessDate.at: true
rbkp.vatdate as TaxReportingDate,
@Semantics.businessDate.at: true
rbkp.fulfilldate as TaxFulfillmentDate,
rbkp.tax_country as TaxCountry,
rbkp.tax_country_bnk as UnplndDeliveryCostTaxCountry,
rbkp.prepay_status as SuplrInvcPrepaymentStatus,
rbkp.payt_rsn as PaymentReason,
rbkp.hbkid as HouseBank,
rbkp.hktid as HouseBankAccount,
// Preliminary fields (parked, held, batch)
_SupplierInvoicePrelimData.SuplrInvcDebitCrdtCodeDelivery, //XRECHR
_SupplierInvoicePrelimData.SuplrInvcDebitCrdtCodeReturns, //XRECHL
_SupplierInvoicePrelimData.RetentionDueDate, //RET_DUE_PROP
//GLO fields
rbkp.glo_ref1_hd as JrnlEntryCntrySpecificRef1,
rbkp.glo_dat1_hd as JrnlEntryCntrySpecificDate1,
rbkp.glo_ref2_hd as JrnlEntryCntrySpecificRef2,
rbkp.glo_dat2_hd as JrnlEntryCntrySpecificDate2,
rbkp.glo_ref3_hd as JrnlEntryCntrySpecificRef3,
rbkp.glo_dat3_hd as JrnlEntryCntrySpecificDate3,
rbkp.glo_ref4_hd as JrnlEntryCntrySpecificRef4,
rbkp.glo_dat4_hd as JrnlEntryCntrySpecificDate4,
rbkp.glo_ref5_hd as JrnlEntryCntrySpecificRef5,
rbkp.glo_dat5_hd as JrnlEntryCntrySpecificDate5,
rbkp.glo_bp1_hd as JrnlEntryCntrySpecificBP1,
rbkp.glo_bp2_hd as JrnlEntryCntrySpecificBP2,
//Localization fields
rbkp.gst_part as IN_GSTPartner,
rbkp.plc_sup as IN_GSTPlaceOfSupply,
rbkp.irn as IN_InvoiceReferenceNumber,
/* Associations */
_CompanyCode,
_FiscalYear,
_CreatedByUser,
_Supplier,
_Currency,
_PaymentTerms,
_BlockingRecord,
_SupplierInvoiceStatus,
_SupplierInvoiceStsAndOrign,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_SupplierInvoiceItemPurOrdRef,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_SupplierInvoiceTax,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_SupplierInvoiceItemGLAcct,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_SupplierInvoiceItemMaterial,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_SupplierInvoiceItemAsset,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_SelectedPurchaseOrders,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_SelectedDeliveryNotes,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_SelectedBillOfLadings,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_SelectedServiceEntrySheets,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_SelectedServiceEntryShtLean,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_WithholdingTax,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_AmountSplit,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_SuplrInvoiceAdditionalData
}
where
(
vgart = 'RD'
or vgart = 'RP'
or vgart = 'RS'
)
and rbkp.rbstat != '2'
and rbkp.ivtyp != '9' // WEB Invoice
and rbkp.ivtyp != 'C' // Account Maintenance
and rbkp.ivtyp != 'E' // BAPI Account Maintenance
// ( rbkp.ivtyp = ' ' //Online
// or rbkp.ivtyp = '1' //ERS
// or rbkp.ivtyp = '2' //ERS Zero Document
// or rbkp.ivtyp = '3' //Batch
// or rbkp.ivtyp = '4' //EDI
// or rbkp.ivtyp = '5' //Cancellation
// or rbkp.ivtyp = '6' //Invoicing Plan
// or rbkp.ivtyp = '7' //Transfer Prices
// or rbkp.ivtyp = '8' //Revaluation
// or rbkp.ivtyp = 'A' //Invoice from Parking Function
// or rbkp.ivtyp = 'B' //BAPI
// or rbkp.ivtyp = 'D' //SRM Invoice
// or rbkp.ivtyp = 'G' //External Service (A2A)
// or rbkp.ivtyp = 'H' //SOA B2B
// or rbkp.ivtyp = 'I' //cXML
// or rbkp.ivtyp = 'J' //cXML from Parking Function
// or rbkp.ivtyp = 'K' //Consignment
// or rbkp.ivtyp = 'L' ) //Recurring Supplier Invoice
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SUPPLIERINVOICEPRELIMDATA",
"RBKP"
],
"ASSOCIATED":
[
"E_SUPPLIERINVOICE",
"I_COMPANYCODE",
"I_CURRENCY",
"I_PAYMENTTERMS",
"I_SUPLRINVCHEADERWHLDGTAX",
"I_SUPLRINVCITEMCONSIGNMENT",
"I_SUPLRINVCSELDINBBILLOFLADING",
"I_SUPLRINVCSELDINBDELIVERYNOTE",
"I_SUPLRINVCSELDPURGDOCUMENT",
"I_SUPLRINVCSELDSRVCENTRSHTLEAN",
"I_SUPLRINVCSELDSRVCENTRYSHEET",
"I_SUPLRINVOICEADDITIONALDATA",
"I_SUPPLIER",
"I_SUPPLIERINVOICEAMOUNTSPLIT",
"I_SUPPLIERINVOICEBLOCK",
"I_SUPPLIERINVOICEFISCALYEAR",
"I_SUPPLIERINVOICEITEMASSET",
"I_SUPPLIERINVOICEITEMGLACCT",
"I_SUPPLIERINVOICEITEMMATERIAL",
"I_SUPPLIERINVOICEITEMPURORDREF",
"I_SUPPLIERINVOICEPRELIMDATA",
"I_SUPPLIERINVOICESTATUS",
"I_SUPPLIERINVOICESTSANDORIGN",
"I_SUPPLIERINVOICETAX",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/