C_CashBankScriptedAddress

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Cash Bank Scripted Address'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MASTER //#MIXED

}
@Metadata.allowExtensions: true
@VDM.viewType: #CONSUMPTION
define view entity C_CashBankScriptedAddress as select from R_BankScriptedAddressTP as _BankScriptedAddress 
  association [1..1] to I_Bank_2                           as _BankDetail          on  $projection.BankCountry   = _BankDetail.BankCountry
                                                                                  and $projection.BankInternalID = _BankDetail.BankInternalID                                         
{     @ObjectModel.text.element: [ 'CountryShortName' ]
  key _BankScriptedAddress.BankCountry,
      @ObjectModel.text.element: [ 'BankName' ] 
  key _BankScriptedAddress.BankInternalID,
      @Consumption.valueHelpDefinition: [{ entity : {name: 'C_BankAddressRepresentationVH', element: 'AddressRepresentationCode'  } }]//C_BankAddressRepCodeVH

      @ObjectModel.text.element: ['AddressCodeDesc']
  key _BankScriptedAddress.AddressRepresentationCode as AddressRepresentationCode, //is not initial

      @UI.hidden: true
      @Semantics.text: true
      _BankScriptedAddress._AddressRepresentationCode._Text[1:Language = $session.system_language].AddressRepresentationDesc as AddressCodeDesc,

      _BankScriptedAddress.LongBankName,   //char80

      _BankScriptedAddress.LongBankBranch, //char80

      _BankScriptedAddress.StreetName,
      _BankScriptedAddress.HouseNumber,
      _BankScriptedAddress.HouseNumberSupplementText,
      _BankScriptedAddress.CityName,
      _BankScriptedAddress.Building,
      _BankScriptedAddress.RoomNumber,
      _BankScriptedAddress.Floor, 
      //----Address---- Fields ADRC where NATION <> ''

      _BankScriptedAddress.StreetPrefixName1,
      _BankScriptedAddress.StreetPrefixName2,
      _BankScriptedAddress.StreetSuffixName1,
      _BankScriptedAddress.StreetSuffixName2,
      _BankScriptedAddress.DistrictName,
      _BankScriptedAddress.VillageName,
       

      @ObjectModel.text.element: [ 'BankCountryName' ]
      @Consumption.valueHelpDefinition: [{ entity:  { name:  'I_CountryVH', element: 'Country' } }]
      _BankScriptedAddress.Country,
      @UI.hidden: true
      @Semantics.text: true
      _BankScriptedAddress._Country._Text[1:Language = $session.system_language].CountryShortName                            as BankCountryName,      
      _BankScriptedAddress.AddressSearchTerm1,
      _BankScriptedAddress.AddressSearchTerm2,
      _BankScriptedAddress.POBoxLobbyName,
      _BankScriptedAddress.POBoxDeviatingCityName,
      _BankScriptedAddress.CareOfName,
      _BankScriptedAddress.SecondaryRegionName,
      _BankScriptedAddress.TertiaryRegionName,

      @UI.hidden: true
      _BankDetail.BankName,
      @UI.hidden: true
      _BankDetail._Country._Text[1:Language = $session.system_language].CountryShortName                                     as CountryShortName,
            
      _BankScriptedAddress.AddressID, //adrc-ADDRNUMBER -> additional?,

      _Bank

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESSREPRESENTATION",
"I_ADDRESSREPRESENTATIONTEXT",
"I_BANK_2",
"I_COUNTRY",
"I_COUNTRYTEXT",
"R_BANKSCRIPTEDADDRESSTP"
],
"ASSOCIATED":
[
"R_BANKTP"
],
"BASE":
[
"R_BANKSCRIPTEDADDRESSTP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/