I_FISCALYEARPERIODFORLEDGER

CDS View

Fiscal Year Period for Ledger

I_FISCALYEARPERIODFORLEDGER is a CDS View in S/4HANA. Fiscal Year Period for Ledger. It contains 9 fields. 31 CDS views read from this table.

Used by 31 CDS view(s) 9 fields

CDS Views using this table (31)

ViewTypeJoinVDMDescription
C_ActualCostRateTimeline view inner CONSUMPTION Actual Cost Rate Timeline
C_CN_CADEAssetByPeriod view from CONSUMPTION Asset Assignment by Period for CADE
C_CN_CADEAssetChangeLog view from CONSUMPTION Change Log of Assgmt of Asset for CADE
C_CN_FsclPerdVH view from CONSUMPTION Fiscal Period Value Help
C_FxdAstFsclYrPerdForLedgerVH view from CONSUMPTION Fixed Asset Fiscal Year Period for Ledger Value Help
C_NL_SAFTPeriod view from CONSUMPTION SAF-T NL Periods
C_PlanCostRateTimeline view inner CONSUMPTION Plan Cost Rate Timeline
C_ServiceCostRateTimeline view inner CONSUMPTION Service Cost Rate Timeline Chart
I_CN_CADECashFlow view left_outer COMPOSITE CADE cash flow details
I_CN_CADEFixedAssetValueCube view from COMPOSITE Fixed Asset Balance Cube for CADE
I_FxdAstAssgmtByFsclPerdEndDte view inner COMPOSITE Fixed Asset Assignment valid at fiscal period end date
I_FxdAstDeprAreaByFsclPerdEnd view inner COMPOSITE Depreciation Area valid at fiscal period end date
I_PostingPeriodHierarchy1 view from COMPOSITE Posting Period Hierarchy 1
I_PostingPeriodHierarchy1 view union COMPOSITE Posting Period Hierarchy 1
P_CN_CADEAcctBalanceStructure view left_outer COMPOSITE
P_CN_CADEAssetAllChgDocWthPrd view inner COMPOSITE
P_CN_CADEAssetQuantity view from COMPOSITE
P_CN_CADECalcExpiredPeriods view inner COMPOSITE
P_CN_CADECashFlowZeroBal view from COMPOSITE
P_CN_CADEFsclPerdForCmpnyCode view from CONSUMPTION
P_EBOC_MaxOrdKeyStatusByPeriod view inner COMPOSITE
P_EBPC_MaxOrderStatusByPeriod view inner COMPOSITE
P_FixedAssetValueCube view inner COMPOSITE
P_FsclYearPerdWithSpclPerd view from COMPOSITE
P_RO_StRpFixedAssetChartValue view inner CONSUMPTION
P_RU_MaxFiscalPeriodForLedger view from COMPOSITE Maximum Fiscal Period For Ledger
P_RU_MinFiscalPeriodForLedger view from COMPOSITE Minimum Fiscal Period For Ledger
P_RU_PropertyTaxFixedAssetVal1 view from COMPOSITE
P_RU_PropertyTaxFixedAssetVal3 view left_outer COMPOSITE
R_EvtBsdFsclYrPeriodByKeyDate view from COMPOSITE Event-Based Fiscal Year Period by Key Date
R_EvtBsdKeyDateByFsclYrPeriod view from COMPOSITE Event-Based Key Date by Fiscal Year Period

Fields (9)

KeyField CDS FieldsUsed in Views
KEY CompanyCode CompanyCode 7
KEY FiscalPeriod FiscalPeriod,NextFiscalPeriod,PostingFiscalPeriod 11
KEY FiscalYear FiscalYear,NextFiscalPeriodFiscalYear 13
KEY FiscalYearPeriod FiscalYearPeriod 5
KEY Ledger Ledger 3
FiscalPeriodEndDate CalendarDeprPeriodEndDate,CalendarPostingPeriodEndDate,FiscalPeriodEndDate 6
FiscalPeriodStartDate CalendarDeprPeriodStartDate,CalendarPostingPeriodStartDate,FiscalPeriodStartDate 2
IsSpecialPeriod IsSpecialPeriod 1
NextFiscalPeriod NextFiscalPeriod 1 
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.sqlViewName: 'IFIFYEARPER4L'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true

@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Fiscal Year Period for Ledger'
@VDM.viewType: #BASIC

@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #CUSTOMIZING

@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.representativeKey: 'FiscalPeriod'
//@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }

