C_CustomerReturnRefDocItem

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Return Reference Document Item'
@VDM.viewType: #CONSUMPTION
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #NOT_REQUIRED
}
@AbapCatalog: {
  sqlViewName: 'CSDCUSTRETREFITM',
  preserveKey: true,
  compiler.compareFilter: true
}
@ObjectModel: {
   updateEnabled,
   //semanticKey: ['CustomerReturn'],

   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #C,
     sizeCategory:   #XXL
   }
}
@Search.searchable: true
@Metadata.ignorePropagatedAnnotations: true

define view C_CustomerReturnRefDocItem
  as select from C_ReturnsReferenceDocumentItem as ReturnRefDocItem
    inner join   C_CustomerReturnRefDoc         as CustomerReturnRefDoc on CustomerReturnRefDoc.ReferenceSDDocument = ReturnRefDocItem.ReturnsReferenceDocument                                       
    
    association [0..1] to I_Product                      as _Product                        on  $projection.Material            = _Product.Product
    association [0..1] to I_ProductPlant                 as _ProductPlant                   on  $projection.Material            = _ProductPlant.Product
                                                                                           and  $projection.ProductionPlant     = _ProductPlant.Plant
    association [0..1] to P_CustRetItemScheduleLine     as _ScheduleLine                    on  $projection.ReturnsReferenceDocument      = _ScheduleLine.SalesDocument
                                                                                           and $projection.ReturnsReferenceDocumentItem   = _ScheduleLine.SalesDocumentItem
{
  key CustomerReturnRefDoc.CustomerReturn,
      @Search.defaultSearchElement: true 
      @EndUserText.label: 'Reference Document'
  key ReturnRefDocItem.ReturnsReferenceDocument,
      @EndUserText.label: 'Item'
  key ReturnRefDocItem.ReturnsReferenceDocumentItem,
      @UI.hidden: true
      ReturnRefDocItem.TargetSalesDocumentType, 
  

      ReturnRefDocItem.HigherLevelItem,
      
      @UI.hidden: true
      ReturnRefDocItem.SalesDocument,
      @UI.hidden: true
      ReturnRefDocItem.SalesDocumentItem,

      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      ReturnRefDocItem.OrderQuantity,
      @Search.defaultSearchElement: true

      @ObjectModel.text.association: '_MaterialText'
      ReturnRefDocItem.Material,
      @ObjectModel.text.association: '_MaterialGroupText'
      ReturnRefDocItem.MaterialGroup,

      @Semantics.amount.currencyCode: 'Currency'
      ReturnRefDocItem.NetAmount,
      @Semantics.currencyCode: true
      ReturnRefDocItem.Currency,
      @Consumption.valueHelp: '_ProductAlternativeUoM'
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_QuantityUnitValueHelp'
      ReturnRefDocItem.OrderQuantityUnit,
      @EndUserText.label: 'Document Category'
      @ObjectModel.text.association: '_SDDocumentCategoryText'
      ReturnRefDocItem.SDDocumentCategory,

      @ObjectModel.text.element:  [ 'PlantName' ]
      ReturnRefDocItem.ProductionPlant,
      @Semantics.text: true
      ReturnRefDocItem.PlantName,

      ReturnRefDocItem.Batch,
      @UI.hidden: true
      _Product.IsBatchManagementRequired as IsBatchManagementRequired,
      
      ReturnRefDocItem.DeliveryDate,

      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      ReturnRefDocItem.ReturnableQuantity,

      ReturnRefDocItem.MaterialByCustomer,

      @Semantics.unitOfMeasure: true
      ReturnRefDocItem.ReturnQuantityUnit,

      @Semantics.quantity.unitOfMeasure: 'ReturnQuantityUnit'
      ReturnRefDocItem.ReturnQuantity,
      
      @ObjectModel.text.association: '_ShippingPointText'
      ReturnRefDocItem.ShippingPoint,

      ReturnRefDocItem.OrganizationDivision,
      ReturnRefDocItem.SalesOrganization,
      ReturnRefDocItem.DistributionChannel,
      @UI.hidden: true
      ReturnRefDocItem.PricingRelevance,
      @UI.hidden: true
      ReturnRefDocItem.BillOfMaterial,
      @UI.hidden: true
      ReturnRefDocItem.BOMExplosionDate,
      @ObjectModel.text.element:  [ 'SalesDocumentRjcnReasonName' ]
      ReturnRefDocItem.SalesDocumentRjcnReason,
      @UI.hidden: true
      @Search.defaultSearchElement: false
      ReturnRefDocItem.SalesDocumentRjcnReasonName,
      @UI.hidden: true
      _ProductPlant.SerialNumberProfile,
      //Associations

      ReturnRefDocItem._QuantityUnitValueHelp,
      ReturnRefDocItem._ProductAlternativeUoM,
      ReturnRefDocItem._MaterialText,
      ReturnRefDocItem._MaterialGroupText,
      ReturnRefDocItem._ShippingPointText,
      ReturnRefDocItem._SDDocumentCategoryText,
      @UI.hidden: true
      _ScheduleLine.GoodsMovementType,
      _Product,
      _ProductPlant
}

where 
    CustomerReturnRefDoc.CustomerReturnType  = ReturnRefDocItem.TargetSalesDocumentType
or  ReturnRefDocItem.TargetSalesDocumentType is null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_CUSTOMERRETURNREFDOC",
"C_RETURNSREFERENCEDOCUMENTITEM",
"I_PRODUCT",
"I_PRODUCTPLANT",
"P_CUSTRETITEMSCHEDULELINE"
],
"ASSOCIATED":
[
"I_MATERIALGROUPTEXT",
"I_MATERIALTEXT",
"I_PRODUCT",
"I_PRODUCTALTERNATIVEUOM",
"I_PRODUCTPLANT",
"I_SDDOCUMENTCATEGORYTEXT",
"I_SHIPPINGPOINTTEXT",
"I_UNITOFMEASURE",
"P_CUSTRETITEMSCHEDULELINE"
],
"BASE":
[
"C_RETURNSREFERENCEDOCUMENTITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/