@AbapCatalog.sqlViewName: 'CCHGRECREFLBL'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Change Record Reference Obj Page Label'
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.viewType: #CONSUMPTION
@AbapCatalog.preserveKey:true
@ObjectModel: {
semanticKey: ['LabelSetSpecificationIntID','Specification'],
createEnabled: true,
deleteEnabled: 'EXTERNAL_CALCULATION',
updateEnabled,
transactionalProcessingDelegated: true
}
@UI.headerInfo:{
typeName: 'Label Set',
typeNamePlural: 'Label Sets',
imageUrl: 'ChangeRecordRefObjIcon',
title:{value:'LabelSet'}
}
@ObjectModel.usageType: {serviceQuality: #D,
dataClass: #MIXED,
sizeCategory: #L}
@ClientHandling.algorithm: #SESSION_VARIABLE
@UI.presentationVariant.requestAtLeast: ['ChangeRecordType', 'ChangeRecordLifecycleStatus']
define view C_ChangeRecordObjPgLabel
as select from I_ChgRecdRefLabelTP as ChangeRecordReferenceLBLTP
association [1..1] to C_ChangeRecordObjPg as _ChangeRecordObjPg on $projection.ChangeRecordUUID = _ChangeRecordObjPg.ChangeRecordUUID
association [0..*] to I_LabelSetText as _LabelSetText on $projection.LabelSetInternalID = _LabelSetText.LabelSetInternalID
association [1..1] to I_LabelSetVH as _LabelVH on $projection.Specification = _LabelVH.LabelSetSpecification
and $projection.LabelSetAlternativeNumber = _LabelVH.LabelSetAlternativeNumber
and $projection.LabelSetVersionNumber = _LabelVH.LabelSetVersionNumber
association [1..1] to C_ChangeRecordItemRelLabelVH as _ChangeRecordItemRelVH on $projection.ChangeRecordItemRelevance = _ChangeRecordItemRelVH.ChangeRecordItemRelevance
and $projection.ChangeRecordType = _ChangeRecordItemRelVH.ChangeRecordType
// and (
// $projection.ChangeRecordReferenceType = _ChangeRecordItemRelVH.ChangeRecordReferenceType
// or _ChangeRecordItemRelVH.ChangeRecordReferenceType = ' '
// )
association [1..1] to C_ChgRecordItemProcgStatusVH as _ProcessingStatusVH on $projection.ChangeRecordItemProcgStatus = _ProcessingStatusVH.ChgRecdNextItemProcgStatus
and $projection.ChgRecdCurrentItemProcgStatus = _ProcessingStatusVH.ChgRecdCurrentItemProcgStatus
and $projection.ChangeRecordLifecycleStatus = _ProcessingStatusVH.ChangeRecordLifecycleStatus
association [0..*] to I_ChgRecdItemProcgStatusText as _ProcessingStatusTxt on $projection.ChangeRecordItemProcgStatus = _ProcessingStatusTxt.ChangeRecordItemProcgStatus
association [0..1] to C_ChgRecdSpecIdfrForCurDate as _Identifier on $projection.LabelSetSpecificationIntID = _Identifier.SpecificationInternalID
association [0..*] to I_ChangeRecordRefObjIcons as _ChangeRecordRefObjIcons on $projection.ChangeRecordUUID = _ChangeRecordRefObjIcons.ChangeRecordUUID
and $projection.ChangeRecordReferenceType = _ChangeRecordRefObjIcons.ChangeRecordReferenceType
association [0..*] to C_ChangeRecdDigSignStatusVH as _DigSignStatusText on $projection.ChgRecdItmDSgntr = _DigSignStatusText.ChgRecdDigitalSignatureStatus
{
@UI.hidden: true
@ObjectModel.readOnly: true
key ChangeRecordReferenceUUID,
@UI.hidden: true
@UI.lineItem:[
{ position:5,
importance:#HIGH }
]
@UI.identification: {position: 5, importance: #HIGH}
@Semantics.imageUrl: true
@ObjectModel.readOnly: true
@EndUserText.label: 'Icon'
_ChangeRecordRefObjIcons[ChangeRecordType = ChangeRecordType].ChangeRecordRefObjIcon as ChangeRecordRefObjIcon,
@UI.hidden: true
@ObjectModel.readOnly: true
_ChangeRecordObjPg.ChangeRecordType as ChangeRecordType,
@UI.hidden: true
ChangeRecordReferenceLBLTP.LabelSetInternalID as LabelSetInternalID,
@UI.hidden: true
@ObjectModel.readOnly: true
ChangeRecordReferenceLBLTP.LabelSetSpecificationIntID as LabelSetSpecificationIntID,
@UI.hidden: true
@ObjectModel.readOnly: true
_LabelSetText[1:Language = $session.system_language].LabelSetDescription as LabelSetDescription,
@UI.lineItem:[{
position:30,
label: 'Label',
importance:#HIGH }
]
@UI.identification: {position: 30, importance: #HIGH}
@ObjectModel.mandatory: true
@Consumption.valueHelp: '_LabelVH'
@ObjectModel.text.element: [ 'LabelSetDescription' ]
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
ChangeRecordReferenceLBLTP.Specification as Specification,
@UI.hidden: true
@ObjectModel.readOnly: true
@UI.lineItem:[{
position:20,
label: 'Identifier',
importance:#HIGH }
]
@UI.identification: {position: 20, importance: #HIGH}
_Identifier.SpecIdfgDescText,
@UI.lineItem:[{
position:50,
label: 'Alternative Label',
importance:#MEDIUM }
]
@UI.identification: {position: 50, importance: #MEDIUM}
@ObjectModel.mandatory: true
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
ChangeRecordReferenceLBLTP.LabelSetAlternativeNumber as LabelSetAlternativeNumber,
@UI.lineItem:[{
position:60,
label: 'Label Version',
importance:#MEDIUM }
]
@UI.identification: {position: 60, importance: #MEDIUM}
@ObjectModel.mandatory: true
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
ChangeRecordReferenceLBLTP.LabelSetVersionNumber as LabelSetVersionNumber,
@UI.lineItem:[{
position:80,
label: 'Relevance',
importance:#MEDIUM }
]
@UI.identification: {position: 80, importance: #MEDIUM}
@ObjectModel.foreignKey.association: '_ChangeRecordItemRelVH'
@Consumption.valueHelp: '_ChangeRecordItemRelVH'
@ObjectModel.mandatory: true
@UI.textArrangement: #TEXT_ONLY
ChangeRecordItemRelevance,
@UI.lineItem:[ {position:45, importance:#MEDIUM } ]
@UI.identification: [{position: 70, importance: #MEDIUM }]
@EndUserText.label: 'Processing Status'
@Consumption.valueHelpDefinition: [{association: '_ProcessingStatusVH'}]
@ObjectModel.foreignKey.association: '_ProcessingStatusVH'
@UI.textArrangement: #TEXT_FIRST
ChangeRecordItemProcgStatus,
@UI.hidden: true
@ObjectModel.readOnly: true
ChgRecdCurrentItemProcgStatus,
@ObjectModel.readOnly:true
@UI.hidden: true
_ChangeRecordObjPg.ChgRecdItemProcgStatusIsEnbld,
@UI.hidden: true
_ChangeRecordObjPg.ChangeRecordLifecycleStatus as ChangeRecordLifecycleStatus,
@UI.hidden: true
@ObjectModel.readOnly: true
_ChangeRecordObjPg.ChangeRecordItemIsNotEditable,
@UI.hidden: true
@ObjectModel.readOnly: true
_ChangeRecordObjPg.ChangeRecordItmIsAddDelEnabled,
@UI.hidden: true
@ObjectModel.readOnly: true
_ChangeRecordObjPg.ChangeRecordStatus,
@UI.hidden: true
ChangeRecordUUID,
@UI.hidden: true
ChangeRecordReferenceType,
@UI.hidden: true
ParentChangeRecordRefUUID,
@UI.hidden: true
ChangeRecordReference,
@Semantics.user.createdBy: true
@ObjectModel.readOnly: true
@UI.identification: [{importance: #MEDIUM, position: 95 }]
CreatedByUser,
@UI.hidden: true
CreationDateTime,
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CREATIONDATE_CONVERT'
@ObjectModel.readOnly: true
@UI.identification: [{importance: #MEDIUM, position: 100 }]
cast( '00000000' as /plmb/created_on ) as CreationDate,
@Semantics.user.lastChangedBy: true
@ObjectModel.readOnly: true
@UI.identification: [{importance: #MEDIUM, position: 105 }]
LastChangedByUser,
@UI.hidden: true
LastChangeDateTime,
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CHANGEDATE_CONVERT'
@ObjectModel.readOnly: true
@UI.identification: [{importance: #MEDIUM, position: 110 }]
cast( '00000000' as /plmb/changed_on ) as LastChangeDate,
@UI.hidden: true
ChangeRecordRefObjectUUID,
@UI.hidden: true
@UI.lineItem:[{importance:#MEDIUM, hidden: true } ]
@EndUserText.label: 'Digital Signature Status'
@ObjectModel.foreignKey.association: '_DigSignStatusText'
@Consumption: { valueHelp: '_DigSignStatusText' }
ChgRecdItmDSgntr,
@UI.lineItem:[{
hidden: true,
importance:#LOW }
]
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
cast( '' as boolean) as DigitalSignUserIsAuthorized,
@ObjectModel.readOnly: true
@UI.identification: [{importance: #LOW, position: 90 }]
@EndUserText.label: 'Digital Signature Status'
_DigSignStatusText.ChgRecdDigSignStatusTxt as ChgRecdDigSignStatusTxt,
@UI.lineItem:[{
hidden: true,
importance:#LOW }
]
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
cast( '' as boolean) as ChgRecdObjDgtlSgntrEnable,
@UI.identification: [{importance: #MEDIUM, position: 115 }]
ChgRecdReasonForChange,
@UI.identification: [{importance: #MEDIUM, position: 120 }]
ExpdCompltnDte,
@UI.identification: [{importance: #MEDIUM, position: 125 }]
@Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChangeRecdAuthznGrpVH' , element: 'ChgRecdNmbrAuthznGrp'}}]
ChgRecdAuthznGrpText,
@UI.identification: [{importance: #MEDIUM, position: 130 }]
@Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChgRecdChgNmbrStatusVH' , element: 'ChgRecdNmbrChgSts'}}]
ChgRecdNmbrChgSts,
@ObjectModel.association.type: [ #TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT ]
_ChangeRecordObjPg,
_LabelVH,
_ChangeRecordItemRelVH,
_ProcessingStatusVH,
_ProcessingStatusTxt,
_DigSignStatusText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_CHANGERECDDIGSIGNSTATUSVH",
"C_CHANGERECORDOBJPG",
"C_CHGRECDSPECIDFRFORCURDATE",
"I_CHANGERECORDREFOBJICONS",
"I_CHGRECDREFLABELTP",
"I_LABELSETTEXT"
],
"ASSOCIATED":
[
"C_CHANGERECDDIGSIGNSTATUSVH",
"C_CHANGERECORDITEMRELLABELVH",
"C_CHANGERECORDOBJPG",
"C_CHGRECDSPECIDFRFORCURDATE",
"C_CHGRECORDITEMPROCGSTATUSVH",
"I_CHANGERECORDREFOBJICONS",
"I_CHGRECDITEMPROCGSTATUSTEXT",
"I_LABELSETTEXT",
"I_LABELSETVH"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/