@Analytics: { dataCategory: #DIMENSION }
//--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

//@AccessControl.privilegedAssociations: ['_LedgerText']

// ]--GENERATED


@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, 
                                     #CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #SQL_DATA_SOURCE]
                                     
define view I_FiscalYearPeriodForLedger as select from I_FiscalYearPeriod inner join finsc_ld_cmp 
                                                  on   I_FiscalYearPeriod.FiscalYearVariant = finsc_ld_cmp.periv


  //--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

association [0..*] to I_LedgerText               as _LedgerText on   $projection.Ledger = _LedgerText.Ledger
  // ]--GENERATED

association [0..1] to I_CompanyCode              as _CompanyCode on  $projection.CompanyCode       = _CompanyCode.CompanyCode
association [0..1] to I_Ledger                   as _Ledger      on  $projection.Ledger            = _Ledger.Ledger
association [0..1] to I_FiscalYearVariant        as _FiscalYearVariant on  $projection.FiscalYearVariant = _FiscalYearVariant.FiscalYearVariant
association [0..1] to I_FiscalYearForCompanyCode as _FiscalYear  on  $projection.FiscalYear        = _FiscalYear.FiscalYear
                                                                 and $projection.CompanyCode       = _FiscalYear.CompanyCode 
association [0..1] to I_FiscalYear               as _FiscalYearForVariant  on  $projection.FiscalYearVariant = _FiscalYearForVariant.FiscalYearVariant
                                                                           and $projection.FiscalYear        = _FiscalYearForVariant.FiscalYear                                                                    
association [0..*] to I_FiscalYearPeriodText     as _Text        on  $projection.FiscalYearVariant = _Text.FiscalYearVariant
                                                                 and $projection.FiscalYear        = _Text.FiscalYear
                                                                 and $projection.FiscalPeriod      = _Text.FiscalPeriod
association [0..1] to I_FiscalYearForLedger      as _FiscalYearForLedger  on  $projection.Ledger = _FiscalYearForLedger.Ledger
                                                                           and $projection.CompanyCode = _FiscalYearForLedger.CompanyCode
                                                                           and $projection.FiscalYear  = _FiscalYearForLedger.FiscalYear                                                                       

{

      //--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
      // ]--GENERATED

@ObjectModel.foreignKey.association: '_CompanyCode'      
key cast( finsc_ld_cmp.bukrs as fis_bukrs preserving type ) as CompanyCode, 
      //--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_LedgerStdVH',
                     element: 'Ledger' }
        }]
      @ObjectModel.text.association: '_LedgerText'
      // ]--GENERATED

@ObjectModel.foreignKey.association: '_Ledger'      
key cast( finsc_ld_cmp.rldnr as fis_rldnr preserving type ) as Ledger,
@ObjectModel.foreignKey.association: '_FiscalYearForLedger'      
key I_FiscalYearPeriod.FiscalYear,
key I_FiscalYearPeriod.FiscalPeriod,

@ObjectModel.foreignKey.association: '_FiscalYearVariant'      
//@Semantics.fiscal.yearVariant: true     

    I_FiscalYearPeriod.FiscalYearVariant,

@ObjectModel.foreignKey.association: '_FiscalPeriodStartDate'      
    I_FiscalYearPeriod.FiscalPeriodStartDate,
    I_FiscalYearPeriod.FiscalPeriodEndDate,
    
    I_FiscalYearPeriod.IsSpecialPeriod,
    
    I_FiscalYearPeriod.FiscalYearStartDate,
    I_FiscalYearPeriod.FiscalYearEndDate,
    
    I_FiscalYearPeriod.NextFiscalPeriod,
    I_FiscalYearPeriod.NextFiscalPeriodFiscalYear,
     
    I_FiscalYearPeriod.FiscalYearPeriod,
    
    _CompanyCode,
    _Ledger,
    _FiscalYearVariant,
    @VDM.lifecycle.status:    #DEPRECATED
    @VDM.lifecycle.successor: '_FiscalYearForLedger'
    _FiscalYearForVariant,
    _FiscalPeriodStartDate,
    @VDM.lifecycle.status:    #DEPRECATED
    @VDM.lifecycle.successor: '_FiscalYearForLedger'    
    _FiscalYear,
    _FiscalYearForLedger,
    _Text,
      //--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

      @Consumption.hidden: true
      _LedgerText
      // ]--GENERATED



}                
 

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FISCALYEARPERIOD",
"FINSC_LD_CMP"
],
"ASSOCIATED":
[
"I_CALENDARDATE",
"I_COMPANYCODE",
"I_FISCALYEAR",
"I_FISCALYEARFORCOMPANYCODE",
"I_FISCALYEARFORLEDGER",
"I_FISCALYEARPERIODTEXT",
"I_FISCALYEARVARIANT",
"I_LEDGER",
"I_LEDGERTEXT"
],
"BASE":
[
"I_FISCALYEARPERIOD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More