C_CN_CADEAssetChangeLog

@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'CCADEASTCHG'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: { usageType.serviceQuality: #D,
                usageType.sizeCategory: #XXL,
                usageType.dataClass: #MIXED }
@EndUserText.label: 'Change Log of Assgmt of Asset for CADE'
define view C_CN_CADEAssetChangeLog with parameters
    @EndUserText.label: 'Fiscal Year'
    P_FiscalYear   : fis_gjahr,
    @EndUserText.label: 'From Fiscal Period'
    P_FromFiscalPeriod : fins_fiscalperiod,
    @EndUserText.label: 'To Fiscal Period'
    P_ToFiscalPeriod   : fins_fiscalperiod,
    @EndUserText.label: 'Language'
    @Environment.systemField: #SYSTEM_LANGUAGE
    P_Language : sylangu
as select from I_FiscalYearPeriodForLedger as FiscalPeriod
inner join P_CN_CADEAssetChangeLog ( P_Language : :P_Language ) as ChangeLog on ChangeLog.CompanyCode = FiscalPeriod.CompanyCode
                                                     and ChangeLog.CreationDate >= FiscalPeriod.FiscalPeriodStartDate
                                                     and ChangeLog.CreationDate <= FiscalPeriod.FiscalPeriodEndDate
                                                     and ChangeLog.Ledger = FiscalPeriod.Ledger
{
  key ChangeLog.CompanyCode,
  key ChangeLog.Ledger,
  key MasterFixedAsset,
  key FixedAsset,
  key ChangeDocObject,
  key ChangeDocObjectClass,
  key ChangeDocument,
  key DatabaseTable,
  key ChangeDocTableKey,
  key ChangeDocDatabaseTableField,
  key ChangeDocItemChangeType,
      concat( ChangeDocument, concat( REPLACE( ChangeDocTableKey, left(ChangeDocTableKey, 23), '' ), concat( '-', ChangeDocDatabaseTableField ) ) ) as AccountingDocument,
      FiscalPeriod.FiscalPeriod,
      FixedAssetExternalID,
      AssetSerialNumber,
      Inventory,
      AssetClass,
      FixedAssetDescription,
      AssetTransactionType,
      AssetTransactionTypeName,
      ChangeTransactionCode,
      CreationDate,
      ChangeDocNewFieldValue,
      ChangeDocPreviousFieldValue
}
where
    FiscalPeriod.FiscalYear = :P_FiscalYear
and FiscalPeriod.FiscalPeriod >= :P_FromFiscalPeriod
and FiscalPeriod.FiscalPeriod <= :P_ToFiscalPeriod
and ( CreationDate < ChangeLog.AssetDeactivationDate
      or ChangeLog.AssetDeactivationDate = '00000000' )

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FISCALYEARPERIODFORLEDGER",
"P_CN_CADEASSETCHANGELOG"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/