I_AdvncdRetsMgmtProcExecuted

@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Advanced Returns Mgmt Process Executed'

@VDM.viewType: #BASIC
@Analytics.dataExtraction.enabled: false

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_Address', '_DfltAddrRprstn' ]
}
@AbapCatalog: {
  sqlViewName: 'IARMPEXECUTED',
  preserveKey: true,
  compiler.compareFilter: true
}
@ObjectModel: {
  usageType: {
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #B,
    sizeCategory:   #L
  }
}

define view I_AdvncdRetsMgmtProcExecuted
  as select from msr_d_executed as Executed
  //Associations

  association [1..1] to I_AdvncdReturnsMgmtProcess     as _AdvncdRetsMgmtProcess        on  $projection.RetsMgmtProcess = _AdvncdRetsMgmtProcess.RetsMgmtProcess
  association [1..1] to I_AdvncdReturnsMgmtProcessItem as _AdvncdRetsMgmtProcessItem    on  $projection.RetsMgmtProcess     = _AdvncdRetsMgmtProcessItem.RetsMgmtProcess
                                                                                        and $projection.RetsMgmtProcessItem = _AdvncdRetsMgmtProcessItem.RetsMgmtProcessItem
                                                                                        
  association [0..1] to I_ReturnsDocumentType          as _ReturnsReferenceDocumentType on  $projection.ReturnsReferenceDocumentType = _ReturnsReferenceDocumentType.ReturnsDocumentType
  association [0..1] to I_ReturnsRefundType            as _ReturnsRefundType            on  $projection.ReturnsRefundType            = _ReturnsRefundType.ReturnsRefundType
  association [0..1] to I_ReturnsRefundProcgModeActive as _ReturnsRefundProcgMode       on  $projection.ReturnsRefundProcgMode       = _ReturnsRefundProcgMode.ReturnsRefundProcgMode
                                                                                        and $projection.ReturnsRefundType            = _ReturnsRefundProcgMode.ReturnsRefundType

  association [0..1] to I_UnitOfMeasure                as _ReplacementMaterialQtyUnit   on  $projection.ReplacementMaterialQtyUnit = _ReplacementMaterialQtyUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure                as _ReplacedMaterialQtyUnit      on  $projection.ReplacedMaterialQtyUnit = _ReplacedMaterialQtyUnit.UnitOfMeasure

  association [1..1] to I_Supplier                     as _Supplier                     on  $projection.Supplier = _Supplier.Supplier
  association [1..1] to I_Address                      as _Address                      on  $projection.AddressID = _Address.AddressID
 association [1..*] to I_Address_2                     as _DfltAddrRprstn               on  $projection.AddressID = _DfltAddrRprstn.AddressID
 
  association [0..1] to I_RetMatlInspResultCode        as _RetMatlInspResultCode        on  $projection.RetMatlInspResultCode = _RetMatlInspResultCode.RetMatlInspResultCode
{
      //Key

  key msr_id                                                             as RetsMgmtProcess,
  key item                                                               as RetsMgmtProcessItem,

  key split_id                                                           as RetsMgmtProcItmQtySplit,
  key executed_step_id                                                   as RetsMgmtProcessStep,

  key doc_type                                                           as ReturnsDocumentType,
  key doc_nr                                                             as ReturnsDocument,
  key doc_item                                                           as ReturnsDocumentItem,

      cast (right(doc_item, 6) as posnr)                                 as SDDocumentItem,

      executed_seq_id                                                    as RetsMgmtProcItmExectdSequence,
      chain_id                                                           as CustRetItmChainID,

      //Reference Document

      @ObjectModel.foreignKey.association: '_ReturnsReferenceDocumentType'
      ref_doc_type                                                       as ReturnsReferenceDocumentType,
      ref_doc_nr                                                         as ReturnsReferenceDocument,
      ref_doc_item                                                       as ReturnsReferenceDocumentItem,

      //Returns Document Status

      doc_status                                                         as ReturnsDocumentStatus,
      appr_status                                                        as ReturnsDocumentApprovalStatus,

      im_plant                                                           as TargetPlant,
      lgort                                                              as TargetStorageLocation,
      insmk                                                              as TargetStockType,
      im_material                                                        as TgtProdForGdsMvtPostg,
      
      //Refunding

      @ObjectModel.foreignKey.association: '_ReturnsRefundType'
      refund_type                                                        as ReturnsRefundType,
      @ObjectModel.foreignKey.association: '_ReturnsRefundProcgMode'
      cast (refund_control as returns_refund_procg_mode preserving type) as ReturnsRefundProcgMode,
      cast (pre_refund as abap.char(1))                                  as PrelimRefundIsDetermined,

      //Replacement

      replace_matnr                                                      as ReplacementMaterial,
      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'ReplacementMaterialQtyUnit'
      replace_qty                                                        as ReplacementMaterialQuantity,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_ReplacementMaterialQtyUnit'
      replace_unit                                                       as ReplacementMaterialQtyUnit,
      cast (replace_request as abap.char(1))                             as ReplacementMaterialIsRequested,
      paying_plant                                                       as ReplacementMatlSupplyingPlant,

      @DefaultAggregation: #SUM
      @Semantics.quantity.unitOfMeasure: 'ReplacedMaterialQtyUnit'
      replaced_qty                                                       as ReplacedMaterialQuantity,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_ReplacedMaterialQtyUnit'
      replaced_unit                                                      as ReplacedMaterialQtyUnit,

      @ObjectModel.foreignKey.association: '_Supplier'
      lifnr                                                              as Supplier,
      @ObjectModel.foreignKey.association: '_Address'
      addrnumber                                                         as AddressID,
      rma_vendor                                                         as SupplierRetMatlAuthzn,
      cast (rma_vendor_req as abap.char(1))                              as SuplrRetMatlAuthznIsRequired,

      //Inspection

      @ObjectModel.foreignKey.association: '_RetMatlInspResultCode'
      inspection_code                                                    as RetMatlInspResultCode,


      //Associations

      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
      _AdvncdRetsMgmtProcess,   
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]
      _AdvncdRetsMgmtProcessItem, 
      _ReturnsReferenceDocumentType,
      _ReturnsRefundType,
      _ReturnsRefundProcgMode,
      _ReplacementMaterialQtyUnit,
      _ReplacedMaterialQtyUnit,
      _Supplier,
      _Address,
      _DfltAddrRprstn,
      _RetMatlInspResultCode
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MSR_D_EXECUTED"
],
"ASSOCIATED":
[
"I_ADDRESS",
"I_ADDRESS_2",
"I_ADVNCDRETURNSMGMTPROCESS",
"I_ADVNCDRETURNSMGMTPROCESSITEM",
"I_RETMATLINSPRESULTCODE",
"I_RETURNSDOCUMENTTYPE",
"I_RETURNSREFUNDPROCGMODEACTIVE",
"I_RETURNSREFUNDTYPE",
"I_SUPPLIER",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/