C_CUSTOMERRETURNREFDOC

CDS View

Return Reference Document

C_CUSTOMERRETURNREFDOC is a CDS View in S/4HANA. Return Reference Document. It contains 1 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 1 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_CustomerReturnRefDocItem view inner CONSUMPTION Return Reference Document Item

Fields (1)

KeyField CDS FieldsUsed in Views
KEY CustomerReturn CustomerReturn 1 
@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Return Reference Document'
@VDM.viewType: #CONSUMPTION
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #NOT_REQUIRED
}
@AbapCatalog: {
  sqlViewName: 'CSDCUSTRETREFDOC',
  preserveKey: true,
  compiler.compareFilter: true
}
@ObjectModel: {
   compositionRoot: true,
   semanticKey: ['CustomerReturn'],
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #D,
     sizeCategory:   #XL
   }
}

define view C_CustomerReturnRefDoc
as select distinct from I_CustomerReturn as CustomerReturn
{
      @Consumption.semanticObject: 'CustomerReturn'
  key CustomerReturn.CustomerReturn,
  key CustomerReturn.ReferenceSDDocument,
      CustomerReturn.ReferenceSDDocumentCategory,
      @UI.hidden: true
      CustomerReturn.CustomerReturnType,
      @UI.hidden: true
      CustomerReturn.OrganizationDivision,
      @UI.hidden: true
      CustomerReturn.SalesOrganization,
      @UI.hidden: true
      CustomerReturn.DistributionChannel
}
where
  CustomerReturn.ReferenceSDDocument is not initial

union all

select distinct from I_CustomerReturn as CustomerReturn
inner join I_CustomerReturnItem as CustomerReturnItem on CustomerReturn.CustomerReturn = CustomerReturnItem.CustomerReturn

{

      @Consumption.semanticObject: 'CustomerReturn'
  key CustomerReturn.CustomerReturn,
  key CustomerReturnItem.ReferenceSDDocument,
      CustomerReturnItem.ReferenceSDDocumentCategory,
      @UI.hidden: true
      CustomerReturn.CustomerReturnType,
      @UI.hidden: true
      CustomerReturn.OrganizationDivision,
      @UI.hidden: true
      CustomerReturn.SalesOrganization,
      @UI.hidden: true
      CustomerReturn.DistributionChannel
}
where
      CustomerReturnItem.ReferenceSDDocument <> CustomerReturn.ReferenceSDDocument
  and CustomerReturnItem.ReferenceSDDocument is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTOMERRETURN",
"I_CUSTOMERRETURNITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More