I_LabelSetVH

@AbapCatalog.sqlViewName: 'ILABELSETVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_SpecificationNonHistoric']

@ClientHandling.algorithm: #SESSION_VARIABLE

@Consumption.ranked: true

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.representativeKey: 'LabelSetInternalID'

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER

@Search.searchable: true

@VDM.lifecycle.contract.type: #NONE
@VDM.viewType: #COMPOSITE

@EndUserText.label: 'Label Set Value Help'
define view I_LabelSetVH
  as select from           I_LabelSet       as hd
    left outer to one join I_LabelSetDetail as detail on hd.LabelSetInternalID = detail.LabelSetInternalID
  association [1..1] to I_SpecificationNonHistoric as _SpecificationNonHistoric on $projection.LabelSetSpecificationIntID = _SpecificationNonHistoric.SpecificationInternalID
  association [1..*] to I_Specification            as _Specification            on $projection.LabelSetSpecificationIntID = _Specification.SpecificationInternalID

{
  key hd.LabelSetInternalID,

      @Consumption.hidden: true
      LabelSetSpecificationIntID,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      _SpecificationNonHistoric.Specification as LabelSetSpecification,

      LabelSetAlternativeNumber,
      LabelSetVersionNumber,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text
      _LabelSetText[1:Language = $session.system_language].LabelSetDescription,

      detail.LabelSetAuthorizationGroup,
      detail.LabelSetStatus,

      @Consumption.hidden:true
      _Specification,

      @Consumption.hidden:true
      _SpecificationNonHistoric
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LABELSET",
"I_LABELSETDETAIL",
"I_LABELSETTEXT",
"I_SPECIFICATIONNONHISTORIC"
],
"ASSOCIATED":
[
"I_SPECIFICATION",
"I_SPECIFICATIONNONHISTORIC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/