C_CustomerReturnItemRefund

@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Returns Order Item Refund'
@VDM.viewType: #CONSUMPTION
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog: {
  sqlViewName: 'CCRTITMRFND',
  preserveKey: true,
  compiler.compareFilter: true,
  viewEnhancementCategory: [#PROJECTION_LIST, #UNION]
}
@ObjectModel: {
  updateEnabled,
  usageType: {
    dataClass:      #MIXED,
    serviceQuality: #C,
    sizeCategory:   #L
  }
}
@UI.presentationVariant:{
  sortOrder: [{ by: 'CustomerReturnItem' , direction: #ASC }]
}

define view C_CustomerReturnItemRefund 
 as select from P_ReturnsDocumentItemRefund as Refund

  association [0..1] to I_SalesDocumentItemCategory    as _CustRetItemCategory          on  $projection.CustomerReturnItemCategory = _CustRetItemCategory.SalesDocumentItemCategory

  association [0..*] to C_CustomerReturnRefundDetail   as _CustomerReturnRefundDetail   on  $projection.CustomerReturn     = _CustomerReturnRefundDetail.CustomerReturn
                                                                                        and $projection.CustomerReturnItem = _CustomerReturnRefundDetail.CustomerReturnItem
                                                                                        and $projection.InspectionDocument = _CustomerReturnRefundDetail.InspectionDocument

  association [0..*] to C_CreditMemoRequestItem        as _CreditMemoRequestItem        on  $projection.CustomerReturn     = _CreditMemoRequestItem.ReferenceSDDocument
                                                                                        and $projection.CustomerReturnItem = _CreditMemoRequestItem.ReferenceSDDocumentItem
                                                                                    
  association [0..*] to C_SalesOrderWithoutChargeItem  as _OrderWOCharge                on  $projection.CustomerReturn     = _OrderWOCharge.ReferenceSDDocument
                                                                                        and $projection.CustomerReturnItem = _OrderWOCharge.ReferenceSDDocumentItem
                
  association [0..*] to C_CustRetSubsqntCrdtMemo       as _CreditMemo                   on  $projection.CustomerReturn      = _CreditMemo.ReferenceSDDocument
                                                                                        and $projection.CustomerReturnItem  = _CreditMemo.ReferenceSDDocumentItem
  
  association [0..*] to I_AdvncdRetsMgmtProcExecuted   as _OutboundDeliveryOrder        on  $projection.RetsMgmtProcess     = _OutboundDeliveryOrder.RetsMgmtProcess                                                                
                                                                                        and $projection.RetsMgmtProcessItem = _OutboundDeliveryOrder.RetsMgmtProcessItem 
                                                                                        and _OutboundDeliveryOrder.ReturnsDocumentType = '18'
                                                                                                                                                       
  association [0..1] to P_RefundedQuantitySum          as _RefundedQuantity             on  $projection.CustomerReturn     = _RefundedQuantity.CustomerReturn
                                                                                        and $projection.CustomerReturnItem = _RefundedQuantity.CustomerReturnItem

  association [0..1] to P_RefundingQuantity            as _RefundingQuantity            on  $projection.CustomerReturn     = _RefundingQuantity.CustomerReturn
                                                                                        and $projection.CustomerReturnItem = _RefundingQuantity.CustomerReturnItem

  association [0..1] to I_ReturnsRefundType            as _ReturnsRefundType            on  $projection.ReturnsRefundType = _ReturnsRefundType.ReturnsRefundType

  association [0..1] to I_ReturnsRefundExtent          as _ReturnsRefundExtent          on  $projection.ReturnsRefundExtent = _ReturnsRefundExtent.ReturnsRefundExtent

  association [0..1] to I_SalesDocumentRjcnReason      as _SalesDocumentRjcnReason      on  $projection.ReturnsRefundRjcnReason = _SalesDocumentRjcnReason.SalesDocumentRjcnReason

  association [0..*] to C_CustomerReturnProductUoMVH   as _CustomerReturnProductUoMVH   on  $projection.Material = _CustomerReturnProductUoMVH.Product
  association [0..1] to I_AdvncdReturnsMgmtProcessItem as _RetsMgmtProcItmWthProcgSts   on  $projection.RetsMgmtProcess    = _RetsMgmtProcItmWthProcgSts.RetsMgmtProcess
                                                                                        and $projection.CustomerReturnItem = _RetsMgmtProcItmWthProcgSts.RetsMgmtProcessItem


  //Text association

  association [0..*] to I_MaterialText                 as _MaterialText                 on  $projection.Material = _MaterialText.Material
  association [0..*] to I_MaterialText                 as _RepMaterialText              on  $projection.ReplacementMaterial = _RepMaterialText.Material
  association [0..1] to I_Plant                        as _SupplyingPlant               on  $projection.ReplacementMatlSupplyingPlant = _SupplyingPlant.Plant
  association [0..*] to I_RetMatlInspResultCodeText    as _RetMatlInspResultCodeText    on  $projection.RetMatlInspResultCode = _RetMatlInspResultCodeText.RetMatlInspResultCode
  association [0..*] to I_ReturnsRefundExtentText      as _ReturnsRefundExtentText      on  $projection.ReturnsRefundExtent = _ReturnsRefundExtentText.ReturnsRefundExtent
  association [0..*] to I_ReturnsRefundTypeText        as _ReturnsRefundTypeText        on  $projection.ReturnsRefundType = _ReturnsRefundTypeText.ReturnsRefundType
  association [0..*] to I_SalesDocumentRjcnReasonText  as _SalesDocumentRjcnReasonT     on  $projection.ReturnsRefundRjcnReason = _SalesDocumentRjcnReasonT.SalesDocumentRjcnReason
  association [0..1] to I_SalesDocumentTypeText        as _SalesDocumentTypeText        on  $projection.CustomerReturnType  = _SalesDocumentTypeText.SalesDocumentType
                                                                                        and _SalesDocumentTypeText.Language = $session.system_language
  association [0..*] to I_FollowUpActivityText         as _FollowUpActivityText         on  $projection.CustRetItmFollowUpActivity = _FollowUpActivityText.CustRetItmFollowUpActivity
  //Extensibility

  association [0..1] to E_SalesDocumentItemBasic       as _Extension                    on  $projection.CustomerReturnItem = _Extension.SalesDocumentItem
                                                                                        and $projection.CustomerReturn     = _Extension.SalesDocument
  association [0..1] to P_CustRetItemScheduleLine     as _ScheduleLine                on  $projection.CustomerReturn     = _ScheduleLine.SalesDocument
                                                                                      and $projection.CustomerReturnItem = _ScheduleLine.SalesDocumentItem
  
{
  key cast (Refund.CustomerReturn as msr_returns_order preserving type) as CustomerReturn,

            @EndUserText.label: 'Item'
  key       Refund.CustomerReturnItem,

  key       Refund.InspectionDocument,
 
            @UI.hidden: true
            @ObjectModel.virtualElement: true
            @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CUSTOMER_RETURN_ITEM_OPG_VE'
            @ObjectModel.filter.transformedBy: 'ABAP:CL_CUSTOMER_RETURN_SADL_FILTER'
            @ObjectModel.sort.transformedBy: 'ABAP:CL_CUSTOMER_RETURN_SADL_FILTER'
            cast('' as msr_fin_status) as RetsMgmtItmCompnProcgStatus,
//            Refund.RetsMgmtItmCompnProcgStatus,


            @UI.hidden: true
            Refund.CustomerReturnItemCategory,

            @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
            Refund.OrderQuantity,

            @Semantics.unitOfMeasure: true
            Refund.OrderQuantityUnit,

            @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
//            cast(_RefundedQuantity.CustReturnItmRefundedQty as msr_rep_refunded)             as CustReturnItmRefundedQty,

            cast(0 as msr_rep_refunded)             as CustReturnItmRefundedQty,

//            case when _RefundingQuantity.CustReturnItmOpenRefundQty <= 0

//            then 'X'

//            else ''

//            end                                                                              as CustReturnItmIsCmpltlyRefunded,

            cast('' as char1)                as CustReturnItmIsCmpltlyRefunded,

            @EndUserText.label: 'Planned Refund Quantity'
            @EndUserText.quickInfo: 'Planned Refund Quantity'
            @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
//            cast(case when _RefundingQuantity.CustReturnItmOpenRefundQty <= 0

//            then 0

//            else _RefundingQuantity.CustReturnItmOpenRefundQty

//            end  as refunding_quantity)                                                      as CustReturnItmOpenRefundQty,

            cast(0 as refunding_quantity)           as CustReturnItmOpenRefundQty,

            @Consumption.valueHelp: '_ReturnsRefundExtent'
            @ObjectModel.text.association: '_ReturnsRefundExtentText'
            Refund.ReturnsRefundExtent,

            @Consumption.valueHelp: '_ReturnsRefundType'
            @ObjectModel.text.association: '_ReturnsRefundTypeText'
            Refund.ReturnsRefundType,

            Refund.HigherLevelItem,

            @UI.hidden: true
            Refund.RetsMgmtProcessStep,

            @UI.hidden: true
            Refund.RetsMgmtProcess,

            @UI.hidden: true
            Refund.RetsMgmtProcessItem,

            @UI.hidden: true
            _CustRetItemCategory.BillingRelevanceCode,

            Refund.ReturnsRefundProcgMode,

            @ObjectModel.text.association: '_MaterialText'
            Refund.Material,

            @Consumption.valueHelp: '_SalesDocumentRjcnReason'
            @ObjectModel.text.association: '_SalesDocumentRjcnReasonT'
            Refund.ReturnsRefundRjcnReason,

            @Semantics.amount.currencyCode: 'TransactionCurrency'
            Refund.NetAmount,

            @Semantics.currencyCode: true
            Refund.TransactionCurrency,

            @ObjectModel.text.association: '_RetMatlInspResultCodeText'
            Refund.RetMatlInspResultCode,

            @UI.hidden: true
            Refund.SalesOrganization,

            @UI.hidden: true
            Refund.DistributionChannel,

            @UI.hidden: true
            Refund.OrganizationDivision,

            @UI.hidden: true
            @ObjectModel.text.association: '_SalesDocumentTypeText'
            Refund.CustomerReturnType,

            @UI.hidden: true
            Refund.Plant,

            Refund.Batch,

            @UI.hidden: true
            cast( $session.system_language as spras )                                        as Language,
            @Consumption.valueHelpDefinition: [
             { entity: { name: 'C_CustomerReturnProductVH',
                         element: 'Product' },
               additionalBinding: [{ element: 'Language',
                                     localElement: 'Language'},
                                   { element: 'Plant',
                                     localElement: 'ReplacementMatlSupplyingPlant',
                                     usage: #FILTER_AND_RESULT }]
             }]
            @ObjectModel.mandatory: true
            @ObjectModel.text.association: '_RepMaterialText'
            Refund.ReplacementMaterial,

            @EndUserText.label: 'Replacement Quantity'
            @ObjectModel.mandatory: true
            @Semantics.quantity.unitOfMeasure: 'ReplacementMaterialQtyUnit'
//            cast(case when _RefundingQuantity.CustReturnItmOpenRefundQty <= 0

//            then 0

//            else _RefundingQuantity.CustReturnItmOpenRefundQty  end  as refunding_quantity ) as ReplacementMaterialQuantity,

            cast(0 as refunding_quantity)           as ReplacementMaterialQuantity,

            @Semantics.unitOfMeasure: true
            @Consumption.valueHelpDefinition: [
             { entity:  { name:    'C_CustomerReturnProductUoMVH',
                          element: 'AlternativeUnit' },
               additionalBinding: [{ element: 'Product',
                                     localElement: 'ReplacementMaterial',
                                     usage: #FILTER_AND_RESULT }]
             }]
            @ObjectModel.mandatory: true
            Refund.ReplacementMaterialQtyUnit,

            @Consumption.valueHelpDefinition: [
             { entity:  { name:    'C_CustomerReturnPlantVH',
                          element: 'Plant' },
               additionalBinding: [{ element: 'Product',
                                     localElement: 'ReplacementMaterial' ,
                                     usage: #FILTER_AND_RESULT}]
             }]
            @ObjectModel.mandatory: true
            @ObjectModel.text.association: '_SupplyingPlant'
            Refund.ReplacementMatlSupplyingPlant,

            Refund.BillOfMaterial,

            @ObjectModel.text.association: '_FollowUpActivityText'
            Refund.CustRetItmFollowUpActivity,

            @Semantics.quantity.unitOfMeasure: 'BaseUnit'
            Refund.InspectedProductQtyInBaseUnit,

            @Semantics.unitOfMeasure: true
            Refund.BaseUnit,

            @UI.hidden: true
            cast ('' as msr_insp_itm_is_splt)                                                as InspectionItemIsSplit,
            @UI.hidden: true
            _ScheduleLine.GoodsMovementType,
            //Associations

            _CreditMemo,
            _OutboundDeliveryOrder,
            _CreditMemoRequestItem,
            _OrderWOCharge,
            @ObjectModel.filter.enabled: false
            _CustomerReturnRefundDetail,
            _MaterialText,
            _RepMaterialText,
            _SupplyingPlant,
            _ReturnsRefundType,
            _ReturnsRefundExtent,
            _SalesDocumentRjcnReason,
            _SalesDocumentRjcnReasonT,
            _CustomerReturnProductUoMVH,
            _RetMatlInspResultCodeText,
            _ReturnsRefundTypeText,
            _ReturnsRefundExtentText,
            _SalesDocumentTypeText,
            _FollowUpActivityText,
            _RetsMgmtProcItmWthProcgSts
}

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SALESDOCUMENTITEMCATEGORY",
"P_CUSTRETITEMSCHEDULELINE",
"P_RETURNSDOCUMENTITEMREFUND"
],
"ASSOCIATED":
[
"C_CREDITMEMOREQUESTITEM",
"C_CUSTOMERRETURNPRODUCTUOMVH",
"C_CUSTOMERRETURNREFUNDDETAIL",
"C_CUSTRETSUBSQNTCRDTMEMO",
"C_SALESORDERWITHOUTCHARGEITEM",
"E_SALESDOCUMENTITEMBASIC",
"I_ADVNCDRETSMGMTPROCEXECUTED",
"I_ADVNCDRETURNSMGMTPROCESSITEM",
"I_FOLLOWUPACTIVITYTEXT",
"I_MATERIALTEXT",
"I_PLANT",
"I_RETMATLINSPRESULTCODETEXT",
"I_RETURNSREFUNDEXTENT",
"I_RETURNSREFUNDEXTENTTEXT",
"I_RETURNSREFUNDTYPE",
"I_RETURNSREFUNDTYPETEXT",
"I_SALESDOCUMENTITEMCATEGORY",
"I_SALESDOCUMENTRJCNREASON",
"I_SALESDOCUMENTRJCNREASONTEXT",
"I_SALESDOCUMENTTYPETEXT",
"P_CUSTRETITEMSCHEDULELINE",
"P_REFUNDEDQUANTITYSUM",
"P_REFUNDINGQUANTITY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/