@AbapCatalog.sqlViewName: 'CCHGRECPRODNROU'
@EndUserText.label: 'Change Record Object Page Production Routing'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType: {serviceQuality: #C,
dataClass: #MIXED,
sizeCategory: #L}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel: {
semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant'],
createEnabled: true,
deleteEnabled: 'EXTERNAL_CALCULATION',
updateEnabled,
transactionalProcessingDelegated: true
}
@UI.headerInfo:{
typeName: 'Production Routing',
typeNamePlural: 'Production Routings',
imageUrl: 'ChangeRecordRefObjIcon',
title:{value:'BillOfOperationsGroup'}
}
@UI.presentationVariant.requestAtLeast: ['ChangeRecordType', 'ChangeRecordLifecycleStatus' , 'ChangeRecordReferenceType' ]
define view C_ChangeRecdObjPgProdnRouting
as select from I_ChgRecdRefProdnRoutingTP as ChangeRecordReferenceRTGTP
association [1..1] to C_ChgRecdItemRelProdnRoutingVH as _ChangeRecordItemRelVH on $projection.ChangeRecordItemRelevance = _ChangeRecordItemRelVH.ChangeRecordItemRelevance
and $projection.ChangeRecordType = _ChangeRecordItemRelVH.ChangeRecordType
// and (
// _ChangeRecordItemRelVH.ChangeRecordReferenceType = ' '
// or $projection.ChangeRecordReferenceType = _ChangeRecordItemRelVH.ChangeRecordReferenceType
// )
association [1..1] to C_ChangeRecordObjPg as _ChangeRecordObjPg on $projection.ChangeRecordUUID = _ChangeRecordObjPg.ChangeRecordUUID
association [1..1] to C_ChangeRecordProdnRoutingVH as _ProdnRoutingVH on $projection.BillOfOperationsType = _ProdnRoutingVH.BillOfOperationsType
and $projection.BillOfOperationsGroup = _ProdnRoutingVH.BillOfOperationsGroup
and $projection.BillOfOperationsVariant = _ProdnRoutingVH.BillOfOperationsVariant
association [1..1] to C_ChgRecordItemProcgStatusVH as _ProcessingStatusVH on $projection.ChangeRecordItemProcgStatus = _ProcessingStatusVH.ChgRecdNextItemProcgStatus
and $projection.ChgRecdCurrentItemProcgStatus = _ProcessingStatusVH.ChgRecdCurrentItemProcgStatus
and $projection.ChangeRecordLifecycleStatus = _ProcessingStatusVH.ChangeRecordLifecycleStatus
association [0..*] to I_ChgRecdItemProcgStatusText as _ProcessingStatusTxt on $projection.ChangeRecordItemProcgStatus = _ProcessingStatusTxt.ChangeRecordItemProcgStatus
association [1..1] to I_BillOfOperations as _BillOfOperations on $projection.BillOfOperationsType = _BillOfOperations.BillOfOperationsType
and $projection.BillOfOperationsGroup = _BillOfOperations.BillOfOperationsGroup
and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
association [0..*] to I_ChangeRecordRefObjIcons as _ChangeRecordRefObjIcons on $projection.ChangeRecordUUID = _ChangeRecordRefObjIcons.ChangeRecordUUID
and $projection.ChangeRecordReferenceType = _ChangeRecordRefObjIcons.ChangeRecordReferenceType
association [0..*] to C_ChangeRecdDigSignStatusVH as _DigSignStatusText on $projection.ChgRecdItmDSgntr = _DigSignStatusText.ChgRecdDigitalSignatureStatus
{
@UI.hidden: true
@ObjectModel.readOnly: true
key ChangeRecordReferenceUUID,
@UI.hidden: true
@UI.lineItem:[
{ position:5,
importance:#HIGH }
]
@UI.identification: {position: 5, importance: #HIGH}
@Semantics.imageUrl: true
@ObjectModel.readOnly: true
@EndUserText.label: 'Icon'
_ChangeRecordRefObjIcons[ChangeRecordType = ChangeRecordType].ChangeRecordRefObjIcon as ChangeRecordRefObjIcon,
@UI.lineItem:[{
position:10,
label: 'Group',
importance:#HIGH }
]
@UI.identification: {position: 10, importance: #HIGH}
@Consumption.valueHelpDefinition: [
{ entity: {name: 'C_ChangeRecordProdnRoutingVH',
element: 'BillOfOperationsGroup'},
additionalBinding: [{ localElement: 'BillOfOperationsVariant', element: 'BillOfOperationsVariant' }],
label: 'Group'
}
]
@ObjectModel.text.element: [ 'BillOfOperationsDesc' ]
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
cast (ChangeRecordReferenceRTGTP.BillOfOperationsGroup as plnnr preserving type ) as BillOfOperationsGroup,
@UI.hidden: true
@ObjectModel.readOnly: true
_BillOfOperations._BillOfOperationsChangeState[1: ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date].BillOfOperationsDesc,
@UI.hidden: true
@UI.lineItem:[{
position:15,
label: 'Task List Type',
importance:#HIGH }
]
@UI.identification: {position: 15, importance: #HIGH}
@ObjectModel.readOnly: true
ChangeRecordReferenceRTGTP.BillOfOperationsType as BillOfOperationsType,
@UI.lineItem:[{
position:20,
label: 'Group Counter',
importance:#HIGH }
]
@UI.identification: {position: 20, importance: #HIGH }
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
cast(ChangeRecordReferenceRTGTP.BillOfOperationsVariant as plnal preserving type) as BillOfOperationsVariant,
@UI.lineItem:[{
position:25,
label: 'Usage',
importance:#MEDIUM }
]
@UI.identification: {position: 25, importance: #MEDIUM}
@ObjectModel.readOnly: true
_BillOfOperations._BillOfOperationsChangeState[1: ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date].BillOfOperationsUsage,
@UI.lineItem:[{
position:40,
label: 'Plant',
importance:#HIGH }
]
@UI.identification: {position: 40, importance: #HIGH}
@ObjectModel.readOnly: true
_BillOfOperations._BillOfOperationsChangeState[1: ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date].Plant,
@UI.lineItem:[{
position:45,
label: 'Status',
importance:#MEDIUM }
]
@UI.identification: {position: 45, importance: #MEDIUM}
@ObjectModel.readOnly: true
_BillOfOperations._BillOfOperationsChangeState[1: ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date].BillOfOperationsStatus,
@UI.lineItem:[ {position: 100, importance:#MEDIUM } ]
@UI.identification: [{position: 100, importance: #MEDIUM }]
@EndUserText.label: 'Processing Status'
@Consumption.valueHelpDefinition: [{association: '_ProcessingStatusVH'}]
@ObjectModel.foreignKey.association: '_ProcessingStatusVH'
@UI.textArrangement: #TEXT_FIRST
ChangeRecordItemProcgStatus,
@UI.hidden: true
@ObjectModel.readOnly: true
ChgRecdCurrentItemProcgStatus,
@ObjectModel.readOnly:true
@UI.hidden: true
_ChangeRecordObjPg.ChgRecdItemProcgStatusIsEnbld,
@UI.hidden: true
_ChangeRecordObjPg.ChangeRecordLifecycleStatus as ChangeRecordLifecycleStatus,
@UI.hidden: true
@ObjectModel.readOnly: true
_ChangeRecordObjPg.ChangeRecordItemIsNotEditable,
@UI.hidden: true
@ObjectModel.readOnly: true
_ChangeRecordObjPg.ChangeRecordItmIsAddDelEnabled,
@UI.hidden: true
@ObjectModel.readOnly: true
_ChangeRecordObjPg.ChangeRecordStatus,
@UI.hidden: true
@ObjectModel.readOnly: true
_ChangeRecordObjPg.ChangeRecordType as ChangeRecordType,
@UI.hidden: true
ChangeRecordUUID,
@UI.hidden: true
ChangeRecordReferenceType,
@UI.hidden: true
ParentChangeRecordRefUUID,
@UI.lineItem:[{
position:50,
importance:#MEDIUM }
]
@UI.identification: {position:50, importance: #MEDIUM}
@ObjectModel.foreignKey.association: '_ChangeRecordItemRelVH'
@Consumption.valueHelp: '_ChangeRecordItemRelVH'
@ObjectModel.mandatory: true
@UI.textArrangement: #TEXT_ONLY
ChangeRecordItemRelevance,
@UI.hidden: true
ChangeRecordReference,
@Semantics.user.createdBy: true
@UI.identification: [{importance: #LOW, position: 110}]
ChangeRecordReferenceRTGTP.CreatedByUser,
@UI.hidden: true
CreationDateTime,
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CREATIONDATE_CONVERT'
@ObjectModel.readOnly: true
@UI.identification: [{importance: #LOW, position: 115}]
cast( '00000000' as /plmb/created_on ) as CreationDate,
@Semantics.user.lastChangedBy: true
@UI.identification: [{importance: #LOW, position: 120}]
ChangeRecordReferenceRTGTP.LastChangedByUser,
@UI.hidden: true
LastChangeDateTime,
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CHANGEDATE_CONVERT'
@ObjectModel.readOnly: true
@UI.identification: [{importance: #LOW, position: 125}]
cast( '00000000' as /plmb/changed_on ) as LastChangeDate,
@UI.hidden: true
@UI.lineItem:[{importance:#HIGH, hidden: true } ]
@EndUserText.label: 'Digital Signature Status'
@ObjectModel.foreignKey.association: '_DigSignStatusText'
@Consumption: { valueHelp: '_DigSignStatusText' }
ChgRecdItmDSgntr,
@UI.lineItem:[{
hidden: true,
importance:#LOW }
]
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
cast( '' as boolean) as DigitalSignUserIsAuthorized,
@ObjectModel.readOnly: true
@UI.identification: [{importance: #LOW, position: 105}]
@EndUserText.label: 'Digital Signature Status'
_DigSignStatusText.ChgRecdDigSignStatusTxt as ChgRecdDigSignStatusTxt,
@UI.lineItem:[{
hidden: true,
importance:#LOW }
]
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
cast( '' as boolean) as ChgRecdObjDgtlSgntrEnable,
@UI.identification: [{importance: #LOW, position: 130}]
ChgRecdReasonForChange,
@UI.identification: [{importance: #LOW, position: 135}]
ExpdCompltnDte,
@UI.identification: [{importance: #LOW, position: 140}]
@Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChangeRecdAuthznGrpVH' , element: 'ChgRecdNmbrAuthznGrp'}}]
ChgRecdAuthznGrpText,
@UI.identification: [{importance: #LOW, position: 145}]
@Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChgRecdChgNmbrStatusVH' , element: 'ChgRecdNmbrChgSts'}}]
ChgRecdNmbrChgSts,
@ObjectModel.association.type: [ #TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT ]
_ChangeRecordObjPg,
_ChangeRecordItemRelVH,
_ProdnRoutingVH,
_ProcessingStatusVH,
_ProcessingStatusTxt,
_BillOfOperations,
_DigSignStatusText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_CHANGERECDDIGSIGNSTATUSVH",
"C_CHANGERECORDOBJPG",
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSCHANGESTATE",
"I_CHANGERECORDREFOBJICONS",
"I_CHGRECDREFPRODNROUTINGTP"
],
"ASSOCIATED":
[
"C_CHANGERECDDIGSIGNSTATUSVH",
"C_CHANGERECORDOBJPG",
"C_CHANGERECORDPRODNROUTINGVH",
"C_CHGRECDITEMRELPRODNROUTINGVH",
"C_CHGRECORDITEMPROCGSTATUSVH",
"I_BILLOFOPERATIONS",
"I_CHANGERECORDREFOBJICONS",
"I_CHGRECDITEMPROCGSTATUSTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/